批处理 选择截取文件名中的日期移动文件

[samwang1]

test1文件夹中有以下文件(3个文件为一组):
CH50_XX_201007071641.csv
CH50_YY_201007071641.csv
CH50_ZZ_201007071641.csv(假设系统为7月)

CH50_XX_201006301641.csv
CH50_YY_201006301641.csv
CH50_ZZ_201006301641.csv

CH50_XX_201006221641.csv
CH50_YY_201006221641.csv
CH50_ZZ_201006221641.csv

现要提取上个月(6月)最后一组文件(日期不一定为30号,只要是上月最后一天的数据)移至文件夹test2中,结果如下:
CH60_XX_201006301641.csv
CH60_YY_201006301641.csv
CH60_ZZ_201006301641.csv

貌似有点复杂 望请高手帮忙 谢谢~!

[samwang1]

[Quote=引用 1 楼 forever_young 的回复:]
比如你的test1和test2文件夹在D盘，如果今天运行，就把20110930的文件从test1移动到test2


BatchFile code


@echo off
set sp=D:\test1
set dp=D:\test2

more +14 %~0>%~dp0tmp.vbs
for /f %%a in ('cscript /nologo "%~dp0tmp.vb……
[/Quote]
我运行了一下 文件可以移动 但是会显示找不到and 文件 并且移动后都会删掉那个tmp.vbs文件吗 这样的话每次移动都要重新建立一个新的vbs文件吗?

[samwang1]

[Quote=引用 4 楼 microogle 的回复:]
Assembly code


@echo off
set sd=d:\test1\
set dd=d:\test2\

pushd %sd%
rem 转换"2010/07/0x 周x"为"201007",需要根据本机的日期格式修改
set d=%date:/=%
set d=%d:~0,6%
rem 也可手动s……
[/Quote]
好像这个运行后没效果

[Forever_Young]

[Quote=引用 5 楼 samwang1 的回复:]
我运行了一下 文件可以移动 但是会显示找不到and 文件 并且移动后都会删掉那个tmp.vbs文件吗 这样的话每次移动都要重新建立一个新的vbs文件吗?
[/Quote]

这个完全是按照你的描述来做的，如果你提供的信息不完整有可能出点错误，比如我这个脚本只提供了当前时间的判断，也就是以你执行的日期为准减一个月，如果你的文件夹没有对应文件肯定就会提示找不到文件了。

另外这个批处理如果你要改动，增减行数的话，要注意前面more后面的数字，那个也要相应增减，VBS临时创建没关系，你也可以单独剥离出来，这个看你自己的需求了。

[samwang1]

[Quote=引用 7 楼 forever_young 的回复:]
引用 5 楼 samwang1 的回复:
我运行了一下 文件可以移动 但是会显示找不到and 文件 并且移动后都会删掉那个tmp.vbs文件吗 这样的话每次移动都要重新建立一个新的vbs文件吗?


这个完全是按照你的描述来做的，如果你提供的信息不完整有可能出点错误，比如我这个脚本只提供了当前时间的判断，也就是以你执行的日期为准减一个月，如果你的文件夹没有对应文件肯定就会提示找不到文件了。……
[/Quote]
more +14 %~0>%~dp0tmp.vbs
for /f %%a in ('cscript /nologo "%~dp0tmp.vbs"') do (set d=%%a&del "%~dp0tmp.vbs")
这两句话有点看不明白 能否解释一下呢?
是不是把&del "%~dp0tmp.vbs"这句话删了就不会删掉那个文件了呢?

[samwang1]

[Quote=引用 3 楼 ljc007 的回复:]
引用 2 楼 mokson 的回复:
这是典型的字串查找功能，多看看批处理的 findstr 用法吧。


这是典型的日期计算问题，跟findstr关系不是特别大。
[/Quote]
不知道版主能否帮我看看这个怎么弄呢?

[samwang1]

[Quote=引用 7 楼 forever_young 的回复:]
引用 5 楼 samwang1 的回复:
我运行了一下 文件可以移动 但是会显示找不到and 文件 并且移动后都会删掉那个tmp.vbs文件吗 这样的话每次移动都要重新建立一个新的vbs文件吗?


这个完全是按照你的描述来做的，如果你提供的信息不完整有可能出点错误，比如我这个脚本只提供了当前时间的判断，也就是以你执行的日期为准减一个月，如果你的文件夹没有对应文件肯定就会提示找不到文件了。……
[/Quote]
不好意思 我没说明白 那个要求是要找到上个月中文件夹日期最大的那个时点的文件组 如果系统是10月的话 test1中9月份的csv中不一定有30号那天的 是选取9月份文件中文件名日期最大的那个文件 有可能是28号等等....

[mokson]

这是典型的字串查找功能，多看看批处理的 findstr 用法吧。

[ljc007]

[Quote=引用 2 楼 mokson 的回复:]
这是典型的字串查找功能，多看看批处理的 findstr 用法吧。
[/Quote]

这是典型的日期计算问题，跟findstr关系不是特别大。

[Microogle]

@echo off
	set sd=d:\test1\
	set dd=d:\test2\
	
	pushd %sd%
	rem 转换"2010/07/0x 周x"为"201007",需要根据本机的日期格式修改
	set d=%date:/=%
	set d=%d:~0,6%
	rem 也可手动set d=201007来实现指定年月
	
	rem n=截至上月文件总数目
	for /f "tokens=1 delims=:" %%i in ('dir /b *.csv ^| findstr /iv "%d%" ^| findstr /n .*') do set /a n=%%i
	
	rem 取最后3个文件
	set /a n-=3
	for /f "skip=%n%" %%i in ('dir /b *.csv ^| findstr /iv "%d%" ^| sort /+8') do move "%%i" "%dd%"
	popd
	pause
goto :eof

[Forever_Young]

比如你的test1和test2文件夹在D盘，如果今天运行，就把20110930的文件从test1移动到test2

[code=BatchFile]
@echo off
set sp=D:\test1
set dp=D:\test2

more +14 %~0>%~dp0tmp.vbs
for /f %%a in ('cscript /nologo "%~dp0tmp.vbs"') do (set d=%%a&del "%~dp0tmp.vbs")
setlocal enabledelayedexpansion
for /f %%a in ('dir /b /a-d "%sp%\ch50*_%d%*.csv"') do (
set nn=%%a
set nn=!nn:ch50=ch60!
copy /y "%sp%\%%a" "%dp%\!nn!"&&del /f /q "%sp%\%%a"
)
pause
exit

dtmp=year(dateadd("m",-1,date))&"-"&month(dateadd("m",-1,date))&"-"
if isdate(dtmp&"28") then lastmon=dtmp&"28"
if isdate(dtmp&"29") then lastmon=dtmp&"29"
if isdate(dtmp&"30") then lastmon=dtmp&"30"
if isdate(dtmp&"31") then lastmon=dtmp&"31"
wscript.echo year(lastmon)&right("0"&month(lastmon),2)&right("0"&day(lastmon),2)
[/code]

[Microogle]

[Quote=引用 6 楼 samwang1 的回复:]

引用 4 楼 microogle 的回复:
Assembly code


@echo off
set sd=d:\test1\
set dd=d:\test2\

pushd %sd%
rem 转换"2010/07/0x 周x"为"201007",需要根据本机的日期格式修改
set d=%date:/=%
set d=%d:~0,6%
rem 也可手动s……

好像……
[/Quote]

set sd=d:\test1\
set dd=d:\test2\

pushd %sd%
rem 转换"2010/07/0x 周x"为"201007",需要根据本机的日期格式修改

[samwang1]

[Quote=引用 13 楼 forever_young 的回复:]
把上面的改了一下，那个一行太长了，呵呵


BatchFile code


@echo off
set sp="D:\test1\ch50_*_!ym!!d!*.csv"
set dp="D:\test2\ch60_*_!ym!!d!*.csv"
set tp=%~dp0tmp.vbs
echo wscript.echo year(dateadd("m",-1,date))^……
[/Quote]
强大啊 可以实现了
不过我想问问你这两句是什么意思
set tp=%~dp0tmp.vbs (%~dp0这没看懂)
echo wscript.echo year(dateadd("m",-1,date))^&^
right("0"^&month(dateadd("m",-1,date)),2)>"%tp%" (right后面是什么意思呢?)
for /f %%a in ('cscript /nologo "%tp%"') do (set ym=%%a&del "%tp%") (nologo这个有什么作用呢?)

[Forever_Young]

%~dp0就是批处理所处的路径

right和上面是一句

nologo是不显示cscript的标题信息

[Forever_Young]

把上面的改了一下，那个一行太长了，呵呵

[code=BatchFile]
@echo off
set sp="D:\test1\ch50_*_!ym!!d!*.csv"
set dp="D:\test2\ch60_*_!ym!!d!*.csv"
set tp=%~dp0tmp.vbs
echo wscript.echo year(dateadd("m",-1,date))^&^
right("0"^&month(dateadd("m",-1,date)),2)>"%tp%"
setlocal enabledelayedexpansion
for /f %%a in ('cscript /nologo "%tp%"') do (set ym=%%a&del "%tp%")
for /l %%a in (31,-1,1) do (
set d=0%%a
set d=!d:~-2!
if exist %sp% (copy /y %sp% %dp%&&del /f /q %sp%&&pause&exit)
)
echo 没有找到目标文件，按任意键退出！
pause>nul
exit
[/code]

[Forever_Young]

你省几个字，回答问题的白费功夫，试试下面的

[code=BatchFile]
echo off
set sp=D:\test1
set dp=D:\test2

echo wscript.echo year(dateadd("m",-1,date))^&right("0"^&month(dateadd("m",-1,date)),2)>"%~dp0tmp.vbs"
for /f "tokens=1,2" %%a in ('cscript /nologo "%~dp0tmp.vbs"') do (set ym=%%a&del "%~dp0tmp.vbs")
setlocal enabledelayedexpansion
for /l %%a in (31,-1,1) do (
set d=0%%a
set d=!d:~-2!
if exist "%sp%\ch50_*_%ym%!d!*.csv" (copy /y "%sp%\ch50_*_%ym%!d!*.csv" "%dp%\ch60_*_%ym%!d!*.csv"&&del "%sp%\ch50_*_%ym%!d!*.csv"&&exit)
)
echo 没有找到目标文件，按任意键退出！
pause>nul
exit
[/code]

[wuwenzhe]

能不能他妈的解释一下每句话都什么意思？