有谁知道:=在VB里是什么意思？MSDN里没有说明

[matboy]

急！

[MilkyWaySoft]

?没有吧？

[xdd1125]

是指命名参数，用它可以不按照sub或function中的参数顺序给参数赋值

[xdd1125]

在MSDN中有很多这样的语句：
Does not support NAMED PARAMETERS
就是有些函数不支持命名参数

[sonicdater]

' If a function's arguments are defined as follows:
Function MyFunc(MyStr As String, Optional MyArg1 As _ Integer = 5, Optional MyArg2 = "Dolly")
Dim RetVal
' The function can be invoked as follows:
RetVal = MyFunc("Hello", 2, "World") ' All 3 arguments supplied.
RetVal = MyFunc("Test", , 5) ' Second argument omitted.
' Arguments one and three using named-arguments.

RetVal = MyFunc(MyStr:="Hello ", MyArg1:=7)
~~~~~~~~~~~~~~~~~~~~~~
你是指 上面的 := 吧?
那是 因为在 函数 声明时, 函数中的 参数前面加了 关键字 Optional
如:
Function MyFunc(MyStr As String, Optional MyArg1 As _ Integer = 5, Optional MyArg2 = "Dolly")

==================================================================
表示对可选 参数符值.
具体请 查阅 MSDN - VB6- 参考- 关键字: Optional

[sonicdater]

' If a function's arguments are defined as follows:
Function MyFunc(MyStr As String, Optional MyArg1 As _ Integer = 5, Optional MyArg2 = "Dolly")
Dim RetVal
' The function can be invoked as follows:
RetVal = MyFunc("Hello", 2, "World") ' All 3 arguments supplied.
RetVal = MyFunc("Test", , 5) ' Second argument omitted.
' Arguments one and three using named-arguments.

RetVal = MyFunc(MyStr:="Hello ", MyArg1:=7)
~~~~~~~~~~~~~~~~~~~~~~
你是指 上面的 := 吧?
那是 因为在 函数 声明时, 函数中的 参数前面加了 关键字 Optional
如:
Function MyFunc(MyStr As String, Optional MyArg1 As _ Integer = 5, Optional MyArg2 = "Dolly")

==================================================================
表示对可选 参数符值.
具体请 查阅 MSDN - VB6- 参考- 关键字: Optional

[matboy]

xdd1125(成长快乐) 兄，能否举个例子讲解一下？
这是我从书上搬来的代码，请您解释一下，小弟先谢过了！
Private Sub Command1_Click()
Set wd = New Word.Application
'产生一个word执行个体
'
'如果没有word8.0 object lib 则改用这行 Set wd = CreateObject("word.application")
Set ww = wd.Documents.Open("D:\test.doc")
'开启WORD事先造出之套版
'移到下一个TABLE所在位置，因是第一次呼叫，所以会是TABLES（1）
With wd
.Selection.GoTo WHAT:=wdGoToTable, WHICH:=wdGoToNext, Count:=1, Name:=""
.Selection.Move unit:=wdRow, Count:=3
'以ROW为单位向下移3个储存格

.Selection.MoveDown unit:=wdLine, Count:=3
'以LINE为单位向下移3行，如果一个CELL是
'MULTILINE时，会先在同一格移动
.Selection.MoveRight unit:=wdCell '向右移一行
.Selection.TypeText Text:="第一格"
.Selection.MoveRight unit:=wdCell
.Selection.TypeText Text:="第二格"
.Selection.Cells.VerticalAlignment = wdCellAlignVerticalCenter
.Selection.MoveRight unit:=wdCell
.Selection.TypeText Text:="第三格"
.Selection.MoveRight unit:=wdCell
.Selection.TypeText Text:="第四格"

.Selection.MoveRight unit:=wdCell
' 已到表格最右，故该指令会新增一个ROW
.Selection.TypeText Text:="NewLine" + vbCrLf + "2'line"
ww.Tables(1).Select
'选取全部表格
.Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
'设定文字居中
.Selection.MoveDown unit:=wdLine
'只是为了让选取消失
ww.SaveAs FileName:="NewFile"
'另存新档
MsgBox "create table OK", vbInformation
'如果想让WORD97能显示出来，要执行以下两行
.Visible = True
AppActivate wd.Application.Caption
'令VSIAL BASIC 的执行停在这里，否则WORD97马上会被以下指令所结束
MsgBox "press any key to close word", vbInformation
ww.Close savechanges:=False
wd.Quit savechanges:=False
'离开WORD97且不存档
End With
Set ww = Nothing
Set wd = Nothing

End Sub

[dbcontrols]

VBA里面的东西

[Ninputer]

:= 用于名称结合的参数传递。参数传递通常方式是位置结合，如
Function Test(A, B, C)
调用：Test(1, 2, 3)这时 A = 1, B = 2, C =3。但有时很多参数都是可选的，只需要其中一的传递时，可采用VB独有的名称结合方式，如
Function Test([A], [B], [C])
调用 Test(C:=3），就表示C = 3，其他参数使用缺省值

[giggs1984]

是VB中的参数传送的一个关键字，在新建的Sub 或Function中的形式参数，与之相对的实际参数不是要和它位置保持一致吗，用“：=”就可以打乱其顺序传值。

[vicon]

吉格斯說得好像有點道理.

[shawls]

Ninputer(装配脑袋) ( ) 信誉：100 2002-3-6 16:31:25 得分:0


:= 用于名称结合的参数传递。参数传递通常方式是位置结合，如
Function Test(A, B, C)
调用：Test(1, 2, 3)这时 A = 1, B = 2, C =3。但有时很多参数都是可选的，只需要其中一的传递时，可采用VB独有的名称结合方式，如
Function Test([A], [B], [C])
调用 Test(C:=3），就表示C = 3，其他参数使用缺省值


又学了知识！！


这些基本东西我还真的不知道！

[matboy]

感谢各位的帮助！特别谢谢几位得分的朋友！分少，各位原谅！