一个新手的疑惑？？？（在线）

uv2000 2002-06-26 05:07:18
你好，我将尽可能把我的想法表述清楚，也请你万分耐心，谢谢！

1 在VB中新建一个新工程：（form.caption="cool")

Dim a As Long
---------------------------------
Private Sub Form_load()

a = 10 ‘注意
MsgBox VarPtr(a) ‘弹出对话框给后一工程指示a的地址。

End Sub
---------------------------------
Private Sub form_click()

MsgBox a

End Sub
---------------------------------

2 然后生成cool.exe文件

3 在新建另一工程：

Private Declare Function WriteProcessMemory Lib "kernel32" ( _
ByVal hProcess As Long, _
lpBaseAddress As Any, _
lpBuffer As Any, _
ByVal nSize As Long, _
lpNumberOfBytesWritten As Long) _
As Long

Private Declare Function GetWindowThreadProcessId Lib "user32" ( _
ByVal Hwnd As Long, lpdwProcessId As Long) As Long

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _
ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare Function OpenProcess Lib "kernel32" ( _
ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, _
ByVal dwProcessId As Long) _
As Long

Private Declare Function CloseHandle Lib "kernel32" ( _
ByVal hObject As Long) _
As Long

Const PROCESS_VM_OPERATION = &H8
Const PROCESS_VM_READ = &H10
Const PROCESS_VM_WRITE = &H20
Const PROCESS_ALL_ACCESS = 0

dim b as long
--------------------------------------------------------------------
Private Sub Form_Load()

b = 99 '注意

End Sub
--------------------------------------------------------------------
Private Sub Form_click()

Dim OutAdress As Long
Dim OWhwnd As Long
Dim OPid As Long
Dim OPhwnd As Long

OutAdress = InputBox("", "") '输入先前弹出a的地址

OWhwnd = FindWindow(vbNullString, "cool")

lret = GetWindowThreadProcessId(OWhwnd, OPid)

OPhwnd = OpenProcess(PROCESS_ALL_ACCESS, False, OPid)

lret = WriteProcessMemory(OPhwnd, Hex(OutAdress), varptr(b), 4&, 0&)

CloseHandle OPhwnd

End Sub
----------------------------------------------------------------------

4 运行cool.exe

5 单击对话窗，弹出对话框给后一工程指示a的地址。

6 运行后建的工程，单击窗体

7 在单击cool.exe窗体，输入先前弹出a的地址，然后...
我的目的未达到，弹出的对话框中显示a的值还为10，未
变为99。

8 我想请问，到底是哪一个细节出了错误？？？

9 最后，万分感谢！！！









...全文
24 18 打赏 收藏 转发到动态 举报
写回复
用AI写文章
18 条回复
切换为时间正序
请发表友善的回复…
发表回复
cxz1992 2002-06-28
  • 打赏
  • 举报
 回复
你在后面的那个工程中加入这段程序，一定OK。我在我的机子上已通过了，先运行cool.exe， 单击对话窗，弹出对话框给后一工程指示a的地址。 运行后建的工程，单击窗体 在单击cool.exe窗体，输入先前弹出a的地址，然后，弹出的对话框中显示a的值为99。

Private Declare Function WriteProcessMemory Lib "kernel32" ( _
ByVal hProcess As Long, _
lpBaseAddress As Any, _
lpBuffer As Any, _
ByVal nSize As Long, _
lpNumberOfBytesWritten As Long) _
As Long

Private Declare Function GetWindowThreadProcessId Lib "user32" ( _
ByVal Hwnd As Long, lpdwProcessId As Long) As Long

Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _
ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare Function OpenProcess Lib "kernel32" ( _
ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, _
ByVal dwProcessId As Long) _
As Long

Private Declare Function CloseHandle Lib "kernel32" ( _
ByVal hObject As Long) _
As Long

Const PROCESS_VM_OPERATION = &H8
Const PROCESS_VM_READ = &H10
Const PROCESS_VM_WRITE = &H20
Const PROCESS_ALL_ACCESS = 0

dim b as long
--------------------------------------------------------------------
Private Sub Form_Load()

b = 99 '注意

End Sub
--------------------------------------------------------------------
Private Sub Form_click()

Dim OutAdress As Long
Dim OWhwnd As Long
Dim OPid As Long
Dim OPhwnd As Long

OutAdress = InputBox("", "") '输入先前弹出a的地址

OWhwnd = FindWindow(vbNullString, "cool")

lret = GetWindowThreadProcessId(OWhwnd, OPid)

