操作系统保护模式问题

[xxxxxx91116]

以下是参照orange一个操作系统的实现的程序，为什么不对呢？实在想不通，希望有人指点，编译有错误：
nasm error write error on output file
%include "gdt.inc"
org 0100h
jmp LABEL_BEGIN

[SECTION .gdt]
;GDT
LABEL_GDT: Descriptor 0, 0,0
LABEL_DESC_NORMAL: Descriptor 0, 0ffffh,DA_DRW
LABEL_DESC_CODE32: Descriptor 0, SegCode32Len-1,DA_C+DA_32
LABEL_DESC_CODE16: Descriptor 0, 0ffffh,DA_C
LABEL_DESC_DATA: Descriptor 0, DataLen-1,DA_DRW
LABEL_DESC_STACK: Descriptor 0, TopOfStack,DA_DRWA+DA_32
LABEL_DESC_TEST: Descriptor 0500000h, 0ffffh,DA_DRW
LABEL_DESC_VIDEO: Descriptor 0B8000h, 0ffffh,DA_DRW

GdtLen equ $-LABEL_GDT
GdtPtr dw GdtLen-1
dd 0

SelectorNormal equ LABEL_DESC_NORMAL-LABEL_GDT
SelectorCode32 equ LABEL_DESC_CODE32-LABEL_GDT
SelectorCode16 equ LABEL_DESC_CODE16-LABEL_GDT
SelectorData equ LABEL_DESC_DATA-LABEL_GDT
SelectorStack equ LABEL_DESC_STACK-LABEL_GDT
SelectorTest equ LABEL_DESC_TEST-LABEL_GDT
SelectorVideo equ LABEL_DESC_VIDEO-LABEL_GDT

[SECTION .data1]
ALIGN 32
[BITS 32]
LABEL_DATA:
SPValueInRealMode dw 0
PMMessage db "In Protect Mode Now.",0
OffsetPMMessage equ PMMessage-$$
StrTest db "ABCDEFGHIJKLMNOPQRSTUVWXYZ",0
OffsetStrTest equ StrTest-$$
DataLen equ $-LABEL_DATA


[SECTION .gs]
ALIGN 32
[BITS 32]
LABEL_STACK:
times 512 db 0
TopOfStack equ $-LABEL_STACK-1

[SECTION .s16]
[BITS 16]
LABEL_BEGIN:
mov ax,cs
mov ds,ax
mov es,ax
mov ss,ax
mov sp,0100h

;
mov [SPValueInRealMode],sp
mov [LABEL_GO_BACK_TO_REAL+3],ax

;Initial LABEL_DESC_CODE16
mov ax,cs
movzx eax,ax
shl eax,4
add eax,LABEL_SEG_CODE16
mov word [LABEL_DESC_CODE16+2],ax
shr eax,16
mov byte [LABEL_DESC_CODE16+4],al
mov byte [LABEL_DESC_CODE16+7],ah

;Initial LABEL_DESC_CODE32
xor eax,eax
mov ax,cs
shl eax,4
add eax,LABEL_SEG_CODE32
mov word [LABEL_DESC_CODE32+2],ax
shr eax,16
mov byte [LABEL_DESC_CODE32+4],al
mov byte [LABEL_DESC_CODE32+7],ah



;Initial LABEL_DESC_DATA
xor eax,eax
mov ax,cs
shl eax,4
add eax,LABEL_DATA
mov word [LABEL_DESC_DATA+2],ax
shr eax,16
mov byte [LABEL_DESC_DATA+4],al
mov byte [LABEL_DESC_DATA+7],ah

;Initial LABEL_DESC_STACK
xor eax,eax
mov ax,cs
shl eax,4
add eax,LABEL_STACK
mov word [LABEL_DESC_STACK+2],ax
shr eax,16
mov byte [LABEL_DESC_STACK+4],al
mov byte [LABEL_DESC_STACK+7],ah

;
xor eax,eax
mov ax,cs
shl eax,4
add eax,LABEL_GDT
mov dword [GdtPtr+2],eax

;
lgdt [GdtPtr]

;
cli

;open addr wire
in al,92h
or al,00000010b
out 92h,al

;
mov eax,cr0
or eax,1
mov cr0,eax

;
jmp dword SelectorCode32:0

