兄弟们，这个SQL怎么写啊？

[am2002cnfj]

下面是Table内容
字段1 字段2 字段3
A1 2001 CSDN
A2 2002 IBM
A3 2000 IBM
A1 2002 CSDN
A3 2000 Oracle
A1 2002 Oracel


现在想根据字段1和字段2统计成下面的格式，如何写这个SQL啊
A1 2001 1 CSDN
A1 2002 2 CSDN/Oracle
A2 2002 1 IBM
A3 2000 2 IBM/ORACLE

[dawugui]

--带符号合并行列转换

--有表t，其数据如下：
a b
1 1
1 2
1 3
2 1
2 2
3 1
--如何转换成如下结果:
a b
1 1,2,3
2 1,2
3 1

create table tb
(
a int,
b int
)
insert into tb(a,b) values(1,1)
insert into tb(a,b) values(1,2)
insert into tb(a,b) values(1,3)
insert into tb(a,b) values(2,1)
insert into tb(a,b) values(2,2)
insert into tb(a,b) values(3,1)
go

if object_id('pubs..f_hb') is not null
drop function f_hb
go

--创建一个合并的函数
create function f_hb(@a int)
returns varchar(8000)
as
begin
declare @str varchar(8000)
set @str = ''
select @str = @str + ',' + cast(b as varchar) from tb where a = @a
set @str = right(@str , len(@str) - 1)
return(@str)
End
go

--调用自定义函数得到结果：
select distinct a ,dbo.f_hb(a) as b from tb

drop table tb

--结果
a b
----------- ------
1 1,2,3
2 1,2
3 1

（所影响的行数为 3 行）


多个前列的合并
数据的原始状态如下：
ID PR CON OP SC
001 p c 差 6
001 p c 好 2
001 p c 一般 4
002 w e 差 8
002 w e 好 7
002 w e 一般 1
===========================
用SQL语句实现，变成如下的数据
ID PR CON OPS
001 p c 差(6),好(2),一般(4)
002 w e 差(8),好(7),一般(1)

if object_id('pubs..tb') is not null
drop table tb
go

create table tb
(
id varchar(10),
pr varchar(10),
con varchar(10),
op varchar(10),
sc int
)

insert into tb(ID,PR,CON,OP,SC) values('001', 'p', 'c', '差', 6)
insert into tb(ID,PR,CON,OP,SC) values('001', 'p', 'c', '好', 2)
insert into tb(ID,PR,CON,OP,SC) values('001', 'p', 'c', '一般', 4)
insert into tb(ID,PR,CON,OP,SC) values('002', 'w', 'e', '差', 8)
insert into tb(ID,PR,CON,OP,SC) values('002', 'w', 'e', '好', 7)
insert into tb(ID,PR,CON,OP,SC) values('002', 'w', 'e', '一般', 1)
go

if object_id('pubs..test') is not null
drop table test
go
select ID,PR,CON , OPS = op + '(' + cast(sc as varchar(10)) + ')' into test from tb

--创建一个合并的函数
if object_id('pubs..f_hb') is not null
drop function f_hb
go
create function f_hb(@id varchar(10),@pr varchar(10),@con varchar(10))
returns varchar(8000)
as
begin
declare @str varchar(8000)
set @str = ''
select @str = @str + ',' + cast(OPS as varchar) from test where id = @id and @pr = pr and @con = con
set @str = right(@str , len(@str) - 1)
return(@str)
End
go

--调用自定义函数得到结果：
select distinct id ,pr , con , dbo.f_hb(id,pr,con) as OPS from test

drop table tb
drop table test

--结果
id pr con OPS
---------- ---------- ---------- -------------------
001 p c 差(6),好(2),一般(4)
002 w e 差(8),好(7),一般(1)

（所影响的行数为 2 行）



create table b
(col varchar(20))

insert b values ('a')
insert b values ('b')
insert b values ('c')
insert b values ('d')
insert b values ('e')


declare @sql varchar(1024)
set @sql=''
select @sql=@sql+b.col+',' from (select col from b) as b
set @sql='select '''+@sql+''''
exec(@sql)

[dawugui]

create table tb(字段1 varchar(10),字段2 varchar(10),字段3 varchar(10))
insert into tb values('A1', '2001', 'CSDN')
insert into tb values('A2', '2002', 'IBM')
insert into tb values('A3', '2000', 'IBM')
insert into tb values('A1', '2002', 'CSDN')
insert into tb values('A3', '2000', 'Oracle')
insert into tb values('A1', '2002', 'Oracel')
go

--创建一个合并的函数
create function f_hb(@字段1 varchar(10),@字段2 varchar(10))
returns varchar(8000)
as
begin
declare @str varchar(8000)
set @str = ''
select @str = @str + '/' + cast(字段3 as varchar) from tb where 字段1 = @字段1 and 字段2 = @字段2
set @str = right(@str , len(@str) - 1)
return(@str)
End
go

--调用自定义函数得到结果：

select m.字段1,m.字段2,m.cnt , n.字段3 from
(
select 字段1,字段2,count(*) cnt from tb group by 字段1,字段2
) m,
(
select distinct 字段1,字段2 ,dbo.f_hb(字段1,字段2) as 字段3 from tb
) n
where m.字段1 = n.字段1 and m.字段2 = n.字段2


drop table tb
drop function f_hb

/*
字段1 字段2 cnt 字段3
---------- ---------- ----------- ------------
A1 2001 1 CSDN
A1 2002 2 CSDN/Oracel
A2 2002 1 IBM
A3 2000 2 IBM/Oracle

（所影响的行数为 4 行）

*/

[yrwx001]

create function db0.fn_test(col1 varchar(10),col2 varchar(10), ifalg int)
returns varchar(100)
as
begin
declare @icount int --字段1 字段2
declare @str varchar(100)
set @str = ''

select @str = @str + ',' +字段3 from Table where 字段1=@col1 and 字段2 = col2
set @str = stuff(@str,1,1,'')

select @icount = count(1) from Table where 字段1=@col1 and 字段2 = col2
if (@iflag = 1)
set @str = cast(@icount as varchar(100))
return @str
end

go

select distinct 字段1,字段2,num = dbo.fn_test(字段1,字段2,1),字段3 = dbo.fn_test(字段1,字段2,0) from Table