交流--数据库备份/恢复方案

[zjcxc]

/*--备份数据库

--邹建 2003.10--*/

/*--调用示例

--备份当前数据库
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_db.bak'

--差异备份当前数据库
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_df.bak',@bktype='DF'

--备份当前数据库日志
exec p_backupdb @bkpath='c:\',@bkfname='db_\DATE\_log.bak',@bktype='LOG'

--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_backupdb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_backupdb]
GO

create proc p_backupdb
@dbname sysname='', --要备份的数据库名称,不指定则备份当前数据库
@bkpath nvarchar(260)='', --备份文件的存放目录,不指定则使用SQL默认的备份目录
@bkfname nvarchar(260)='', --备份文件名,文件名中可以用\DBNAME\代表数据库名,\DATE\代表日期,\TIME\代表时间
@bktype nvarchar(10)='DB', --备份类型:'DB'备份数据库,'DF' 差异备份,'LOG' 日志备份
@appendfile bit=1 --追加/覆盖备份文件
as
declare @sql varchar(8000)
if isnull(@dbname,'')='' set @dbname=db_name()
if isnull(@bkpath,'')='' set @bkpath=dbo.f_getdbpath(null)
if isnull(@bkfname,'')='' set @bkfname='\DBNAME\_\DATE\_\TIME\.BAK'
set @bkfname=replace(replace(replace(@bkfname,'\DBNAME\',@dbname)
,'\DATE\',convert(varchar,getdate(),112))
,'\TIME\',replace(convert(varchar,getdate(),108),':',''))
set @sql='backup '+case @bktype when 'LOG' then 'log ' else 'database ' end +@dbname
+' to disk='''+@bkpath+@bkfname
+''' with '+case @bktype when 'DF' then 'DIFFERENTIAL,' else '' end
+case @appendfile when 1 then 'NOINIT' else 'INIT' end
print @sql
exec(@sql)
go

----------------------------------------------------------------------
/*--恢复数据库

--邹建 2003.10--*/