OPhwnd = OpenProcess(PROCESS_ALL_ACCESS, False, OPid)


lret = WriteProcessMemory(OPhwnd, ByVal OutAdress, b, 4&, 0&)

CloseHandle OPhwnd

End Sub
楼上的zyl910(910：分儿，我来了！) (L2002）分析得很不错。
dsclub 2002-06-27
  • 打赏
  • 举报
 回复
服了楼上的。

收好
zyl910 2002-06-27
  • 打赏
  • 举报
 回复
问题可能出现在这句：
lret = WriteProcessMemory(OPhwnd, Hex(OutAdress), varptr(b), 4&, 0&)

如果Hex的返回值完全是数字，它会传递该数字的地址，而不是a的地址
如果返回值有字母，那就会是一个字符串，传递的是字符串变量的地址

而且varptr(b)得值是b的地址，传送方式却是ByRef，也就是把b的地址的地址传了过去

写入位置错误，写入的数字错误，当然无法的到正确的结果


正确写法：lret = WriteProcessMemory(OPhwnd, ByVal OutAdress, b, 4&, 0&)
uv2000 2002-06-27
  • 打赏
  • 举报
 回复
up
uv2000 2002-06-27
  • 打赏
  • 举报
 回复
up
uv2000 2002-06-27
  • 打赏
  • 举报
 回复
up
GLAY 2002-06-26
  • 打赏
  • 举报
 回复
使用 Visual Basic 制作修改器

作者：Bean(beans@gamehacking.com)

由flyinsky翻译

最新更新于2000/5/24


"对不起，我想这是不可能的，因为VB是一个如此简单的编程语音。"如果有人这么告诉你，别去理他。我可以肯定告诉你，对于制作修改器这种简单的程序，VB完全可以胜任。
然而，有个问题必须首先考虑：使用VB编写的修改器需要VB的运行库才能运行。如果考虑到有些使用者(实际上可能是大部分使用者)没有运行库，那么在最后制作的ZIP压缩文件中就必须包含这些庞大的文件。在下面的教程里我将制作一个修改器，如果为它再制作一个安装程序，那么整个修改器的体积将超过1MB。其中包括一个很好的安装和反安装程序，但大部分还是VB40032.DLL这个文件。
除了以上这点，使用VB制作修改器是非常简单的。一旦制作了多次后，你会发现能很快地制作出一个修改器。而且使用VB制作的修改器能够毫无困难地解决游戏运行时的动态内存分配问题，因此即使是最新的游戏，也可以使用VB制作修改器。在本教程中将不涉及动态内存分配，因为虽然简单，但仍然属于一个高级的选项。

一些背景知识
不象C语音，VB不会自动包括普通的API函数的声明，因此我们必须把他们加入我们的项目文件。在几乎所有的修改器中会使用到6个主要的函数，讨论如下：
1. FindWindow(ClassName, WindowTitle) - FindWindow 返回符合指定的类名( ClassName )和窗口名( WindowTitle )的窗口句柄。对我们来说，可以让 ClassName 为空( Null )，只给出游戏的 WindowTitle。函数应该这样声明： Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
2. GetWindowThreadProcessId(WindowHandle, ProcessId) - 在这里我们把 FindWindow 函数中得到的句柄作为参数，来获得进程标识符(ProcessId )。声明如下： Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long
3. OpenProcess(DesiredAccess, Inherit, ProcessId) - 这个函数将返回一个我们目标进程的句柄，可以用来对目标进行读写操作。 DesiredAccess 参数的值决定了句柄对进程的存取权利，对我们来说，要使用 PROCESS_ALL_ACCESS (完全存取权限)。Inherit 应该总是 False。 ProcessId 是从 GetWindowThreadProcessId 函数中取得的。 Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
4. CloseHandle(ProcessHandle) - 每一个打开的句柄必须呼叫这个函数来关闭。 Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
5. WriteProcessMemory(ProcessHandle, Address, Value, SizeofValue, BytesWritten) - 把指定的值 Value 写入由 Address 指定的目标地址。 Declare Function WriteProcessMemory Lib "kernel32" (ByVal hProcess As Long, ByVal lpBaseAddress As Any, ByVal lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
6. ReadProcessMemory(ProcessHandle, Address, Value, SizeofValue, BytesWritten) - 把 Address 指定的目标地址的值存入 Value 位置的变量中。 Declare Function WriteProcessMemory Lib "kernel32" (ByVal hProcess As Long, ByVal lpBaseAddress As Any, ByVal lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
这些函数一环扣一环，缺一不可。更详细的内容可以参考VB的帮助文件。

一个简单的修改器范例
如何使上面介绍的这些函数一起工作，制作出我们需要的修改器呢？下面是一个为Windows的计算器程序制作修改器的例子。这个修改器将读出计算器窗口中显示的数值，并在点击一个按钮后在计算器窗口中显示我们的名字。

首先我们需要找到计算器显示窗口中显示值的地址。本教程不是关于如何进行内存搜索，因而我将只作简单的说明：
· 在计算器窗口中输入123456
· 使用你喜欢的任何一种内存地址搜索程序寻找字串123456
· 使用另一个值重复上面的过程直到只返回1个地址
那是制作我们的修改器需要的唯一一个地址。在我的计算器程序里这个地址是40B181 hex, 4239745 dec。用你找到的地址替代在下面的代码里使用的这个地址。

现在让我们开始设计修改器的界面：
· 在VB中新建一个项目，加入一个文本框( Textbox )、一个按钮和一个计时器( timer )。文本框用来显示从计算器窗口取得的字串，按钮用来把我们的名字传到计算器窗口
· 把表单( form )的标题( Caption )属性设为 Calculator Trainer
· 把文本框改名为 txtDisplay 并清除 Text 属性
· 把计时器改名为 ReadTimer 并把间隔( interval )设为500
· 把按钮的标题改为 Display Name，按钮的名字改为 btnPasteName

在这个修改器中我们将使用所有6个函数，ReadProcessMemory、WriteProcessMemory、OpenProcess、GetWindowThreadProcessId、FindWindow 和 CloseHandle。在项目中插入一个新的模块，增加下列代码。(下面的一些行自动换行了，在你的模块中每一句必须在一行里，或使用延长符_)
Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Declare Function GetWindowThreadProcessId Lib "user32" (ByVal hwnd As Long, lpdwProcessId As Long) As Long
Declare Function OpenProcess Lib "kernel32" (ByVal dwDesiredAccess As Long, ByVal bInheritHandle As Long, ByVal dwProcessId As Long) As Long
Declare Function WriteProcessMemory Lib "kernel32" (ByVal hProcess As Long, ByVal lpBaseAddress As Any, ByVal lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
Declare Function ReadProcessMemory Lib "kernel32" (ByVal hProcess As Long, ByVal lpBaseAddress As Any, ByVal lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long

下面我们要开始写在计时器窗口中显示我们名字的代码了。首先我们使用 FindWindow 函数取得目标窗口的句柄。把这个返回值保存在一个变量中，并检查它的值是否出错来确保计时器程序正在运行。(FindWindow函数出错时返回0)
Dim hwnd As Long
hwnd = FindWindow(vbNullString, "Calculator")
If (hwnd = 0) Then
MsgBox "Window not found!"
Exit Sub
End If
注意在这里我们传递了一个 Null 值给 FindWindow 函数，而不是 ClassName。因此任何名为 Calculator 的窗口都符合条件。如果知道计算器程序窗口的 ClassName，你可以传给它，但这不是必须的。

现在使用得到的窗口句柄来取得进程标识符( ProcessId )。注意 pid 是作为参数传递给函数的，而不是被赋以函数返回值。
Dim pid As Long
GetWindowThreadProcessId hwnd, pid

再利用变量pid得到计算器程序的进程句柄。再次检查函数的返回值，如果是非法数据则退出程序。
Dim pHandle As Long
pHandle = OpenProcess(PROCESS_ALL_ACCESS, False, pid)
If (pHandle = 0) Then
MsgBox "Couldn't get a process handle!"
Exit Sub
End If

在我们的修改器中 WriteProcessMemory 函数是最重要的部分，而且非常容易出错。不妨让我们再仔细讨论一下它的参数。
WriteProcessMemory (ByVal hProcess As Long, ByVal lpBaseAddress As Any, ByVal lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As)
hProcess 是目标进程的句柄，从上面的 OpenProcess 函数中取得的。
lpBaseAddress 是在计算器程序的虚拟内存中将要被修改的地址，也就是使用内存搜索程序找到的那个地址。(在我的程序里是&H40B181)
lpBuffer 是将要写如上述地址的数据，可以是一个数值、数组、字符串或其他任何数据类型。
nSize 是希望写入 lpBaseAddress 的字节数。这个位置应该与你的数据类型相符。如果写入的是一个长整数( long )，这里应该是4。如果写入的是一个字符串，那么这里应该是字符串的长度。
lpNumberOfBytesWritten 是函数执行返回后，写入目标地址的实际字节数。它能被用来确认函数实际的执行情况。

把我们的数据放到函数中，得到 WriteProcessMemory pHandle, &H40B181, "Beans", 5, 0&。我把0传递到 lpNumberOfBytesWritten 位置是因为不需要检查两次实际写入的字节数。

最后通过传递进程句柄给 CloseHandle() 函数来关闭由 OpenProcess 打开的句柄。
CloseHandle hProcess

现在将所有的代码输入我们的编辑器中。双击按钮，显示它的代码编辑窗口。代码应该加到名为 btnPasteName 的 Click 事件中。(不必输入注释)
Private Sub btnPasteName_Click()
' 声明一些需要的变量
Dim hwnd As Long ' 储存 FindWindow 函数返回的句柄
Dim pid As Long ' 储存进程标识符( Process Id )
Dim pHandle As Long ' 储存进程句柄

' 首先取得目标窗口的句柄
hwnd = FindWindow(vbNullString, "Calculator")
If (hwnd = 0) Then
MsgBox "Window not found!"
Exit Sub
End If

' 取得进程标识符
GetWindowThreadProcessId hwnd, pid

' 使用进程标识符取得进程句柄
pHandle = OpenProcess(PROCESS_ALL_ACCESS, False, pid)
If (pHandle = 0) Then
MsgBox "Couldn't get a process handle!"
Exit Sub
End If

' 在内存地址中写入名字
WriteProcessMemory pHandle, &H40B181, "Beans", 5, 0&

' 关闭进程句柄
CloseHandle hProcess
End Sub

完毕。现在单击按钮将使计算器窗口文本变为我们键如的名字。(可能需要最小化计算器程序，再还原，以便程序更新显示)

uv2000 2002-06-26
  • 打赏
  • 举报
 回复
up
uv2000 2002-06-26
  • 打赏
  • 举报
 回复
up
comeby 2002-06-26
  • 打赏
  • 举报
 回复
不会吧，这也算新手？？？？？？？？
blueer 2002-06-26
  • 打赏
  • 举报
 回复
OPhwnd = OpenProcess(PROCESS_ALL_ACCESS, False, OPid)
OpenProcess时出错了
leonnet 2002-06-26
  • 打赏
  • 举报
 回复
楼上三个说很对，sigh
jakseng 2002-06-26
  • 打赏
  • 举报
 回复
近视又加深了！
jakseng 2002-06-26
  • 打赏
  • 举报
 回复
近视又加深了！
cat7035 2002-06-26
  • 打赏
  • 举报
 回复
??
balloonman2002 2002-06-26
  • 打赏
  • 举报
 回复
K，又说是VB新手！！！
godanddog 2002-06-26
  • 打赏
  • 举报
 回复
你想干什么？
Backspace24 2002-06-26
  • 打赏
  • 举报
 回复
what?
一个新手对erp的思考和疑惑
国内最专业的erp论坛，某人整理，很多很详细，erp学习资料 http://hi.erp100.com/invite.php?u=185659&c=9340c471d7847b99
新手学习react迷惑的点
你肯定疑惑过，下面的代码都没有用到React，为什么要引入React呢？如果你把importReactfrom‘react’删掉，还会报下面这样的错误：那么究竟是哪里用到了这个React，导致我们引入React会报错呢，不懂这个原因，那么就是JSX没有搞得太明白。你可以讲上面的代码(忽略导入语句)放到在线babel里进行转化一下，发现babel会把上面的代码转化成:因为从本质上讲，JSX只是为React.createElement(component,props,...children)函数提供的语法糖。React一开始的理念是想与浏览器的DOMAPI保持一直而不是HTML，因为JSX是JS的
性能测试学习线路图
新手开始学习性能测试，该如何由浅入深？该文档为你解答疑惑。
phpcms v9如何调用外部数据库？调用的标签是什么
在某些特殊的情况下需要调用外部数据库，有些新手朋友对此还是很疑惑的，下面是具体的实现标签，感兴趣的朋友可以参考下
新手疑惑？。？
奇怪！
VB基础类

7,762

社区成员

197,608

社区内容

发帖
与我相关
我的任务
社区描述
VB 基础类
社区管理员
  • VB基础类社区
加入社区
  • 近7日
  • 近30日
  • 至今

加载中

查看更多榜单
社区公告
暂无公告

试试用AI创作助手写篇文章吧

+ 用AI写文章