;---------------------------
LABEL_REAL_ENTRY:
mov ax,cs
mov ds,ax
mov es,ax
mov ss,ax

mov sp,[SPValueInRealMode]

in al,92h
and al,11111101b
out 92h,al

sti

mov ax,4c00h
int 21h

[SECTION .s32]
[BITS 32]
LABEL_SEG_CODE32:
mov ax,SelectorData
mov ds,ax

mov ax,SelectorStack
mov ss,ax
mov esp,TopOfStack

mov ax,SelectorVideo
mov gs,ax

mov ax,SelectorTest
mov es,ax

;

xor edi,edi
xor esi,esi
mov ah,0Ch
mov esi,OffsetPMMessage
mov edi,(80*10+0)*2
cld

.1:
lodsb
test al,al
jz .2
mov [gs:edi],ax
add edi,2
jmp .1

.2:
call DispReturn
call TestRead
call TestWrite
call TestRead

jmp SelectorCode16:0


;-----------------------------------------------------------------
TestRead:
xor esi,esi
mov ecx,8
.loop:
mov al,[es:esi]
call DispAL
inc esi
loop .loop

call DispReturn
ret

;------------------------------------------------------------------
TestWrite:
push esi
push edi

xor edi,edi
xor esi,esi
mov esi,OffsetStrTest
cld

.1:
lodsb
test al,al
jz .2
mov [es:edi],al
inc edi
jmp .1

.2:
pop edi
pop esi

ret

;------------------------------------------------------------------
DispAL:
push ecx
push edx

mov dl,al
mov ah,0Ch
shr al,4
mov ecx,2

.begin:
and al,01111b
cmp al,9
ja .1
add al,'0'
jmp .2

.1:
sub al,0Ah
add al,'A'

.2:
mov [gs:edi],ax
mov al,dl
add edi,2
loop .begin

add edi,2

pop edx
pop ecx
ret


;----------------------------
DispReturn:
push eax
push ebx
mov eax,edi
mov bl,160
div bl
and eax,0ffh
inc eax
mov bl,160
mul bl
mov edi,eax
pop ebx
pop eax
ret
SegCode32Len equ $-LABEL_SEG_CODE32
;------------------------------
[SECTION .s16code]
ALIGN 32
[BITS 16]
LABEL_SEG_CODE16:
mov ax,SelectorNormal
mov ds,ax
mov es,ax
mov ss,ax
mov fs,ax
mov gs,ax
mov eax,cr0
and al,11111110b
mov cr0,eax

LABEL_GO_BACK_TO_REAL:
jmp 0:LABEL_REAL_ENTRY

Code16Len equ $-LABEL_SEG_CODE16

[xxxxxx91116]

后来我终于找出来了~不过我自己还是不太明白~有两个地方非常不明白
第一个：
[SECTION .gdt]
;GDT
LABEL_GDT: Descriptor 0, 0,0
LABEL_DESC_NORMAL: Descriptor 0, 0ffffh,DA_DRW
LABEL_DESC_CODE32: Descriptor 0, SegCode32Len-1,DA_C+DA_32
LABEL_DESC_CODE16: Descriptor 0, 0ffffh,DA_C
LABEL_DESC_DATA: Descriptor 0, DataLen-1,DA_DRW
LABEL_DESC_STACK: Descriptor 0, TopOfStack,DA_DRWA+DA_32
LABEL_DESC_TEST: Descriptor 0500000h, 0ffffh,DA_DRW
LABEL_DESC_VIDEO: Descriptor 0B8000h, 0ffffh,DA_DRW
这一段里面~那个LABEL_DESC_CODE16: Descriptor 0, 0ffffh,DA_C的界限为什么是0ffffh，我改成了Code16Len-1就编译出错~

第二个：
[SECTION .data1]
ALIGN 32
[BITS 32]
LABEL_DATA:
SPValueInRealMode dw 0
;
PMMessage: db "In Protect Mode Now.",0
OffsetPMMessage equ PMMessage-$$
StrTest: db "ABCDEFGHIJKLMNOPQRSTUVWXYZ",0
OffsetStrTest equ StrTest-$$
DataLen equ $-LABEL_DATA
上面这一段里面为什么SPValueInRealMode dw 0后面必须要有一个;的注释符号或者一个空行，否则也会出错~请高手解答