如何将图象保存到access数据库里？？？

[doubleh]

如何将图象保存到access数据库里？？？
SQL语句怎么写的？

[lihonggen0]

通过ado stream存入图象,参考:
http://support.microsoft.com/default.aspx?scid=kb;EN-US;258038

[online]

'** 引用 Microsoft ActiveX Data Objects 2.5 Library 及以上版本
Dim iConcstr As String
Dim iConc As ADODB.Connection

'保存文件到数据库中
Sub s_SaveFile()
Dim iStm As ADODB.Stream
Dim iRe As ADODB.Recordset
Dim iConcstr As String

'读取文件到内容
Set iStm = New ADODB.Stream
With iStm
.Type = adTypeBinary '二进制模式
.Open
.LoadFromFile App.Path + "\a.bmp"
End With

'打开保存文件的表
Set iRe = New ADODB.Recordset
With iRe
.Open "select * from img", iConc, 1, 3
.AddNew '新增一条记录
.Fields("photo") = iStm.Read
.Update
End With

'完成后关闭对象
iRe.Close
iStm.Close
End Sub

Sub s_ReadFile()
Dim iStm As ADODB.Stream
Dim iRe As ADODB.Recordset


'打开表
Set iRe = New ADODB.Recordset
iRe.Open "select * from img", iConc, adOpenKeyset, adLockReadOnly
iRe.Filter = "id=1"

'保存到文件
Set iStm = New ADODB.Stream
With iStm
.Mode = adModeReadWrite
.Type = adTypeBinary
.Open
.Write iRe("photo")
.SaveToFile App.Path & "\b.bmp"
End With

'关闭对象
iRe.Close
iStm.Close
End Sub

Private Sub Command1_Click()
Call s_ReadFile
End Sub

Private Sub Command2_Click()
Call s_SaveFile
End Sub

Private Sub Form_Load()
'数据库连接字符串
iConcstr = "Provider=Microsoft.Jet.OLEDB.4.0;Persist Security Info=False" & _
";Data Source=F:\csdn_vb\database\保存图片\access\img.mdb"

Set iConc = New ADODB.Connection
iConc.Open iConcstr
End Sub

[lihonggen0]

在数据库版回答了

[cwm545]

我觉得定义一个路径，存到数据库里，把图片文件上传到硬盘里，那样更快。
以前在ASP下经常这样做，VB也是一样的。

[bluesky23]

楼上所说的做法对远程访问不方便。