交流--拼音处理

[zjcxc]

/*--获得汉字字符串的首字母

根据大力的贴子改成.将大力的两个函数合并成了一个函数.
可以应用于助记码的查询
--*/
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[fGetPy]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[fGetPy]
GO

--创建取拼音函数
create function fGetPy(@Str varchar(500)='')
returns varchar(500)
as
begin
declare @strlen int,@return varchar(500),@ii int
declare @n int,@c char(1),@chn nchar(1)

select @strlen=len(@str),@return='',@ii=0
set @ii=0
while @ii<@strlen
begin
select @ii=@ii+1,@n=63,@chn=substring(@str,@ii,1)
if @chn>'z'
select @n = @n +1
,@c = case chn when @chn then char(@n) else @c end
from(
select top 27 * from (
select chn = '吖'
union all select '八'
union all select '嚓'
union all select '咑'
union all select '妸'
union all select '发'
union all select '旮'
union all select '铪'
union all select '丌' --because have no 'i'
union all select '丌'
union all select '咔'
union all select '垃'
union all select '嘸'
union all select '拏'
union all select '噢'
union all select '妑'
union all select '七'
union all select '呥'
union all select '仨'
union all select '他'
union all select '屲' --no 'u'
union all select '屲' --no 'v'
union all select '屲'
union all select '夕'
union all select '丫'
union all select '帀'
union all select @chn) as a
order by chn COLLATE Chinese_PRC_CI_AS
) as b
else set @c='a'
set @return=@return+@c
end
return(@return)
end

go
--测试
select dbo.fgetpy('东莞市') as 东莞市,dbo.fgetpy('ab中c国人') as 中国人

--删除拼音函数
drop function fgetpy

[zjcxc]

如果仅仅是要查询同音字的情况,就是我举的案例:
--查询包含与'长城'拼音一样的记录：
select * from mytable
where exists(select 1 from dbo.f_getpy_tb('长城') where dbo.f_getpy(name) like '%'+re+'%')

用j9988的方法好.

我的方法只适用于要得到拼音的情意.

[zarge]

先收起来，有时间再学习！

[Jarod]

太好了,正需要这个!

[prcgolf]

收藏ing！！

[txlicenhe]

邹建总结了不少好贴子啊。先收藏。

[zjcxc]

/*--获得汉字拼音的函数

需要创建一个拼音表,包含所有汉字的发音,这个可以通过转换全拼输入法的编码库得到,这里仅举了一个简单的例子.
--邹建 2003.10--*/

--创建汉字拼音库
create table YingShe(CHR char(2),PY varchar(10))
insert YingShe
select '长','chang'
union all select '长','zhang'
union all select '城','cheng'
union all select '科','kel'
union all select '技','ji'
union all select '金','jin'
union all select '立','li'
union all select '章','zhang'
union all select '公','gong'
union all select '司','si'

/*--下面是两个函数,一个以表的形式返回某个字符串的全部拼音,一个返回某某个字符串的其中一个拼音
--*/

--获取汉字拼音的函数--返回所有的拼音
create function f_getpy_tb(@str varchar(100))
returns @tb table(re varchar(8000))
as
begin
declare @re table(id int,re varchar(8000)) --数据处理中间表

declare @i int,@ilen int,@splitchr varchar(1)
select @splitchr=' ' --两个拼音之间的分隔符(目的是为了通用性考虑)
,@i=1,@ilen=len(@str)

insert into @re select @i,py from YingShe where chr=substring(@str,@i,1)
while @i<@ilen
begin
set @i=@i+1
insert into @re select @i,re+@splitchr+py from @re a,YingShe b
where a.id=@i-1 and b.chr=substring(@str,@i,1)
end

insert into @tb select re from @re where id=@i
return
end
go

--获取汉字拼音的函数--返回汉字的某一个拼音
create function f_getpy(@str varchar(100))
returns varchar(8000)
as
begin
declare @re varchar(8000)

declare @i int,@ilen int,@splitchr varchar(1)
select @splitchr=' ' --两个拼音之间的分隔符(目的是为了通用性考虑)
,@i=1,@ilen=len(@str)

select @re=py from YingShe where chr=substring(@str,@i,1)
while @i<@ilen
begin
set @i=@i+1
select top 1 @re=@re+@splitchr+py
from YingShe where chr=substring(@str,@i,1)
end

return(@re)
end
go

--测试
--返回'长城'的所有可能拼音
select * from dbo.f_getpy_tb('长城')

--返回'长城'的拼音
select dbo.f_getpy('长城')

--删除拼音函数
drop function f_getpy,f_getpy_tb

[zjcxc]

--应用案例:

create table MyTable(Name varchar(10),ID int)
insert MyTable select '长城科技',1
union all select '金长城科技',2
union all select '立章城公司',3

go

--查询包含与'长城'拼音一样的记录：
select * from mytable
where exists(select 1 from dbo.f_getpy_tb('长城') where dbo.f_getpy(name) like '%'+re+'%')

--根据汉字首字母查询包含'CC'的记录
select * from mytable where dbo.fgetpy(name) like '%CC%'

[zjcxc]

/*--关于同音字的查询,转一个: j9988(j9988) 的,获得某个汉字的同音字:

原文见:
http://expert.csdn.net/Expert/topic/2352/2352724.xml?temp=.8756067
--*/

create function return_py(@a varchar(100))
returns @b table(string varchar(100))
as
begin
insert @b select chr from YingShe where py in (select py from YingShe where chr=substring(@a,1,1))
set @a=right(@a,len(@a)-1)
while @a<>''
begin
insert @b select string+chr from YingShe B,@b A where py in (select py from YingShe where chr=substring(@a,1,1))
delete @b where len(string)<(select top 1 len(string) from @b order by len(string) desc)
set @a=right(@a,len(@a)-1)
end
return
end

[sdhdy]

好帖，收藏！

[lansquenet]

我的网文快捕都好大一个个的,精华贴,这个一定要加进去

[happydreamer]

好贴

[rockrabbit]

怎么转换输入法编码？创建汉字拼音库？
这个可是比较关键的。
我不会。

[愉快的登山者]

感谢zjcxc (邹建) 的整理。收藏。

[gmlxf]

真的非常感谢。收藏。

[playyuer]

表扬一下

[atlasGS]

收！