如何在VB中备份及恢复SQL数据库,用SQL当后台数据库(请高手给出代码,谢谢!)

hongjiduan 2003-10-17 05:07:51
我是用VB连接SQL数据库的,现在想在VB下通过代码去实现对SQL数据库的备份,而备份可以备份到任何一个磁盘中去,然后又可以从盘中可以再恢复过来,请高手们给出代码,谢谢!
...全文
265 8 打赏 收藏 转发到动态 举报
写回复
用AI写文章
8 条回复
切换为时间正序
请发表友善的回复…
发表回复
阿建像熊猫 2003-10-20
  • 打赏
  • 举报
回复
如何创建数据库备份 (Transact-SQL)
创建数据库备份

执行 BACKUP DATABASE 语句以创建数据库备份,同时指定:
要备份的数据库的名称。


数据库备份将写入的备份设备。
指定(可选):
INIT 子句,通过它可以重写备份媒体,并在备份媒体上将该备份作为第一个文件写入。如果没有现成的媒体头,备份过程将自动写入一个。


SKIP 和 INIT 子句,通过它们可以在备份媒体中仍然存在未失效的备份,或在媒体本身的名称与备份媒体中的名称不匹配时重写备份媒体。


FORMAT 子句,通过它可以在第一次使用媒体时对备份媒体进行完全初始化,并覆盖任何现有的媒体头。
如果已经指定了 FORMAT 子句,则不需要指定 INIT 子句。



重要 当使用 BACKUP 语句的 FORMAT 子句或 INIT 子句时,一定要十分小心,因为它们会破坏以前存储在备份媒体中的所有备份。


示例
下例将整个 MyNwind 数据库备份到磁带上:

USE MyNwind
GO
BACKUP DATABASE MyNwind
TO TAPE = '\\.\Tape0'
WITH FORMAT,
NAME = 'Full Backup of MyNwind'
GO






如何还原数据库备份 (Transact-SQL)
还原数据库备份



重要 还原数据库备份的系统管理员必须是唯一一位当前使用要还原的数据库的人。

执行 RESTORE DATABASE 语句以还原数据库备份,同时指定:
要还原的数据库名称。


要从其中还原数据库备份的备份设备。


NORECOVERY 子句,如果要在还原数据库备份后应用事务日志或差异数据库备份的话。
指定(可选):
FILE 子句,以此标识备份设备上要还原的备份集。
示例
下例从磁带还原 MyNwind 数据库备份:

USE master
GO
RESTORE DATABASE MyNwind
FROM TAPE = '\\.\Tape0'
GO


woshixirui 2003-10-20
  • 打赏
  • 举报
回复
yoki(小马哥):
在数据恢复的时候,显示数据库正在使用,我的其他代码通过ODBC连接,是不是与ODBC有关,请解决该问题。谢谢。
txlicenhe 2003-10-18
  • 打赏
  • 举报
回复
数据库备份/恢复方案
http://expert.csdn.net/Expert/topic/2359/2359124.xml?temp=.3535425
Jackile 2003-10-18
  • 打赏
  • 举报
回复
你真强,全被你说了!
bigpig 2003-10-18
  • 打赏
  • 举报
回复
up
yoki 2003-10-17
  • 打赏
  • 举报
回复
*********************************************************
'* 名称:BackupDatabase
'* 功能:备份数据库
'* 控件:一个文本框和两个按钮(备份到和确定)
'*********************************************************
Public Sub BackupDatabase()
Dim cn As New ADODB.Connection
Dim s_path, s_dataexport As String
s_path = App.Path
Me.MousePointer = 11 '设置鼠标指针形状
'student1是需要备份的数据库名称
s_dataexport = "backup database student1 to disk='" + CommonDialog1.FileName + "'"
cn.Open "driver={sql server};server=" & d1 & ";database=student1;persist security info=false; userid=sa" '数据库连接字符串
'这里不需要连接master数据库,即可完成备份
cn.BeginTrans
cn.Execute s_dataexport
Err.Number = 0
If Err.Number = 0 Then
cn.CommitTrans
MsgBox "数据备份成功!", vbInformation, "提示"
MsgBox "数据备份文件存放路径:" & CommonDialog1.FileName, vbOKOnly, "提示"
Unload Me
Else
cn.RollbackTrans
MsgBox "数据备份失败!请检查数据库是否正在打开!", vbCritical, "提示"
End If
cn.Close
Set cn = Nothing
Me.MousePointer = 1
End Sub



