大家把自己知道的强大的API 函数SendMessage的应用例子贴出来

[zcb2000]

比如，怎样为列表框加入水平滚动条，使文本框只读，。。。

[山卜居士]

在ListBox自动查找:
'This project needs a ListBox, named List1 and a TextBox, named Text1
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As Any) As Long
Const LB_FINDSTRING = &H18F
Private Sub Form_Load()
'KPD-Team 1998
'URL: http://www.allapi.net/
'E-Mail: [e-mail]
'Add some items to the listbox
With List1
.AddItem "Computer"
.AddItem "Screen"
.AddItem "Modem"
.AddItem "Printer"
.AddItem "Scanner"
.AddItem "Sound Blaster"
.AddItem "Keyboard"
.AddItem "CD-Rom"
.AddItem "Mouse"
End With
End Sub
Private Sub Text1_Change()
'Retrieve the item's listindex
List1.ListIndex = SendMessage(List1.hwnd, LB_FINDSTRING, -1, ByVal CStr(Text1.Text))
End Sub

[zyl910]

1.Call SendMessage(List_hWnd, LB_SETHORIZONTALEXTENT, 长度, ByVal 0&)

[TechnoFantasy]

SendMessage函数应用技巧之一（斑竹作品）
本文介绍如何利用SendMessage函数向特定类的窗口（文本 、列表框）发送消息实现对窗口的定制。这篇讲的是ListBox的消息。
http://www.applevb.com/art/tg1.txt


SendMessage函数应用技巧之二（斑竹作品）
本文介绍如何利用SendMessage函数向特定类的窗口（文本 、列表框）发送消息实现对窗口的定制。这篇讲的是TextBox的消息。
http://www.applevb.com/art/tg2.txt


SendMessage函数应用技巧之三（斑竹作品）
本文介绍如何利用SendMessage函数向特定类的窗口（文本 、列表框）发送消息实现对窗口的定制。这篇讲的是TreeView的消息。
http://www.applevb.com/art/tg3.txt

SendMessage函数应用技巧之四（斑竹作品）
本文介绍如何利用SendMessage函数向特定类的窗口（文本 、列表框）发送消息实现对窗口的定制。这篇讲的是ListView的消息。
http://www.applevb.com/art/tg4.txt

[zyl910]

建议看MSDN，找“WM_”、“EM_”、……开头的！

[lihonggen0]

用SendMessage函数实现VB程序的查询功能
作者：土人
在API文本浏览器里，当我们在搜索栏输入任意字母，“可用项”里以该字母开头的项目以高亮显示以引起我们注意该项是不是我们所需的。象这样的功能一切提供搜索选项的程序都应该具备。以下例子采用SendMessage函数实现这一技术。
请给标准工程添加ListBox和TextBox控件各一个，其各项属性均取默认值，然后将下列代码拷贝到你的工程：

Option Explicit

'申明API函数
Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Integer, ByVal lParam As Any) As Long

Const LB_FINDSTRING = &H18F '常数

Private Sub Form_Load()

'给列表框添加26个字母（大写）
Dim i As Integer
For i = Asc("A") To Asc("Z")
List1.AddItem Chr$(i)
Next
Text1 = "" '令文本框为空

End Sub

Private Sub Text1_KeyPress(KeyAscii As Integer)

Text1 = "" '按下任意键则令原内容消失
Text1.SelLength = 1 '限制长度
Text1.SelText = Chr(KeyAscii) '显示键盘符号
KeyAscii = 0 '禁止响铃
'ListBox中的项目文本若与文本框的一致则选中(高亮)
List1.ListIndex = SendMessage(List1.hwnd, LB_FINDSTRING, -1, ByVal CStr(Text1.Text))

End Sub

以上程序适用于单项目为多个字母的查询，但必须注意，在TextBox的KeyPress事件中要作相应的改动。

[lihonggen0]

