求救，如何实现VB自动填写网页联动

[nn_sky]

如题，，，
自动填写一下网页联动，我已经想了好多天了，最终无法解决，，，，
http://house.gxsky.com/intermediary/ChuShou.aspx?type=n
自动填写： 城市 城区 片区
请高手指点，，谢谢
QQ：215831207

[nn_sky]

高手在哪里呀？？？

[nn_sky]

自己顶了~~~！！！

[nn_sky]

等了2天了，，，

[supergreenbean]

Option Explicit
Private WithEvents ctl00_ContentPlaceHolder1_DropDownList城市 As HTMLSelectElement
Private WithEvents ctl00_ContentPlaceHolder1_DropDownList区域 As HTMLSelectElement
Private WithEvents ctl00_ContentPlaceHolder1_DropDownList片区 As HTMLSelectElement

Private Sub ctl00_ContentPlaceHolder1_DropDownList城市_onchange()
    ctl00_ContentPlaceHolder1_DropDownList区域.Value = "青秀区"
    ctl00_ContentPlaceHolder1_DropDownList区域.FireEvent "onchange"
End Sub

Private Sub ctl00_ContentPlaceHolder1_DropDownList区域_onchange()
    ctl00_ContentPlaceHolder1_DropDownList片区.Value = "柳沙"
    ctl00_ContentPlaceHolder1_DropDownList片区.FireEvent "onchange"
End Sub

Private Sub ctl00_ContentPlaceHolder1_DropDownList片区_onchange()
    '提交
End Sub

Private Sub Form_Load()
    WebBrowser1.Navigate2 "http://house.gxsky.com/intermediary/ChuShou.aspx?type=n"
End Sub

Private Sub WebBrowser1_DocumentComplete(ByVal pDisp As Object, URL As Variant)
    Dim oDoc As HTMLDocument
    Set oDoc = pDisp.Document
    
    With oDoc
        Set ctl00_ContentPlaceHolder1_DropDownList城市 = .getElementById("ctl00_ContentPlaceHolder1_DropDownList城市")
        Set ctl00_ContentPlaceHolder1_DropDownList区域 = .getElementById("ctl00_ContentPlaceHolder1_DropDownList区域")
        Set ctl00_ContentPlaceHolder1_DropDownList片区 = .getElementById("ctl00_ContentPlaceHolder1_DropDownList片区")
        
        ctl00_ContentPlaceHolder1_DropDownList城市.Value = "南宁市"
        ctl00_ContentPlaceHolder1_DropDownList城市.FireEvent "onchange"
    End With
    
End Sub

[wrongagain98]

关注

[yintiger5092]

关注

[lxinyuan03]

关注 我学在搞这个

[nn_sky]

提示错误“用户定义类型未定义”

晕倒~~！！

[Edidu]

没分,拒绝回答.

[supergreenbean]

添加引用 Microsoft HTML Object Library 就可以了

[vicentmcu]

hao

[huoying88]

谢谢分享

[ouzhengping]

HGFHGFHGFH

[d327943542]

ctl00_ContentPlaceHolder1_DropDownList城市.Value = "南宁市"
ctl00_ContentPlaceHolder1_DropDownList城市.FireEvent "onchange"
End With
拷贝这么多 我要分啊 没分下载

[supergreenbean]

Option Explicit
Private WithEvents dpl城市 As HTMLSelectElement
Private WithEvents dpl区域 As HTMLSelectElement
Private WithEvents dpl片区 As HTMLSelectElement

Private Sub dpl城市_onchange()
    SelectByDisplayText dpl区域, "良庆区"
End Sub

Private Sub dpl区域_onchange()
    SelectByDisplayText dpl片区, "五象新区"
End Sub

Private Sub dpl片区_onchange()
    '提交
End Sub

Private Sub Form_Load()
    WebBrowser1.Navigate2 "http://www.nn-sky.com"
End Sub

Private Sub WebBrowser1_DocumentComplete(ByVal pDisp As Object, URL As Variant)
    '一天一个梦
    '000000
    
    If LCase(URL) <> "http://www.nn-sky.com/user/house_fabu.asp" Then Exit Sub
    

    Dim oDoc As HTMLDocument
    Set oDoc = pDisp.Document
    
    With oDoc
        Set dpl城市 = .getElementById("city_one")
        Set dpl区域 = .getElementById("city_two")
        Set dpl片区 = .getElementById("city_three")
        
        If dpl城市 Is Nothing Then Exit Sub
        If dpl区域 Is Nothing Then Exit Sub
        If dpl片区 Is Nothing Then Exit Sub
                
        SelectByDisplayText dpl城市, "南宁市"
    End With
    
End Sub


Private Sub SelectByDisplayText(dpl As HTMLSelectElement, ByVal sSelectText As String)
    Dim opt As HTMLOptionElement
    
    For Each opt In dpl.Options
        If opt.Text = sSelectText Then
            opt.Selected = True
            dpl.FireEvent "onchange"
            Exit Sub
        End If
    Next
End Sub

[nn_sky]

Option Explicit
Private WithEvents dpl城市 As HTMLSelectElement
Private WithEvents dpl区域 As HTMLSelectElement
Private WithEvents dpl片区 As HTMLSelectElement

Private Sub dpl城市_onchange()
SelectByDisplayText dpl区域, "良庆区"
End Sub

Private Sub dpl区域_onchange()
SelectByDisplayText dpl片区, "五象新区"
End Sub

Private Sub dpl片区_onchange()
'提交
End Sub

Private Sub Form_Load()
WebBrowser1.Navigate2 "http://www.nn-sky.com"
End Sub

Private Sub WebBrowser1_DocumentComplete(ByVal pDisp As Object, URL As Variant)
'一天一个梦
'000000

If LCase(URL) <> "http://www.nn-sky.com/user/house_fabu.asp" Then Exit Sub


Dim oDoc As HTMLDocument
Set oDoc = pDisp.Document

With oDoc
Set dpl城市 = .getElementById("city_one")
Set dpl区域 = .getElementById("city_two")
Set dpl片区 = .getElementById("city_three")

If dpl城市 Is Nothing Then Exit Sub
If dpl区域 Is Nothing Then Exit Sub
If dpl片区 Is Nothing Then Exit Sub

SelectByDisplayText dpl城市, "南宁市"
End With

End Sub


Private Sub SelectByDisplayText(dpl As HTMLSelectElement, ByVal sSelectText As String)
Dim opt As HTMLOptionElement

For Each opt In dpl.Options
If opt.Text = sSelectText Then
opt.Selected = True
dpl.FireEvent "onchange"
Exit Sub
End If
Next
End Sub

[超级松林]

精彩啊，有空研究一下！谢了

[hkchoose]

看来真有点精华

[onedl821]

经典............

收藏先.

[yiweibiao]

精，，，如何修改网页中的内容呢？

比如，网页装载完毕后，如何将网页中的“TEL”改成“电话”呢？