一个关于VB拨号的程序

[塑料勺]

有人知道用VB怎么写拨号程序吗???急呀....老师要...
最好细点...

[gpo2002]

G:\Program Files\Microsoft Visual Studio\MSDN98\98VS\2052\SAMPLES\VB98\Dialer

VERSION 5.00
Object = "{648A5603-2C6E-101B-82B6-000000000014}#1.1#0"; "MSCOMM32.OCX"
Begin VB.Form DIALER
Caption = "MSComm 电话拨号器"
ClientHeight = 1545
ClientLeft = 4005
ClientTop = 3270
ClientWidth = 4275
LinkTopic = "Form2"
PaletteMode = 1 'UseZOrder
ScaleHeight = 1545
ScaleWidth = 4275
WhatsThisHelp = -1 'True
Begin MSCommLib.MSComm MSComm1
Left = 0
Top = 0
_ExtentX = 1005
_ExtentY = 1005
_Version = 393216
DTREnable = -1 'True
End
Begin VB.CommandButton CancelButton
Caption = "取消"
Enabled = 0 'False
BeginProperty Font
Name = "宋体"
Size = 9
Charset = 134
Weight = 700
Underline = 0 'False
Italic = 0 'False
Strikethrough = 0 'False
EndProperty
Height = 348
Left = 1680
TabIndex = 3
Top = 885
Width = 852
End
Begin VB.CommandButton QuitButton
Cancel = -1 'True
Caption = "退出"
BeginProperty Font
Name = "宋体"
Size = 9
Charset = 134
Weight = 700
Underline = 0 'False
Italic = 0 'False
Strikethrough = 0 'False
EndProperty
Height = 348
Left = 2640
TabIndex = 1
Top = 885
Width = 852
End
Begin VB.CommandButton DialButton
Caption = "拨号"
Default = -1 'True
BeginProperty Font
Name = "宋体"
Size = 9
Charset = 134
Weight = 700
Underline = 0 'False
Italic = 0 'False
Strikethrough = 0 'False
EndProperty
Height = 348
Left = 720
TabIndex = 0
Top = 885
Width = 852
End
Begin VB.Label Status
BorderStyle = 1 'Fixed Single
Caption = "要拨一个号码, 请单击“拨号”按钮"
Height = 255
Left = 720
TabIndex = 2
Top = 360
Width = 3015
End
End
Attribute VB_Name = "DIALER"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
'--------------------------------------------------------
' DIALER.FRM
' Copyright (c) 1994 Crescent Software, Inc.
' by Carl Franklin
'
' Updated by Anton de Jong
'
' 演示如何用调制解调器拨电话号码。
'
' 为使此程序工作正常, 您的电话和
' 调制解调器必须用同一根电话线相连接。
'--------------------------------------------------------
Option Explicit

DefInt A-Z

' 当用户选择取消时设置此标志。
Dim CancelFlag

Private Sub CancelButton_Click()
' CancelFlag 用来告知退出拨号过程。
CancelFlag = True
CancelButton.Enabled = False
End Sub

Private Sub Dial(Number$)
Dim DialString$, FromModem$, dummy

' AT 是贺氏兼容 ATTENTION 命令并且要求发送命令到调制解调器。
' DT 意味着"音频拨号。" 这个拨号命令用于音频, 相对的是脉冲 (DP = 脉冲拨号)。
' Numbers$ 为要拨的电话号码。
' 分号告知调制解调器拨号后返回命令模式(这一点很重要)。
' 一个回车, vbCr, 当发送命令到调制解调器时被要求。
DialString$ = "ATDT" + Number$ + ";" + vbCr

' 通信端口设置
' 假设鼠标器连接到 COM1, 那么通信端口设置为 COM2
MSComm1.CommPort = 2
MSComm1.Settings = "9600,N,8,1"

' 打开通信端口
On Error Resume Next
MSComm1.PortOpen = True
If Err Then
MsgBox " COM2: 不可用。 更改 CommPort 属性使其使用 COM1。"
Exit Sub
End If

' 清空输入缓冲区。
MSComm1.InBufferCount = 0

' 拨电话号码。
MSComm1.Output = DialString$

' 等待从调制解调器返回"OK" 。
Do
dummy = DoEvents()
' 如果缓冲区中有数据，则把它读出来。
If MSComm1.InBufferCount Then
FromModem$ = FromModem$ + MSComm1.Input
' 检查 "OK"。
If InStr(FromModem$, "OK") Then
' 提醒用户摘电话。
Beep
MsgBox "请您摘电话然后按“回车”键或单击“确定”"
Exit Do
End If
End If

' 用户是否选择“取消”?
If CancelFlag Then
CancelFlag = False
Exit Do
End If
Loop

' 断开与调制解调器的连接。
MSComm1.Output = "ATH" + vbCr

' 关闭端口。
MSComm1.PortOpen = False
End Sub

Private Sub DialButton_Click()
Dim Number$, Temp$

DialButton.Enabled = False
QuitButton.Enabled = False
CancelButton.Enabled = True

' 取得要拨的电话号码。
Number$ = InputBox$("请输入电话号码：", Number$)
If Number$ = "" Then Exit Sub
Temp$ = Status
Status = "正在拨号码 - " + Number$

' 拨选定的电话号码。
Dial Number$

DialButton.Enabled = True
QuitButton.Enabled = True
CancelButton.Enabled = False

Status = Temp$
End Sub

Private Sub Form_Load()
' 当 Input 属性被使用，设置 InputLen 为 0
' 告知 MSComm 读取输入缓冲区中的全部内容。
MSComm1.InputLen = 0

End Sub

Private Sub QuitButton_Click()
End
End Sub

很详细吧，呵呵

[塑料勺]

谢谢.....