功能强大的SendMessage函数
Windows API（应用程序接口）是Windows系列软件为程序开发人员提供的火力强大的“武器库”，在这个武器库中，有很多极具威力的武器，SendMessage就是其中之一，它的功能非常丰富，灵活使用这个函数，会给编程工作带来很多便利。本文以Visual Basic为例，结合几个具体的例子介绍该函数的功能。
一、SendMeaasge函数简介
顾名思义，SendMessage函数的功能是“发送消息”，即将一条消息发送到指定对象（操作系统、窗口或控件等）上，以产生特定的动作（如滚屏、修改对象外观等）。
SendMessage函数在VB中的函数说明如下：
Declare Function SendMessage Lib "user32" Alias "SendMessageA" (Byval hwnd As Long, Byval wMsg As Long,Byval wParam As Long,lParam As Any) As Long
其中四个自变量的含义和说明如下：
hWnd：对象的句柄。希望将消息传送给哪个对象，就把该对象的句柄作为实参传送，在VB中可以简单地用“对象.hWnd”获得某个对象的句柄，如Text1.hWnd和Form1.hWnd分别可以得到Text1和Form1的句柄。
wMsg：被发送的消息。根据具体需求和不同的对象，将不同的消息作为实参传送，以产生预期的动作。
wParam、lParam：附加的消息信息。这两个是可选的参数，用来提供关于wMsg消息更多的信息，不同的wMsg可能使用这两个参数中的0、1或2个，如果不需要哪个附加参数，则将实参赋为NULL（在VB中赋为0）。
在简单了解了SendMessage函数的格式和功能后，让我们以几个例子来看看它的威力。
二、SendMessage函数使用实例
例1 多行TextBox中的快速处理功能在处理多行TextBox时我们经常会碰到以下几种情况：
希望了解多行TextBox中目前共有多少行文字。
想快速返回第N行的文字。
对于上面的情况，如果用VB自身的语句或函数来实现的话，要写不短的代码，而且由于要采用顺序查找的办法来完成，因此代码的执行效率也很低。如果使用SendMessage函数则可以大大减少代码量，并大幅度的提高执行效率。
用SendMessage函数完成上面两个任务的方法非常简单，每个任务只需简单地发送一条消息给多行TextBox即可，两个消息分别为：EM_GETLINECOUNT、EM_GETLINE，其它参数和返回值见附表。
下面用一个简单的实例演示这两个功能：
新建工程，在Form1上添加三个TextBox（名称分别为Text1、txtLineCount、TxtString，将Text1的Multi
Line属性置为True）、三个标签和一个命令按钮。为工程添加一个模块Moudle1，在其中写如下声明（其中
SendMessage函数的声明可以从VB的“API浏览器”中复制）： 消息常量名 消息值 wParam lParam 返回值
EM_GETLINECOUNT &HBA 未用 未用 行数
EM_GETLINE &HC4 要找的行号 存结果的字节串 结果字节串的字节数

Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long,lParam As Any) As Long
Public Const EM_GETLINECOUNT=&HBA
Public Const EM_GETLINE=&HC4
在Form1的代码模块中写如下代码：
Private Sub Command1_Click()
Dim str(256) As Byte
str(1)=1 '最大允许存放256个字符
'获取总行数，结果显示在文本框txtLineCount中
txtlineCount=SendMessage(Text1.hwnd,EM_GETLINECOUNT,0,0)
'获取第3行的数据放在str中，转换为字符串后显示在文本框txtString中
SendMessage Text1.hwnd,EM_GETLINE,2,str(0)
txtString= StrConv(str,vbUnicode)
End Sub
之后，按F5运行程序，在多行文本框中随便键入几行文字，然后按下[确定]按钮，说明程序正确统计出了总行数和第3行的文字。


