如何在InstallShield使用密码编辑框？分数一定如数奉上！

[bcai]

对于vc高手而言，InstallShield应该是必然精通的吧。小弟最近在使用IntallShield过程中，发现InstallShield的Script Dialog的函数不能直接提供密码编辑框功能，而InstallShield的帮助文档和例程并没有提供足够好的说明（当然本人的英文也只是一般），希望有使用过密码编辑框的大虾伸出援助之手，不胜感激！

[bcai]

您可能误会我意思了,使用SdRegisterUserEx是可以看到序列号的,我要求的是不能看到序列号,譬如输入123,显示成***.不知道InstallShield支不支持密码编辑框,有人知道么?

[bcai]

关注!

[bcai]

没人知道么?

[ccom]

通过installshield提供的对话框模板
你可以订制自己的对话框,也就可以加入自己的password属性的编辑框了
参见教程
http://www2.yesky.com/34603008/154189.shtml

[bcai]

分给了,但答案还是不让我非常满意,sigh!

[bcai]

关注！

[code_cold]

Dlg_SdRegisterUserEx:
szMsg = "";
szTitle = "";
SetTitle("电子助教安装程序", 0, BACKGROUNDCAPTION );
nResult = SdRegisterUserEx( szTitle, szMsg, szName, szCompany, szSerial );

if(szSerial != "序列号码" && nResult != BACK) then
MessageBox("序列号错误，请从新输入", WARNING);
goto Dlg_SdRegisterUserEx;
endif;

if (nResult = BACK) goto Dlg_Start;

[PerfectCK]

我遇到过这个问题，我是这样解决的：
prototype LoginDBDlg (BYREF STRING,BYREF STRING,BYREF STRING,BYREF STRING,BYREF STRING,BYREF STRING,BYREF STRING,BYREF STRING);

prototype HWND user32.GetDlgItem(HWND,INT);
prototype LONG user32.SetWindowLong(HWND,INT,LONG);
prototype LONG user32.GetWindowLong(HWND,INT);


function LoginDBDlg( szTitle, szMsg, szField1, szField2, szField3, svEdit1, svEdit2, svEdit3 )
STRING szDlg, szTemp,CKtmp,CKEdit,strTemp,SetEditText;
NUMBER nId, nMessage, nTemp,nSdDialog,i;
HWND hwndDlg,CKwnd,CCwnd;
BOOL bDone;
begin

svEdit3="";
szDlg = SD_DLG_SHOWDLGEDIT3;
nSdDialog = SD_NDLG_SHOWDLGEDIT3;

if (MODE=SILENTMODE) then
SdMakeName( szAppKey, szDlg, szTitle, nSdShowDlgEdit3 );
SilentReadData( szAppKey, "Result", DATA_NUMBER, szTemp, nId );
if ((nId != BACK) && (nId != CANCEL)) then
SilentReadData( szAppKey, "szEdit1", DATA_STRING, svEdit1, nTemp );
SilentReadData( szAppKey, "szEdit2", DATA_STRING, svEdit2, nTemp );
SilentReadData( szAppKey, "szEdit3", DATA_STRING, svEdit3, nTemp );
endif;

return nId;
endif;

if (!bSdInit) then
SdInit();
endif;

if (EzDefineDialog( szDlg, "", "", SD_NDLG_SHOWDLGEDIT3 ) = DLG_ERR) then
return -1;
endif;


bDone = FALSE;

while (!bDone)

nId = WaitOnDialog( szDlg );

switch (nId)
case DLG_INIT:
if( szMsg != "" ) then
SdSetStatic(szDlg, SD_STA_MSG1, szMsg);
endif;

if( szField1 != "" ) then
SdSetStatic(szDlg, SD_STA_FIELD1, szField1 );
endif;

if( szField2 != "" ) then
SdSetStatic(szDlg, SD_STA_FIELD2, szField2 );
endif;

if( szField3 != "" ) then
SdSetStatic(szDlg, SD_STA_FIELD3, szField3 );
endif;

CtrlSetText(szDlg, SD_EDIT1, svEdit1);
CtrlSetText(szDlg, SD_EDIT2, svEdit2);
CtrlSetText(szDlg, SD_EDIT3, svEdit3);

hwndDlg = CmdGetHwndDlg( szDlg );
SdGeneralInit( szDlg, hwndDlg, STYLE_BOLD, szSdProduct );

if(szTitle != "") then
SetWindowText(hwndDlg, szTitle);
endif;

CCwnd=FindWindow("","输入数据库信息");
CKwnd=user32.GetDlgItem(CCwnd,303);

SendMessage(CKwnd,204,42,0);

case SD_EDIT1:
nMessage = CtrlGetSubCommand(szDlg);

if(nMessage = EDITBOX_CHANGE) then
CtrlGetText(szDlg, SD_EDIT1, svEdit1);
endif;

case SD_EDIT2:
nMessage = CtrlGetSubCommand(szDlg);

if(nMessage = EDITBOX_CHANGE) then
CtrlGetText(szDlg, SD_EDIT2, svEdit2);
endif;

case SD_EDIT3:
nMessage = CtrlGetSubCommand(szDlg);

if (nMessage=EDITBOX_CHANGE) then
CtrlGetText(szDlg,SD_EDIT3,svEdit3);
endif;

case SD_PBUT_OK:
CKEdit="";
strTemp="";
nId = OK;
bDone = TRUE;

case BACK:
svEdit3="";
CKEdit="";
strTemp="";
nId = BACK;
bDone = TRUE;

case DLG_ERR:
svEdit3="";
CKEdit="";
strTemp="";
SdError( -1, "SdShowEdit3" );
nId = -1;
bDone = TRUE;

case DLG_CLOSE:
SdCloseDlg( hwndDlg, nId, bDone );

default:
if (SdIsStdButton( nId ) && SdDoStdButton( nId )) then
bDone = TRUE;
endif;
endswitch;

endwhile;

//关闭对话框
EndDialog( szDlg );
//释放内存
ReleaseDialog( szDlg );

SdUnInit( );

SdMakeName( szAppKey, szDlg, szTitle, nSdShowDlgEdit3 );
SilentWriteData( szAppKey, "szEdit1", DATA_STRING, svEdit1, 0 );
SilentWriteData( szAppKey, "szEdit2", DATA_STRING, svEdit2, 0 );
SilentWriteData( szAppKey, "szEdit3", DATA_STRING, svEdit3, 0 );
SilentWriteData( szAppKey, "Result", DATA_NUMBER, "", nId );

return nId;

end;