/*--调用示例
--完整恢复数据库
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db'

--差异备份恢复
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:\db_20031015_df.bak',@dbname='db',@retype='DF'

--日志备份恢复
exec p_RestoreDb @bkfile='c:\db_20031015_db.bak',@dbname='db',@retype='DBNOR'
exec p_backupdb @bkfile='c:\db_20031015_log.bak',@dbname='db',@retype='LOG'

--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_RestoreDb]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_RestoreDb]
GO

create proc p_RestoreDb
@bkfile nvarchar(1000), --定义要恢复的备份文件名
@dbname sysname='', --定义恢复后的数据库名,默认为备份的文件名
@dbpath nvarchar(260)='', --恢复后的数据库存放目录,不指定则为SQL的默认数据目录
@retype nvarchar(10)='DB', --恢复类型:'DB'完事恢复数据库,'DBNOR' 为差异恢复,日志恢复进行完整恢复,'DF' 差异备份的恢复,'LOG' 日志恢复
@filenumber int=1, --恢复的文件号
@overexist bit=1, --是否覆盖已经存在的数据库,仅@retype为
@killuser bit=1 --是否关闭用户使用进程,仅@overexist=1时有效
as
declare @sql varchar(8000)

--得到恢复后的数据库名
if isnull(@dbname,'')=''
select @sql=reverse(@bkfile)
,@sql=case when charindex('.',@sql)=0 then @sql
else substring(@sql,charindex('.',@sql)+1,1000) end
,@sql=case when charindex('\',@sql)=0 then @sql
else left(@sql,charindex('\',@sql)-1) end
,@dbname=reverse(@sql)

--得到恢复后的数据库存放目录
if isnull(@dbpath,'')='' set @dbpath=dbo.f_getdbpath('')

--生成数据库恢复语句
set @sql='restore '+case @retype when 'LOG' then 'log ' else 'database ' end+@dbname
+' from disk='''+@bkfile+''''
+' with file='+cast(@filenumber as varchar)
+case when @overexist=1 and @retype in('DB','DBNOR') then ',replace' else '' end
+case @retype when 'DBNOR' then ',NORECOVERY' else ',RECOVERY' end
print @sql
--添加移动逻辑文件的处理
if @retype='DB' or @retype='DBNOR'
begin
--从备份文件中获取逻辑文件名
declare @lfn nvarchar(128),@tp char(1),@i int

--创建临时表,保存获取的信息
create table #tb(ln nvarchar(128),pn nvarchar(260),tp char(1),fgn nvarchar(128),sz numeric(20,0),Msz numeric(20,0))
--从备份文件中获取信息
insert into #tb exec('restore filelistonly from disk='''+@bkfile+'''')
declare #f cursor for select ln,tp from #tb
open #f
fetch next from #f into @lfn,@tp
set @i=0
while @@fetch_status=0
begin
select @sql=@sql+',move '''+@lfn+''' to '''+@dbpath+@dbname+cast(@i as varchar)
+case @tp when 'D' then '.mdf''' else '.ldf''' end
,@i=@i+1
fetch next from #f into @lfn,@tp
end
close #f
deallocate #f
end

--关闭用户进程处理
if @overexist=1 and @killuser=1
begin
declare @spid varchar(20)
declare #spid cursor for
select spid=cast(spid as varchar(20)) from master..sysprocesses where dbid=db_id(@dbname)
open #spid
fetch next from #spid into @spid
while @@fetch_status=0
begin
exec('kill '+@spid)
fetch next from #spid into @spid
end
close #spid
deallocate #spid
end

--恢复数据库
exec(@sql)

go

[txlicenhe]

我也来转一个贴子：

/*************** http://www.csdn.net/develop/article/21/21304.shtm
标题 使用SQLSERVER的扩展存储过程实现远程备份与恢复 happy_david（原作）

关键字 扩展存储过程，远程，备份，恢复



标题很长，但内容简单。。这是小弟的第一篇习作，写的不好，望大家海涵。

最近我在为公司的框架程序（以数据应用为导向的应用体系）做数据管理模块，这个模块的需求比较简单：备份、恢复和清理日志。我公司的软件基本上以C/S为基本架构，所以数据管理模块中两个主要的功能‘备份与恢复’都可能会在Client端操作，备份与恢复’的文件也都有可能存储在client端，因而这个数据管理模块就必须能够实现在远程备份与恢复数据库。

文章的前提阐述完了，就该说说如何具体实现吧。其实都很简单，我想写个远程备份的测试实例
给大家看,就能够很清楚的描述吧！
实例说明：
环境：win2k+sqlserver 2K+查询分析器
SQLSERVER服务实例名称:mainserver
需要备份的数据库名称: msdb
本地机器名称（Client端）：david
本地用户:zf 密码：123
本地域名：domain
本地提供备份需求的文件夹:e:\test

第一步: 建立共享文件夹
在程序代码中调用（或者CMD窗口） net share test=e:\test
或者用NetShareAdd这个API
简要说明：
net share : 是WINDOWS内部的网络命令。
作用：建立本地的共享资源，显示当前计算机的共享资源信息。
语法：参见 net share /?
第二步: 建立共享信用关系
master..xp_cmdshell 'net use \\david\test 123 /user:domain\zf'
简要说明：
1：xp_cmdshell ：是SQLSERVER的扩展存储过程。
作用，以操作系统命令行解释器的方式执行给定的命令字符串，
并以文本行方式返回任何输出。
语法：参见SQLSERVER联机帮助
2:net use : 是WINDOWS内部的网络命令。
作用，将计算机与共享资源连接或断开，或者显示关于计算机
连接的信息。该命令还控制持久网络连接。
语法：参见 net use /?

第三步:备份数据库
backup database msdb to disk='\\david\test\msdb.bak'
这个不需要说明吧，语法参见SQLSERVER联机帮助

第四步: 删除共享文件夹
在程序代码中调用（或者CMD窗口） net share test /delete
或者用NetShareDel这个API
结果:
已处理 1376 页，这些页属于数据库 'msdb' 的文件 'MSDBData'（位于文件 1 上）。
已处理 1 页，这些页属于数据库 'msdb' 的文件 'MSDBLog'（位于文件 1 上）。
BACKUP DATABASE 操作成功地处理了 1377 页，花费了 3.653 秒（3.086 MB/秒）。

这样mainserver服务器上的msdb就备份到了david机器的E:\test\msdb.bak文件了，使用起来很简单吧？恢复数据库操作也是一样，只要将第三个步骤的语句改为'restore database msdb from disk='\\david\test\msdb.bak'就可以啦。。你看完了也可以试试呀？！（最简单的测试工具查询分析器+CMD窗口）

备注：xp_cmdshell 这个扩展存储过程只能SA级别的用户调用，而且是SQLSERVER的安全隐患之
一，许多DBA都喜欢将其删除或者禁用，所以开发人员使用时要倍加小心哦。
文章中的例子只是简要的说明了应如何利用扩展存储过程实现远程备份与恢复，没有涉及安全以及其他方面的考虑，希望读者在代码中自行完善。


/**************************************************
SQL异地备份失败，归根结底是权限问题！！！
如：
SQLServer备到FileServer上
那你的SQLServer的启动用户必须在FileServer上有足够的权限!
--------------------^^^---------------------------------
1、SQLServer上新建一SQLUser用户权限大一点。
2、FileServer上建同一用户对某一文件夹有足够权限。
3、两机的SQLUser密码相同(方便一点)
4、将SQLServer改为SQLUser启动
(管理工具-->服务-->mssql项-->属性-->指定用户及密码)
5、\\192.168.*.*\文件夹\ShareBak.Bak就可以了
-----------------------------------------------------------
简单一点就是：
如果你两台都是windows2ks
你的机器也用同样的Administrator密码,且sql服务器用administrator启动
那你写设备时就可以写:\\ip\.......

如果对方是98那你要完全共享一下！
你写设备时就可以写:\\ip\.......

[txlicenhe]

对于如下错误：因为数据库正在使用，所以未能获得对数据库的排它访问权。
最好如下处理：

use master -- 请注意建在master数据库里
go
create proc killspid (@dbname varchar(20))
as
begin
declare @sql nvarchar(500),@temp varchar(1000)
declare @spid int
set @sql='declare getspid cursor for
select spid from sysprocesses where dbid=db_id('''+@dbname+''')'
exec (@sql)
open getspid
fetch next from getspid into @spid
while @@fetch_status =0
begin
set @temp='kill '+rtrim(@spid)
exec(@temp)
fetch next from getspid into @spid
end
close getspid
deallocate getspid
end

--用法
use master -- 请注意在master数据库下运行
go
exec killspid '数据库名'

[missj]

up

[zhoutian618]

学习

[jingxijun]

学习

[wangxl430]

mark

[lvltt]

学习

[edchild]

收藏!

[于之]

邹建的，你的这个存储过程怎么感觉乱乱的呀！到底一个每周一次完全备份，每日一次差异备份，每日两小时一次日志备份，这个存储过程的完整处是哪些！我怎么看来看去，乱乱的，很多呀！不知哪里是哪里了，麻烦你在我下面重贴一次刚才我说的这个存储过程好吗？谢谢！

[workhand]

收藏

[handsomeduke]

学习

[xygjerry]

pl！
学！
thanks！

[vileboy]

收藏

[Primer2002cn]

mark

[j2l2000]

学习

[stsh]

我想在客户端备份服务器上的数据，不知哪位做过，能否讲解一下事例？上面的那些，我试过了，好像只能备份本机上的，如果可以，恢复又该怎么做呢。？谢谢！

[zjcxc]

共享本机目录,然后难过共享目录来备份/恢复.

或者有条件的话,通过架设ftp来上传/下载备份文件.

[loves123]

学习！不错！

[ecamel]

收藏

[jm_qinqin]

restore database fkn from disk='e\fkn.bak' with file=1,replace,RECOVERY
消息 3201，级别 16，状态 2，第 1 行
无法打开备份设备 'C:\Program Files\Microsoft SQL Server\MSSQL.2\MSSQL\Backup\e\fkn.bak'。出现操作系统错误 3(系统找不到指定的路径。)。
消息 3013，级别 16，状态 1，第 1 行
RESTORE FILELIST 正在异常终止。

(0 行受影响)
消息 3201，级别 16，状态 2，第 1 行
无法打开备份设备 'C:\Program Files\Microsoft SQL Server\MSSQL.2\MSSQL\Backup\e\fkn.bak'。出现操作系统错误 3(系统找不到指定的路径。)。
消息 3013，级别 16，状态 1，第 1 行
RESTORE DATABASE 正在异常终止。

我执行怎么有报错，帮我看下。