两点补充说明：在调用SendMessage获取第N行字符串时，lParam需要说明为字节数组，在调用完成后，再将字节数组转换为字符串；另外，调用前必须在lParam的前两个字节指明允许存放的最大长度，其中第一个字节为低位，第二个字节为高位，本例将高位（即str(1)）置1．说明最大允许存放256个字符。
例2 程序控制拉下或收起组合框的下拉列来
一般情况下，为了拉下或收起组合框的下拉列表，需要用键盘或鼠标进行操作，而有时我们希望程序运行的某个时刻自动拉出下拉列表（比如在一些演示程序中），为了实现这个目的，我们也只有借助于SendMessage函数，方法是发一个CB_SHOWDROPDOWN(&H14F)消息给组合框。
在发CB_SHOWDROPDOWN消息时，wParam参数决定了是拉下列表（=True时）还是收起列表（＝False时），lParam无用（设为0）。
为说明具体的使用方法，下面提供简单的程序片段。首先在代码模块中做如下声明：
Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long,ByVal wMsg As Long，ByVal wParam As Long,lParam As Any) As Long
Const CB_SHOWDROPDOWN=&H14F
当程序中某处需要拉下组合框Combol的列表时，写如下调用语句：
SendMessage Combol.hwnd,CB_SHOWDROPDOWN,True,0
当需要收起组合框Combol的列表时，写如下语句：
SendMessage Combol.hwnd,CB_SHOWDROPDOWNN,False,0
例3 在列表框中查找匹配的项目
在Win95风格的帮助系统中一般都有一个“索引”页，索引页含有一个文本框和一个列表框，当用户在文本框中输入文字时，下拉列表会动态地显示与文本框中文字最匹配的项目，为用户提供了最大的方便。这种效果在应用程序的帮助系统中很容易实现（只要按照Win95帮助系统的正常制作过程制作就可以实现），如果想在应用程序的其它地方实现这种特性就需费一番心思了。
而使用SendMessage函数实现上述特性则非常简单，甚至只需一条语句就足够了，那就是在文本框的Change事件中给列表框发一条LB_FINDSTRING(&H18F）消息，该消息告诉列表框在列表中查找匹配的项目。
在发LB_FINDSTRING消息时，wParam参数代表从列表框的哪一个项目后面开始查找，一般情况下该参数可定为-1，表示从List1(0)即第一项开始向后循环查找，lParam则传进欲搜索的字符串（必须采用值传递）。
具体的代码和运行画面与后面的例4合并在一起演示。
例4 为ListBox添加水平滚动条
在VB中，列表框控件仅提供垂直滚动条，没有设置水平滚动条的能力，当某些项目的文本宽度较长时，超出列表框宽度部分的文本就无法显示出来，因此，很有必要为ListBox添加一个水平滚动条来方便操作。
为添加水平滚动条，只需发一条LB_SETHORIZONTALEXTENT(&H194)消息给列表框即可。发送消息时，wParam为滚动条的长度（以像素为单位，可通过计算得出准确的长度，也可随便给一个大于最大文本宽度的数字，如本例的250），lParam无用。下面是例3和例4合并在一起的代码和运行画面


Declare Function SendMessage Lib "user32" Alias "SendMessageA"(ByVal hwnd As Long,ByVal wMsg As Long,ByVal wParam As Long,lParam As Any) As Long
Public Const LB_FINDSTRING=&H18F
Public Const LB_SETHORIZONTALEXTENT=&H194
Private Sub Form_Load()
List1.AddItem "软件"
List1.AddItem "电脑游戏"
List1.AddItem "电视机"
List1.AddItem "电视台"
List1.AddItem "电脑"
List1.AddItem "电脑游戏软件"
'下一句为列表框添加水平滚动条
SendMessage List1.hwnd,LB_SETHORIZONTALEXTENT,250,0
End Sub
Private Sub Text1_Change()
'注意！当lParam传入的是字符串时，必须用ByVal传递
List1.ListIndex ＝ SendMessage(List1.hwnd,LB_FINDSTRING,-1,ByVal Text1.Text)
End Sub
通过上面几个例子，想必您已经对SendMessage函数的强大功能有了初步的了解。事实上利用该函数我们还可以完成更多更好的任务，如控制文本框的自动滚屏、实现文字编辑过程中的Undo功能、操纵应用程序的窗体控制菜单等等，感兴趣的读者请参阅有关Windows API的资料。
本文程序均用Visual Basic 5.0企业版编写，在Pwin95环境下运行正常。

[fangyds]

'从当前行的行首选择文本到光标当前位置
Dim cursorPos As Long '装载指针位置
Dim currLine As Long '装载当前所在行
Dim chrsToCurrent As Long
Dim TxtHwnd As Long '装载文本框的句柄

On Local Error Resume Next

'获得文本框的句柄
TxtHwnd = Me.ActiveForm.RichTextBox1.hwnd

'获得指针在文本框中的位置
cursorPos = SendMessage(TxtHwnd, EM_GETSEL, 0, ByVal 0&) \ &H10000

'获得当前行
currLine = SendMessage(TxtHwnd, EM_LINEFROMCHAR, cursorPos, ByVal 0&) ' + 1

'获得当前行上面的字符数
chrsToCurrent = SendMessage(TxtHwnd, EM_LINEINDEX, currLine, ByVal 0&)

'从当前行的行首选择到当前指针位置
Me.ActiveForm.RichTextBox1.SetFocus
Call SendMessage(TxtHwnd, EM_SETSEL, chrsToCurrent, ByVal cursorPos)


'从当前光标当前位置选择文本到当前行的行尾
Dim cursorPos As Long '装载指针位置
Dim currLine As Long '装载当前所在行
Dim chrsToCurrent As Long '装载当前指针位置到行尾的长度
Dim TxtHwnd As Long '装载文本框的句柄

On Local Error Resume Next

'获得文本框的句柄
TxtHwnd = Me.ActiveForm.RichTextBox1.hwnd

'获得文本框中指针的当前位置
cursorPos = SendMessage(TxtHwnd, EM_GETSEL, 0, ByVal 0&) \ &H10000

'获得当前行的行号
currLine = SendMessage(TxtHwnd, EM_LINEFROMCHAR, cursorPos, ByVal 0&)

'获得当前位置到下一行的长度
chrsToCurrent = SendMessage(TxtHwnd, EM_LINEINDEX, currLine + 1, ByVal 0&)

'从当前位置选择到当前行的行尾，为了使指针停留在当前行必须减1
Me.ActiveForm.RichTextBox1.SetFocus
Call SendMessage(TxtHwnd, EM_SETSEL, cursorPos, ByVal chrsToCurrent - 1)

'选择当前行
Dim cursorPos As Long '装载指针位置
Dim currLine As Long '装载当前行的行号
Dim chrsToStart As Long '装载当前位置到行首的长度
Dim chrsToEnd As Long '装载当前位置到下一行的长度
Dim TxtHwnd As Long '装载文本框的句柄

On Local Error Resume Next

'获得文本框的句柄
TxtHwnd = Me.ActiveForm.RichTextBox1.hwnd

'获得文本框中指针的位置
cursorPos = SendMessage(TxtHwnd, EM_GETSEL, 0, ByVal 0&) \ &H10000

'获得当前行的行号
currLine = SendMessage(TxtHwnd, EM_LINEFROMCHAR, cursorPos, ByVal 0&)

'获得当前位置到行首的长度
chrsToStart = SendMessage(TxtHwnd, EM_LINEINDEX, currLine, ByVal 0&)

'获得当前位置到下一行的长度
chrsToEnd = SendMessage(TxtHwnd, EM_LINEINDEX, currLine + 1, ByVal 0&)

'选择当前行，为使指针停留在当前行必须减1
Me.ActiveForm.RichTextBox1.SetFocus
Call SendMessage(TxtHwnd, EM_SETSEL, chrsToStart, ByVal chrsToEnd - 1)

[fangyds]

'从当前光标位置选择文本到文件尾
Dim cursorPos As Long '装载指针位置
Dim lineCount As Long '装载文本框中内容的总行数
Dim ChrsUpToLast As Long
Dim lastLineLen As Long
Dim TxtHwnd As Long '装载文本框的句柄
On Local Error Resume Next

'获得文本框的句柄
TxtHwnd = Me.ActiveForm.RichTextBox1.hwnd

'获得指针在文本框中的位置
cursorPos = SendMessage(TxtHwnd, EM_GETSEL, 0, ByVal 0&) \ &H10000

'获得文本框中内容的总行数
lineCount = SendMessage(TxtHwnd, EM_GETLINECOUNT, 0, ByVal 0&)

'获得字符在文本框中的哪一行，直到最后但不包括最后一行
ChrsUpToLast = SendMessage(TxtHwnd, EM_LINEINDEX, lineCount - 1, ByVal 0&)

'字符在最后一行
lastLineLen = SendMessage(TxtHwnd, EM_LINELENGTH, lineCount, ByVal 0&)

'从光标位置开始一直选择到最后一行
Me.ActiveForm.RichTextBox1.SetFocus
Call SendMessage(TxtHwnd, EM_SETSEL, cursorPos, ByVal ChrsUpToLast + lastLineLen)


'为LISTBOX设置水平滚动条(可自动计算滚动的长度)
Dim c As Long
Dim rcText As RECT
Dim newWidth As Long
Dim itemWidth As Long
Dim sysScrollWidth As Long
sysScrollWidth = GetSystemMetrics(SM_CXVSCROLL)
For c = 0 To ListName.ListCount - 1
DrawText Me.hDC, (ListName.List(c)), -1&, rcText, DT_CALCRECT
itemWidth = rcText.Right + sysScrollWidth
If itemWidth >= newWidth Then
newWidth = itemWidth
End If
Next
SendMessage ListName.hwnd, LB_SETHORIZONTALEXTENT, newWidth, ByVal 0&


'窗口总在最前
SetWindowPos Me.hwnd, HWND_TOPMOST, 0, 0, 0, 0, _
SWP_SHOWWINDOW Or SWP_NOSIZE Or SWP_NOMOVE
'取消窗口总在最前
SetWindowPos Me.hwnd, HWND_NOTOPMOST, 0, 0, 0, 0, _
SWP_SHOWWINDOW Or SWP_NOSIZE Or SWP_NOMOVE


'滚动文本框内容
Dim success As Long
Dim SavedWnd As Long
Dim R As Long
Dim moveLines As Long

'save the window handle of the control that currently has focus
SavedWnd = Screen.ActiveForm.hwnd
moveLines = vLines

'Set the focus to the passed control (text control)
TextBox.SetFocus

'Scroll the lines.
success = SendMessageLong(TextBox.hwnd, EM_LINESCROLL, 0, moveLines)

'Restore the focus to the original control
R = PutFocus(SavedWnd)

'Return the number of lines actually scrolled
ScrollText = success