关于拖动编程，如何实现外部对象经拖动被自己的程序所识别。？

[romanticonline]

比如，我们打开一个播放器，可以直接托动一个外部文件到这个播放器上，这时播放器可以直接识别，并且播放这个文件，这是如何实现的？

我只知道如何实现在程序内部的对象托动问题。

高手给，或者最好发一个例程到我的邮件中，同样给分。

[e-mail]

[TechnoFantasy]

自制支持文件拖放的VCL组件

[ 作者: 不详 添加时间: 2001-7-13 11:46:46 ]




用过Winamp的朋友都知道，Winamp的界面能支持文件拖放，当你想欣赏某MP3文件时，只需要
将文件拖到Winamp的窗口上，然后放开鼠标就行了。那我们如何让自己的程序也实现这样的功能
呢？我们可以通过改进开发工具提供的标准组件来实现。下面以Delphi环境中的ListBox组件为
例，让ListBox支持文件拖放。
首先介绍一下要用到的API函数：
DragAcceptFiles() 初始化某窗口使其允许/禁止接受文件拖放
DragQueryFile() 查询拖放的文件名
DragFinish() 释放拖放文件时使用的资源
实现的基本原理如下：首先调用DragAcceptFiles()函数初始化组件窗口，使其允许接受文件
拖放，然后等待WM_DropFiles消息（一旦用户进行了拖放文件操作，组件窗口即可获得此消息），
获得消息后即可使用DragQueryFile()函数查询被拖放的文件名，最后调用DragFinish()释放资
源。

因为在VCL类库中，ListBox组件，所属类名为：TListBox，所以我们可以从TListBox继承建立
自己的组件。新组件名为：TDropFileListBox，它比标准TListBox增加了一个OnDropFiles事件和
一个DropEnabled属性。当DropEnabled为True时即可接受文件拖放，文件拖放完成后激发
OnDropFiles事件，该事件提供一个FileNames参数让用户获得文件名。

组件的代码如下：

{ TDropFileListBox V1.00 Component }
{ Copyright (c) 2000.5 by Shen Min, Sunisoft }
{ Email: [e-mail] }
{ Web: http://www.sunistudio.com }
unit DropFileListBox;
interface
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
StdCtrls, ShellApi; //增加ShellApi单元，因为所使用的三个API函数声明于此单元文件中
type
TMyNotifyEvent = procedure (Sender: TObject;FileNames:TStringList) of object; //自定
义事件类型。
TDropFileListBox = class(TListBox) //新的类从TListBox继承
private
{ Private declarations }
FEnabled:Boolean; //属性DropEnabled的内部变量
protected
FDropFile:TMyNotifyEvent; //事件指针
procedure DropFiles(var Mes:TMessage);message WM_DROPFILES;
procedure FDropEnabled(Enabled:Boolean); //设置DropEnabled属性的过程
{ Protected declarations }
public
constructor Create(AOwner: TComponent);override;
destructor Destroy;override;
{ Public declarations }
published
property OnDropFiles:TMyNotifyEvent read FDropFile write FDropFile;
property DropEnabled:Boolean read FEnabled write FDropEnabled;
{ Published declarations }
end;
procedure Register;

implementation

procedure Register;
begin
RegisterComponents('Sunisoft', [TDropFileListBox]); //注册组件到组件板上
end;

constructor TDropFileListBox.Create(AOwner: TComponent);
begin
inherited Create(AOwner);
FEnabled:=true; //类被构造时，使DropEnabeld的默认值为True
end;

destructor TDropFileListBox.Destroy;
begin
inherited Destroy;
end;

//改变属性DropEnabled的调用过程
procedure TDropFileListBox.FDropEnabled(Enabled:Boolean);
begin
FEnabled:=Enabled;
DragAcceptFiles(Self.Handle,Enabled);//设置组件窗口是否接受文件拖放
end;

//接受WM_DropFiles消息的过程
procedure TDropFileListBox.DropFiles(var Mes:TMessage);
var FN:TStringList;
FileName:array [1..256] of char;
sFN:String;
i,Count,p:integer;
begin
FN:=TStringList.Create;
Count:=DragQueryFile(Mes.WParam,$FFFFFFFF,@FileName,256);//得到拖放文件的个数
For i:=0 to Count-1 do
begin
DragQueryFile(mes.WParam,i,@FileName,256);//查询文件名称
sFN:=FileName;
p:=pos(chr(0),sFN);//去掉文件名末尾的ASCII码为0的字符
sFN:=copy(sFN,1,p-1);
FN.Add(sFN);
end;
DragFinish(mes.WParam); //释放所使用的资源
if Assigned(FDropFile) then
FDropFile(self, FN); //调用事件，并返回文件名列表参数
FN.Free;
end;

end.

[taxi]

unit Unit1;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls;

type
TForm1 = class(TForm)
ListBox1: TListBox;
procedure FormCreate(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
procedure WMDropFiles(var Message: TMessage); message WM_DropFiles;
end;

var
Form1: TForm1;

implementation

{$R *.dfm}

uses
ShellApi;

procedure TForm1.WMDropFiles(var Message: TMessage);
var
Index, iFileCount: Integer;
sFileName: array[0..MAX_PATH] of Char;
begin
Index := -1;
iFileCount := DragQueryFile(Message.WParam, Index, nil, 0);

for Index := 0 to iFileCount - 1 do
begin
DragQueryFile(Message.WParam, Index, sFileName, MAX_PATH);
ListBox1.Items.Add(sFileName);
end;
DragFinish(Message.WParam);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
DragAcceptFiles(Handle, True);
end;

end.

[短歌如风]

用OleDragDrop控件.

[短歌如风]

用OleDragDrop,不但可以接受文件,还可以接受URL,图片等.

[del_c_sharp]

来晚了！
同意 taxi(游少爷）的方法，简单有效

[romanticonline]

谢谢高手，送分。