如何在查找中使用通配符？

[kwxx]

如何返回某一目录下特定扩展名的所有文件的完整路径？
比如返回C:\WINDOWS目录下的所有EXE文件的路径。

[Chice_wxg]

Dir()命令

[water_j]

Dir 支持多字符 (*) 和单字符 (?) 的通配符来指定多重文件。

[qbilbo]

dim myFiles() as string,strTmp as string

private sub GetAllFile(yourpath as string,FileType as string)
dim i as integer

strTmp=dir(yourpath+"\*."+FileType)

if strTmp<>"" then
redim preserve myFiles(i)
myfiles(i)=yourpath+"\"+strTmp
do until strTmp=""
strTmp=dir()
if strtmp<>"" then
i=i+1
redim preserve myFiles(i)
myfiles(i)=yourpath+"\"+strTmp
end if
loop
end if
end sub

如果要返回windows下的所有EXE文件：
GetAllFile "c:\windows","exe"
运行后，windows目录下所有EXE文件的文件名（包括路径）在变量数组myfiles中

[zyl910]

Dir 函数


返回一个 String，用以表示一个文件名、目录名或文件夹名称，它必须与指定的模式或文件属性、或磁盘卷标相匹配。

语法

Dir[(pathname[, attributes])]

Dir 函数的语法具有以下几个部分：

部分 描述
pathname 可选参数。用来指定文件名的字符串表达式，可能包含目录或文件夹、以及驱动器。如果没有找到 pathname，则会返回零长度字符串 ("")。
attributes 可选参数。常数或数值表达式，其总和用来指定文件属性。如果省略，则会返回匹配 pathname 但不包含属性的文件。


设置值

attributes 参数的设置可为：

常数 值 描述
vbNormal 0 (缺省) 指定没有属性的文件。
vbReadOnly 1 指定无属性的只读文件
vbHidden 2 指定无属性的隐藏文件
VbSystem 4 指定无属性的系统文件
vbVolume 8 指定卷标文件；如果指定了其它属性，则忽略vbVolume
vbDirectory 16 指定无属性文件及其路径和文件夹。


注意 这些常数是由 VBA 所指定的，在程序代码中的任何位置，可以使用这些常数来替换真正的数值。

说明

Dir 支持多字符 (*) 和单字符 (?) 的通配符来指定多重文件。

由于 Macintosh 不支持通配符，使用文件类型指定文件组。可以使用 MacID 函数指定文件类型而不用文件名。比如，下列语句返回当前文件夹中第一个TEXT文件的名称:

Dir("SomePath", MacID("TEXT"))

为选中文件夹中所有文件，指定一空串:

Dir("")

在 Microsoft Windows 中，如果在Dir函数中使用MacID函数，将产生错误。

任何大于256的attribute值都被认为是MacID 函数的值。

在第一次调用 Dir 函数时，必须指定 pathname，否则会产生错误。如果也指定了文件属性，那么就必须包括 pathname。

Dir 会返回匹配 pathname 的第一个文件名。若想得到其它匹配 pathname 的文件名，再一次调用 Dir，且不要使用参数。如果已没有合乎条件的文件，则 Dir 会返回一个零长度字符串 ("")。一旦返回值为零长度字符串，并要再次调用 Dir 时，就必须指定 pathname，否则会产生错误。不必访问到所有匹配当前 pathname 的文件名，就可以改变到一个新的 pathname 上。但是，不能以递归方式来调用 Dir 函数。以 vbDirectory 属性来调用 Dir 不能连续地返回子目录。

提示 由于文件名并不会以特别的次序来返回，所以可以将文件名存储在一个数组中，然后再对这个数组排序。

[zyl910]

Dir 函数示例
本示例使用 Dir 函数来检查某些文件或目录是否存在。在 Macintosh 计算机上，默认驱动器名称是 “HD” ，并且路径部分由冒号取代反斜线隔开。而且 Microsoft Windows 的通配符在 Mac 中可以作为有效字符出现在文件名中。也可以使用 MacID 函数来指定文件组。

Dim MyFile, MyPath, MyName

' 返回“WIN.INI” （如果该文件存在）。
MyFile = Dir("C:\WINDOWS\WIN.ini")

' 返回带指定扩展名的文件名。如果超过一个 *.ini 文件存在，
' 函数将返回按条件第一个找到的文件名。
MyFile = Dir("C:\WINDOWS\*.ini")

' 若第二次调用 Dir 函数，但不带任何参数，则函数将返回同一目录下的下一个 *.ini 文件。
MyFile = Dir

' 返回找到的第一个隐式 *.TXT 文件。
MyFile = Dir("*.TXT", vbHidden)

' 显示 C:\ 目录下的名称。
MyPath = "c:\" ' 指定路径。
MyName = Dir(MyPath, vbDirectory) ' 找寻第一项。
Do While MyName <> "" ' 开始循环。
' 跳过当前的目录及上层目录。
If MyName <> "." And MyName <> ".." Then
' 使用位比较来确定 MyName 代表一目录。
If (GetAttr(MyPath & MyName) And vbDirectory) = vbDirectory Then
Debug.Print MyName ' 如果它是一个目录，将其名称显示出来。
End If
End If
MyName = Dir ' 查找下一个目录。
Loop