在程序窗口失去焦点后，取得键盘按键的方法

[hanzye]

在程序窗口失去焦点后，取得键盘按键的方法：
用SetWindowsHookEx()可以做到，但难控制如KeyDown,KeyUP,KeyPress等
的效果，有没有更好的方法呢？

[mouseanAnya]

gz

[lkal4587]

key_event

[hanzye]

没有答在要点上，
我指的是程序在Load时就定义了一个热键，对应程序中的某一功能(子程序).
之后，不论该程序是否是当前窗口，是否具有焦点，都能响应这个热键。
有点类似于在Snagit抓图软件中，只要程序已运行，不管它是不是当前的，都可按Ctrl+P进行抓图。
我已经知道这个功能要用API，用SetWindowsHookEx()
Private Sub Form_Load()
hHook = SetWindowsHookEx(WH_KEYBOARD, AddressOf Myfunc, , 0)
End Sub　　　

Private Sub Form_Unload(Cancel As Integer)
UnhookWindowsHookEx (hHook)
End Sub

'Myfunc()是这个功能子函数
Function Myfunc(ByVal nCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
If wParam = 18（假设是响应Alt键） Then
.....
Myfunc = 1
Exit Function
End If
Myfunc = CallNextHookEx(hHook, ncode, wParam, lParam)
End Function

在这里，我不太明白CallNextHookEx()的作用，
在实际应用中按一次键，程序会响应三次，？？？其中nCode,wParam,lParam
的值也不一样，这三个参数是什么意思？
最关键的还在于当焦点在桌面上时，程序的热键就失灵了，
该怎么办？有没有更好的办法呢，我知道这个功能还可能涉及到的函数有
LowLevelKeyboardProc（），keybd_event（），KBDLLHOOKSTRUCT（）
在MSDN中有英文文档，可我的英文实在是无能为力，
请高手们帮忙，我出100分。

[zyl910]

http://www.csdn.net/expert/topic/981/981051.xml?temp=.7772943

[cgh1970]

可以呀！

[shenxin]

你钩子查查以往的帖子，很多的

[guiqing]

如果想简单但麻烦的话可以使用getkeyboardstate函数。
例如：按下A键,getkeyboardstate(vbkeyA)为true.

[fq1]

SetWindowsHookEx不行,只能拦截本进程的,全局单纯vb做不到(必须dll中)

据我所知有以下两种方法hook全局输入:
Dinput: 就是所谓全局hook了,可拦截所有输入和其他,但复杂,且没必要为了一个键hook全部
JournalRecord: 可能很少人知道这个,这个就是全局inputhook又不用在dll中的超级方法,而且是API不用象DX那样需要另外的库支持,但一个system只能有一个!


根据你的题目要求,你只是有一个热键就行了,那么有如下方法:
WM_SETHOTKEY:对某窗口发这个就可以设定一个热键,当按下时就可以激活这个窗口,但它只是激活,不对应程序中的函数,需要你自己根据窗口的激活事件再运行特定的函数,不太好,所以还有这个:
RegisterHotKey: 这是window专门用来设定热键的,按下后可会发回WM_HOTKEY消息,配合SetWindowLong就可以回调你指定的函数,是热键问题的最佳解决方法!

如下是RegisterHotKey的例子:

'以下在.bas中
Option Explicit

Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" _
(ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" _
(ByVal hwnd As Long, ByVal nIndex As Long) As Long
Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" _
(ByVal lpPrevWndFunc As Long, ByVal hwnd As Long, ByVal Msg As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long
Declare Function RegisterHotKey Lib "user32" (ByVal hwnd As Long, ByVal id As Long, ByVal fsModifiers As Long, ByVal vk As Long) As Long
Declare Function UnregisterHotKey Lib "user32" (ByVal hwnd As Long, ByVal id As Long) As Long

Public Const WM_HOTKEY = &H312
Public Const MOD_ALT = &H1
Public Const MOD_CONTROL = &H2
Public Const MOD_SHIFT = &H4
Public Const GWL_WNDPROC = (-4)

Public preWinProc As Long
Public Modifiers As Long, uVirtKey As Long, idHotKey As Long

Private Type taLong
ll As Long
End Type
Private Type t2Int
lWord As Integer
hword As Integer
End Type
Public Function wndproc(ByVal hwnd As Long, ByVal Msg As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long
If Msg = WM_HOTKEY Then
If wParam = idHotKey Then
Dim lp As taLong, i2 As t2Int
lp.ll = lParam
LSet i2 = lp
If (i2.lWord = 0) And i2.hword = uVirtKey Then
Shell "notepad", vbNormalFocus '热键按下就启动纪事本
Beep
Debug.Print "G!"

End If
End If
End If
wndproc = CallWindowProc(preWinProc, hwnd, Msg, wParam, lParam)
End Function


'以下在form中
Sub Form_Load()
Dim ret As Long
preWinProc = GetWindowLong(Me.hwnd, GWL_WNDPROC)
ret = SetWindowLong(Me.hwnd, GWL_WNDPROC, AddressOf wndproc)
idHotKey = 1
Modifiers = 0
uVirtKey = vbKeyG '热键定为G
ret = RegisterHotKey(Me.hwnd, idHotKey, Modifiers, uVirtKey)
End Sub

Private Sub Form_Unload(Cancel As Integer)
Dim ret As Long
ret = SetWindowLong(Me.hwnd, GWL_WNDPROC, preWinProc)
Call UnregisterHotKey(Me.hwnd, uVirtKey)
End Sub


详细用法自己参考MSDN。


以上是我的一些经验,如果哪位朋友还知道其他方法贴出来共享!

[sworddx]

用HOOK吧，可以自己用支持Win32 DLL的编程工具（VC++,Delphi什么的）写，也可以直接去网上找，很多的。

[hanzye]

fq1兄的解释非常到位，非常感谢，我给90分。

用RegisterHotKey基本能解决问题，但这个方法在焦点不在任何窗口上（在桌面上）时，可能接收不对按键。它的不足之处fq1也点到了，但键值用Ctrl,All,Shift,时老有问题，我还需看看。

如果还有其他的同道有更好的方法，不妨详细一道，我还要加分。