定点还原！！！？？？

[daihuiwu]

restore database pubs from mybackup
with norecovery ,file=1 --完全备份（第一个）

restore log pubs from mybackup
with recovery,file=1 stopat='2007-05-25 17:27' --都指名了recovery!!（最好
一个）

胜利的还原了，但是数据库还处在“正在装载”的状态。
这是什么原因呢，菜鸟在线等候。

还有我如果在企业管理下实现上面的功能，在输入时间点时就是有“为STOPAT 参数指定的值无效,RESTORE LOG 操作异常终止”怎么可能呢？？难道企业管理器下面不支持定点还原？！！！

[daihuiwu]

还原时间点：：：：对完全备份和日志备份之间的时间点还原都是支持的，不是吗？

那邹建大哥！
还原时间点在企业管理器抱错，那用SQL语句怎么又不报错呢？？？（这个问题就是想不明白）

restore database pubs from mybackup
with norecovery ,file=1 --完全备份（第一个）

restore log pubs from mybackup
with recovery,file=1 stopat='2007-05-25 17:27' --都指名了recovery!!（最好
一个）

胜利的还原了，但是数据库还处在“正在装载”的状态。
谢谢！！！！

[daihuiwu]

急切盼回！！

[zjcxc]

应该是时间点不对.

企业管理器里面你可以选择时间点, 从而可以看到支持在那个时间点范围内还原.
时间点还原不是说可以还原到任意时候的, 是在日志备份支持的时间范围内

[肥胖的柠檬]

zjcxc(邹建)大哥,想你了....

[daihuiwu]

谢谢lizhenghanwl() ！！

1，你所做的实验我也做过，只是有时成功，有时失败，有时还原时出现数据库正在加载的状态？？

2，还有就是有时候用SQL语句还原时可以，但是在企业管理器下就出现时间参数错误！真的是不解？？？？

[daihuiwu]

只能顶下了！！

[lizhenghanwl]

数据还原到指定时间点的处理示例
--创建测试数据库
CREATE DATABASE Db
GO
--对数据库进行备份
BACKUP DATABASE Db TO DISK='c:\db.bak' WITH FORMAT
GO
--创建测试表
CREATE TABLE Db.dbo.TB_test(ID int)
--延时1秒钟,再进行后面的操作(这是由于SQL Server的时间精度最大为百分之三秒,不延时的话,可能会导致还原到时间点的操作失败)
WAITFOR DELAY '00:00:01'
GO
--假设我们现在误操作删除了 Db.dbo.TB_test 这个表
DROP TABLE Db.dbo.TB_test
--保存删除表的时间
SELECT dt=GETDATE() INTO #
GO
--在删除操作后,发现不应该删除表 Db.dbo.TB_test
--下面演示了如何恢复这个误删除的表 Db.dbo.TB_test
--首先,备份事务日志(使用事务日志才能还原到指定的时间点)
BACKUP LOG Db TO DISK='c:\db_log.bak' WITH FORMAT
GO
--接下来,我们要先还原完全备份(还原日志必须在还原完全备份的基础上进行)
RESTORE DATABASE Db FROM DISK='c:\db.bak' WITH REPLACE,NORECOVERY
GO
--将事务日志还原到删除操作前（这里的时间对应上面的删除时间，并比删除时间略早
DECLARE @dt datetime
SELECT @dt=DATEADD(ms,-20,dt) FROM # --获取比表被删除的时间略早的时间
RESTORE LOG Db FROM DISK='c:\db_log.bak' WITH RECOVERY,STOPAT=@dt
GO
--查询一下,看表是否恢复
SELECT * FROM Db.dbo.TB_test
/*--结果:
ID
-----------
（所影响的行数为 0 行）
--*/
--测试成功
GO
--最后删除我们做的测试环境
DROP DATABASE Db
DROP TABLE #