sql replace处理ntext问题

[limitanger]

一个ntext字段，要对该字段内的指定字符串替换操作，但是用一条语句：update PE_Article set content = replace(cast(content as nvarchar(200000)),'[href=''uploadfile]','[href=''../oldweb/uploadfile]')，报错：nvarchar(200000)最大不允许超过8000，有什么办法？

[lwl0606]

搂住如果想用NVARCHAR可以这样，nvarchar(4000) 这是nvarchar 所能容纳的最大长度
update PE_Article set content = replace(cast(content as nvarchar(4000)),'[href=''uploadfile]','[href=''../oldweb/uploadfile]')

[lwl0606]

用UPDATETEXT 可以实现TEXT 类型的替换

--drop table aatt
create table aatt(id int ,atext Ntext)
insert into aatt select 1,N'[href=''uploadfile]test text tttttttttttgbgs fdgdfgdfg [href=''uploadfile] '
insert into aatt select 2,N'gdfhfghgfhdfhfghfghfgh......'
insert into aatt select 3,N'controlled[href=''uploadfile], into[href=''uploadfile] .....'


declare @aa BINARY(16)
declare @i int
declare @id int
declare RepaceText cursor
for
select id,PATINDEX('%''uploadfile%', atext) from aatt where PATINDEX('%''uploadfile%', atext)>0
open RepaceText
fetch next from RepaceText into @id,@i
while @@fetch_status=0
begin
--print @id
while @i>=0
begin
SELECT @aa = TEXTPTR(atext),
@i = PATINDEX('%''uploadfile%', atext) - 1
FROM aatt
WHERE id = @id
--print @i
if @i>=0
begin
UPDATETEXT aatt.atext
@aa
@i --插入的位置
1 --删除的字符数
WITH LOG
'../oldweb/uploadfile' --要新插入的文本

end
else
begin
break
end
end

fetch next from RepaceText into @id,@i
end
close RepaceText
deallocate RepaceText


--查看结果
select * from aatt

[simonhehe]

--这是我用过的一个ntext处理的例子，你可以改变成你需要的情况
--关于ntext的操作楼主可以查看联机帮助

exec sp_dboption 'hnimdb','select into/bulkcopy','true'
go
declare @Point varbinary(16),@Point2 varbinary(16),@var varchar(8000),@var2 varchar(8000)
declare @yxID int
select @yxID=min(yxID) from mysql.hneam.dbo.tbyxtlrz where jjman2 is null and reportdate>'2006-12-05'
select @yxID

select @Point = textptr(yxjs),@Point2=textptr(jdsx) from tbYXjzztlrz where num=@yxID+94
--select @Point,@Point2

select @var=yxjs,@var2=jdsx from mysql.hneam.dbo.tbyxtlrz where yxid=@yxID
if @var is null set @var=''
if @var2 is null set @var2=''
--select @var,@var2
writetext tbyxjzztlrz.yxjs @Point @var
writetext tbyxjzztlrz.jdsx @Point2 @var2
go
exec sp_dboption 'hnimdb','select into/bulkcopy','false'
go

[leo_lesley]

varchar和nvarchar的最大长度都是8000，如果你转换的ntext类型超过这个长度，就要截取来提换，下面是老大的一个replace替换ntext的例子。


--测试数据
CREATE TABLE tb(col ntext)
INSERT tb VALUES(REPLICATE( '0001,0002,0003,0004,0005,0006,0007,0008,0009,0100,'
+'220000001,302000004,500200006,700002008,900002120,',800))
DECLARE @p binary(16)
SELECT @p=TEXTPTR(col) FROM tb
UPDATETEXT tb.col @p NULL 0 tb.col @p
GO

--替换处理定义
DECLARE @s_str nvarchar(1000),@r_str nvarchar(1000)
SELECT @s_str='00' --要替换的字符串
,@r_str='0000' --替换成该字符串

DECLARE @p varbinary(16)
DECLARE @start int,@s nvarchar(4000),@len int
DECLARE @s_len int,@step int,@last_repl int,@pos int

--替换处理参数设置
SELECT
--用于要判断每次截取数据,最后一个被替换数据位置的处理
@s_len=LEN(@s_str),

--设置每次应该截取的数据的长度,防止REPLACE后数据溢出
@step=CASE WHEN LEN(@r_str)>LEN(@s_str)
THEN 4000/LEN(@r_str)*LEN(@s_str)
ELSE 4000 END

--替换处理的开始位置
SELECT @start=PATINDEX('%'+@s_str+'%',col),
@p=TEXTPTR(col),
@s=SUBSTRING(col,@start,@step),
@len=LEN(@s),
@last_repl=0
FROM tb
WHERE PATINDEX('%'+@s_str+'%',col)>0
AND TEXTVALID('tb.col',TEXTPTR(col))=1
WHILE @len>=@s_len
BEGIN
--得到最后一个被替换数据的位置
WHILE CHARINDEX(@s_str,@s,@last_repl)>0
SET @last_repl=@s_len
+CHARINDEX(@s_str,@s,@last_repl)

--如果需要,更新数据,同时判断下一个取数位置的偏移量
IF @last_repl=0
SET @last_repl=@s_len
ELSE
BEGIN
SELECT @last_repl=CASE
WHEN @len<@last_repl THEN 1
WHEN @len-@last_repl>=@s_len THEN @s_len
ELSE @len-@last_repl+2 END,
@s=REPLACE(@s,@s_str,@r_str),
@pos=@start-1
UPDATETEXT TB.col @p @pos @len @s
END
--获取下一个要处理的数据
SELECT @start=@start+LEN(@s)-@last_repl+1,
@s=SUBSTRING(col,@start,@step),
@len=LEN(@s),
@last_repl=0
FROM tb
END
GO

--显示处理结果
SELECT datalength(col),* FROM tb
DROP TABLE tb