如何得到图片文件长和宽等信息？包括bmp/jpg/ico等文件

[czwwh]

我想得到一个图片的长度和宽度等信息，请问如何做？

[footballboy]

http://www.csdn.net/expert/topic/633/633523.xml?temp=7.563418E-02

[孙小雄]

Picture1.AutoSize = True
Picture1.Picture = LoadPicture("C:\Documents and Settings\Administrator\My Documents\My Pictures\20000621_yvonne2000_cprim.jpg", vbLPCustom)
MsgBox Picture1.Height & "*" & Picture1.Width

[810303]

使用image控件,
image1.picture=loadpicture(x:\xx.jpg)
msgbox "pic's width=" & image1.width & ",pic's height=" & image1.height

[孙小雄]

这回对了

Private Sub Form_Load()
Picture1.AutoSize = True
Picture1.Picture = LoadPicture("C:\1.jpg")
Picture1.ScaleMode = 3
MsgBox Picture1.ScaleHeight & "*" & Picture1.ScaleWidth
End Sub

[kevincomein]

Private Declare Function GetObject Lib "gdi32" Alias "GetObjectA" _
(ByVal hObject As Long, ByVal nCount As Long, lpObject As Any) _
As Long
Private Declare Function GetBitmapBits Lib "gdi32" (ByVal hBitmap As Long, _
ByVal dwCount As Long, lpBits As Any) As Long

Private Type BITMAP
bmType As Long
bmWidth As Long
bmHeight As Long
bmWidthBytes As Long
bmPlanes As Integer
bmBitsPixel As Integer
bmBits As Long
End Type

Private Sub Command1_Click()
Dim hBitmap As Long
Dim res As Long
Dim bmp As BITMAP
Dim byteAry() As Byte
Dim totbyte As Long, i As Long
hBitmap = Picture1.Picture.Handle

res = GetObject(hBitmap, Len(bmp), bmp) '取得BITMAP的结构

totbyte = bmp.bmWidthBytes * bmp.bmHeight '总共要多少BYTE来存图
ReDim byteAry(totbyte - 1)
'将Picture1中的图信息存到ByteAry
res = GetBitmapBits(hBitmap, totbyte, byteAry(0))

Debug.Print "Total Bytes Copied :"; res
Debug.Print "bmp.bmBits "; bmp.bmBits
Debug.Print "bmp.bmBitsPixel "; bmp.bmBitsPixel '每相素位数
Debug.Print "bmp.bmHeight "; bmp.bmHeight '以相素计算图象高度
Debug.Print "bmp.bmPlanes "; bmp.bmPlanes
Debug.Print "bmp.bmType "; bmp.bmType
Debug.Print "bmp.bmWidth "; bmp.bmWidth '以相素计算图形宽度
Debug.Print "bmp.bmWidthBytes "; bmp.bmWidthBytes '以字节计算的每扫描线长度
End Sub