'*********************************************************
'* 名称:RestoreDataBase
'* 功能:还原数据库
'* 控件:一个文本框和两个按钮( 打开和确定)
'*********************************************************
Public Sub RestoreDataBase()
If Text1.Text = "" Then
MsgBox "请选择要恢复的数据文件!", vbInformation, "提示"
Exit Sub
Else
ret = MsgBox("数据恢复操作将会覆盖以前的所有数据并且覆盖后无法恢复,您确定要进行恢复操作吗?", vbQuestion + vbOKCancel, "提示")
If ret = vbOK Then
Dim cn As New ADODB.Connection
Dim sn As New ADODB.Recordset
Dim s_restore As String
Me.MousePointer = 11
cn.Open "Provider=SQLOLEDB.1;Persist Security Info=False;server=" & d1 & ";Initial Catalog=master;Data Source=127.0.0.1;user id=sa;password=" & d3 & ""
sn.Open "select spid from sysprocesses where dbid=db_id('student1')", cn
Do While Not sn.EOF
cn.Execute "kill " & sn("spid")
sn.MoveNext
Loop
sn.Close
s_restore = "restore database student1 from disk='" + Trim(Text1.Text) + "' with REPLACE"
cn.Execute s_restore
'Debug.Print gs_conn_string
'此时需要连接master数据库才能完成数据恢复操作
'同上student1为需要恢复的数据库
s_restore = "restore database student1 from disk='" + Trim(Text1.Text) + "'"
'text1一个用于记录需要恢复文件的地址的textbox
cn.Execute s_restore
cn.BeginTrans
If Err.Number = 0 Then
cn.CommitTrans
MsgBox "数据恢复成功!", vbInformation, "提示"
Command1.Enabled = True
Label1.Visible = False
Else
cn.RollbackTrans
MsgBox "数据恢复失败!", vbCritical, "提示"
Command1.Enabled = True
End If
cn.Close
Set cn = Nothing
Me.MousePointer = 1
Else
Exit Sub
End If '''''''''''''''''''''''''''''''''''''''''
On Error Resume Next
Dim DBC As New DataBaseConnection
If db.State = 1 Then
db.Close
End If
db.ConnectionString = DBC.SqlConnectString(d1, d2, d3)
rs.CursorType = adOpenDynamic
rs.CursorLocation = adUseClient
rs.LockType = adLockOptimistic
db.CursorLocation = adUseClient
db.Open
Set cmd.ActiveConnection = db
If Err.Number Then
MsgBox Err.Description, 16 + vbOKOnly, Err.Number
Exit Sub
End If
db.DefaultDatabase = "student1"
If Err.Number Then
MsgBox Err.Description, 16 + vbOKOnly, Err.Number
Exit Sub
End If
End If
End Sub '''''''''''''''''''''''''''''''''''''''''''''

如果当前没有与要恢复的数据库立连接,则不需要加单引号中的内容。

如果希望恢复数据库之后继续建立连接,则需要写这部分代码。

我要恢复数据库名称为student1,备份数据库的时候是在连接状态下进行的,但是恢复数据库不可以在数据库存在连接的状态下进行操作!代码的解决方法是:先连接SQL Server中主库master 库,在该库中的sysprocesses表中存放着所有连接到此数据库的连接信息,将这些连接信息用Kill语句删除。然后再恢复数据库student1,由于用Kill语句后,数据库已经被断开,所以在恢复完成后,再用系统最初的连接数据库代码连接上数据库student1。
yoki 2003-10-17
  • 打赏
  • 举报
回复
------------------------------------------------------------------
' 代码描述:SQL Server数据库的备份与恢复
'
' 注意事项:1.需要在工程中引用Microsoft SQLDMO Object Library
' 2.备份/恢复数据库时,要保证没有其它用户连接到SQL Server
'
' 窗体控件:2个Command,名称分别为cmdBackup,cmdRestore
' 1个Label,名称为lblProgress,用于显示备份/恢复进程。

'------------------------------------------------------------------
'
Option Explicit

Private WithEvents objBackup As SQLDMO.Backup
Private WithEvents objRestore As SQLDMO.Restore

Private Sub cmdBackup_Click()
Dim objSQLServer As New SQLDMO.SQLServer
Dim strServer As String
Dim strUserID As String
Dim strPassword As String
Dim strDatabase As String
Dim strFile As String

strServer = "Developer"
strUserID = "SA"
strPassword = ""
strDatabase = "Test"
strFile = "c:\test.bak"

If Dir(strFile) <> "" Then
If MsgBox("文件" & strFile & "已存在,是否删除?", vbQuestion + vbYesNo) = vbYes Then
Kill strFile
Else
Exit Sub
End If
End If

lblProgress.Caption = "备份进度: 0%"
Screen.MousePointer = 11

On Error GoTo ErrorHandler

objSQLServer.Connect strServer, strUserID, strPassword

