dos启动盘的问题

[alulu3721]

本人想做一张像win98启动盘那样，将程序放在一个压缩包里，引导时自解压到虚拟磁盘里，请问批处理怎样检索最后盘符，并虚拟一个磁盘。请给我批处理代码。

[alulu3721]

我发现win98启动盘有个批处理程序是专门用来检测系统最后一个盘符的，这样就可以接着最后一个盘符后面虚拟磁盘，我想知道它怎样找到并虚拟最后一个盘符的。

[icemanpro]

在win98下做一个启动盘后，将你所需要的软件压缩在EBD文件中去就可以了。关于虚拟磁盘的问题：是系统自动工作，不要我们控制。

[wuhuar]

找一下DOS的书，有个ramdriver命令

[flyuu]

DOS下虚拟磁盘一般用RAMDRIVER（在CONFIG里设置）

检索最后盘符可以用FOR循环，从Z到C用IF EXIST进行处理（批处理）

详细命令格式可以参考DOS命令帮助

[licome]

可直接使用z盘盘符!!!!

[MagicianZ]

楼上几位的观点是对的，WIN98的 启动盘是用了一个专用程序的，可以参考一下，另外，做一个LASTDRIVE程序也不是不可以，参考 《未公开的DOS核心技术》。

[rosson]

Windows\Command目录下有慢慢找吗，他能过autoexec.bat,调用别外一个setramd.bat
内容如下：
setramd.bat
@echo off
set RAMD=
set CDROM=

echo.
echo WINdows98 正在准备启动您的电脑.
echo 启动电脑将需要一些时间. 请耐心等待...
echo.

a:\findramd

if errorlevel 255 goto no_ramdrive

if not errorlevel 3 goto no_ramdrive

goto do_shift

:loop
if errorlevel %1 goto no_shift

:do_shift
set cdrom=%2
shift
shift
if not %1*==* goto loop
goto no_ramdrive

:no_shift
set ramd=%2

if "%RAMD%"=="C" goto c_drive

goto success

:c_drive
echo Windows 98 检测到磁盘C:是无效的文件格式FAT或者FAT32.
echo 这里可能存在以下问题.
echo.
echo 1. 驱动器需要进行分区,建立分区请运行FDISK.
echo.
echo 2. 你可以使用其他分区软件,请取出启动盘重新启动电脑然后,再运行分区软件.
echo .
echo 3. 一些病毒可以使C盘无效,请运行杀毒软件检查你的电脑.
echo.
goto success

:no_ramdrive
echo Windows 98 启动盘无法为诊断工具建立RAM驱动器.
echo 可能是电脑内存不够无法满足最小的扩展内存.
echo.
:success

autoexec.bat内容如下
@ECHO OFF
pbios
font16
hzvio95
set EXPAND=YES
SET DIRCMD=/O:N
set LglDrv=27 * 26 Z 25 Y 24 X 23 W 22 V 21 U 20 T 19 S 18 R 17 Q 16 P 15
set LglDrv=%LglDrv% O 14 N 13 M 12 L 11 K 10 J 9 I 8 H 7 G 6 F 5 E 4 D 3 C
cls
echo 汉字显示系统(内码GB)成功载入...
echo 制作:罗雄 [e-mail]
echo.
call setramd.bat %LglDrv%
set temp=c:\
set tmp=c:\
path=%RAMD%:\;a:\;%CDROM%:\
copy command.com %RAMD%:\ > NUL
set comspec=%RAMD%:\command.com
copy extract.exe %RAMD%:\ > NUL
copy readme.txt %RAMD%:\ > NUL

:ERROR
IF EXIST ebd.cab GOTO EXT
echo 请插入WIN98#2盘
echo.
pause
GOTO ERROR

:EXT
%RAMD%:\extract /y /e /l %RAMD%: ebd.cab > NUL
echo 诊断工具成功装载RAM驱动器 %RAMD%.
echo.

IF "%config%"=="NOCD" GOTO QUIT
IF "%config%"=="HELP" GOTO HELP
LH %ramd%:\MSCDEX.EXE /D:mscd001 /L:%CDROM%
echo.
GOTO QUIT

:HELP
cls
call help.bat
echo 您的电脑将重新启动并显示启动菜单.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
echo.
restart.com
GOTO QUIT

:QUIT
echo 需要帮助请输入help并按Enter键.
echo.
rem 下面SET作用是：清除环境变量
set CDROM=
set LglDrv=

我这里经将他作成了中文启动盘不过要拷几个文件进去