Set objBackup = New SQLDMO.Backup
With objBackup
.PercentCompleteNotification = 1
.Database = strDatabase
.Files = strFile
.SQLBackup objSQLServer
End With
Set objBackup = Nothing

objSQLServer.Close
Set objSQLServer = Nothing

Screen.MousePointer = 0
Exit Sub

ErrorHandler:
Screen.MousePointer = 0
MsgBox Err.Description, vbCritical
End Sub

Private Sub cmdRestore_Click()
Dim objSQLServer As New SQLDMO.SQLServer
Dim strServer As String
Dim strUserID As String
Dim strPassword As String
Dim strDatabase As String
Dim strFile As String

strServer = "Developer"
strUserID = "SA"
strPassword = ""
strDatabase = "Test"
strFile = "c:\test.bak"

If Dir(strFile) = "" Then
MsgBox "文件" & strFile & "不存在!", vbExclamation
Exit Sub
End If

lblProgress.Caption = "恢复进度: 0%"
Screen.MousePointer = 11

On Error GoTo ErrorHandler

objSQLServer.Connect strServer, strUserID, strPassword

Set objRestore = New SQLDMO.Restore
With objRestore
.PercentCompleteNotification = 1
.Database = strDatabase
.ReplaceDatabase = True
.Files = strFile
.SQLRestore objSQLServer
End With
Set objRestore = Nothing

objSQLServer.Close
Set objSQLServer = Nothing

Screen.MousePointer = 0
Exit Sub

ErrorHandler:
Screen.MousePointer = 0
MsgBox Err.Description, vbCritical
End Sub

Private Sub objBackup_Complete(ByVal Message As String)
lblProgress.Caption = "备份成功!"
Set objBackup = Nothing
End Sub

Private Sub objBackup_PercentComplete(ByVal Message As String, ByVal Percent As Long)
lblProgress.Caption = "备份进度: " & Percent & "%"
DoEvents
End Sub

Private Sub objRestore_Complete(ByVal Message As String)
lblProgress.Caption = "恢复成功!"
Set objRestore = Nothing
End Sub

Private Sub objRestore_PercentComplete(ByVal Message As String, ByVal Percent As Long)
lblProgress.Caption = "恢复进度: " & Percent & "%"
DoEvents
End Sub

'备份数据库

'需要添加一个commoldialog控件
Sub backDataBase()
On Error GoTo errnum
dlg.CancelError = True
Cn1.Execute "use master"
dlg.Filter = "(*.bak)|*.bak"
dlg.ShowSave
MousePointer = 11
Cn1.Execute "BACKUP DATABASE kffgl TO DISK = '" & dlg.FileName & "'" '备份数据库
MousePointer = 0
Set Cn1 = Nothing
'重新建立连接
errnum:


Call dbint
Set Cn1 = New ADODB.Connection
Cn1.Open "Driver={SQL Server};Server=" & SQL_SRV & ";Uid=" & SA & ";Pwd=" & PA & ";Database=" & SJK & ""
End Sub



用SQLDMO实现备份




添加进度条ProgressBar1控件
引用Microsoft SQLDMO Object Library

'声明
Public WithEvents bkps As SQLDMO.Backup
'数据库备份操作
Private Sub Command3_Click()
Dim oSvr As SQLDMO.SQLServer
Set oSQLServer = CreateObject("SQLDMO.SQLServer")
oSQLServer.LoginSecure = False
oSQLServer.Connect ("(local)"), ("sa"), ("")'连接服务器
Screen.MousePointer = 11
Set bkps = CreateObject("SQLDMO.Backup")
bkps.Database = "db"'指定需备份的数据库
bkps.Action = 0
bkps.Files = "c:\backup\db.bak"'指定备份文件
bkps.Initialize = True
ProgressBar1.Value = 0
ProgressBar1.max = 100
Screen.MousePointer = 0
DoEvents
Err = 0
bkps.SQLBackup oSQLServer
Screen.MousePointer = 11
ProgressBar1.Value = 100
DoEvents
Set bkps = Nothing
Screen.MousePointer = 0
MsgBox "数据库备份完成"
End Sub
'显示进度
Private Sub bkps_PercentComplete(ByVal Message As String, ByVal Percent As Long)
ProgressBar1.Value = ProgressBar1.max * (Percent / 100)
End Sub

备份时ProgressBar1显示进度,恢复操作方法相同。
gs_luoqiang 2003-10-17
  • 打赏
  • 举报
回复
把服务停掉然后拷贝就可以了

1,216

社区成员

发帖
与我相关
我的任务
社区描述
VB 数据库(包含打印,安装,报表)
社区管理员
  • 数据库(包含打印,安装,报表)社区
加入社区
  • 近7日
  • 近30日
  • 至今
社区公告
暂无公告

试试用AI创作助手写篇文章吧