一個 sql查詢問題?

2007-12-21 05:36:33 147 阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

复杂查询优化：避免 SQL 查询中的 N+1 查询问题复杂查询优化：避免 SQL 查询中的 N+1 查询问题阅读详情

FACTORY_NAME STOP_THING MOB_PHONE
HOA 機器固障 13416662327
HOA 機器固障 13416662328
HOA 來料不良 13416612212
HOA 測試面板 13654582454
結果為：
FACTORY_NAME STOP_THING MOB_PHONE
HOA 機器固障 13416662327,13416662328
HOA 來料不良 13416612212
HOA 測試面板 13654582454
謝謝！！

...全文

大语言模型在建筑规范自动化合规审查中的微调策略与规模效应实践大语言模型（LLM）通过在海量文本数据上预训练，具备了强大的语言理解和生成能力。其核心原理是基于Transformer架构，通过自注意力机制捕捉长距离依赖关系。在工程实践中，为了将这种通用能力适配到建筑、法律、金融等高度专业化的垂直领域，通常需要采用领域微调技术。微调通过使用特定领域的高质量指令数据对模型参数进行更新，使其掌握专业术语、逻辑规则和任务范式，从而解决通用模型在专业场景下知识匮乏和“幻觉”问题。结合检索增强生成（RAG）技术，将动态外部知识库作为模型的“参考手册”，能进一步提升事实准确性并降低幻阅读详情

youngtsinghua

应用实例 27,579 成员 68,540 内容

+ 关注 + 加入社区

切换为时间正序

andysun88 2007-12-22

打赏
举报



--这个可以用一个函数实现:

--首先写一个返回MOB_PHONE 的函数如下



Create FUNCTION [dbo].[F_getValue] 

(

@FACTORY_NAME nvarchar(50),

@STOP_THING nvarchar(20)

)

RETURNS nvarchar(max)

AS

begin

   declare @strRet nvarchar(max)

   set @strRet = ''

    select @strRet = @strRet+MOB_PHONE+',' from t_test 

   where FACTORY_NAME= @FACTORY_NAME and STOP_THING=@STOP_THING

  return @strRet

end



-- 测试数据

--select distinct a.FACTORY_NAME,a.STOP_THING,dbo.F_getValue(a.FACTORY_NAME,a.STOP_THING) as 



--MOB_PHONE from t_test a  -- 这个的后面有一个逗号,



select distinct a.FACTORY_NAME,a.STOP_THING,substring(dbo.F_getValue(a.FACTORY_NAME,a.STOP_THING),0,len(dbo.F_getValue(a.FACTORY_NAME,a.STOP_THING))-1) as MOB_PHONE from t_test a





--测试结果

   FACTORY_NAME  STOP_THING       MOB_PHONE

1    HOA	         測試面板	  13654582454,

2   HOA	         機器固障	  13416662327,13416662328,

3   HOA	         來料不良	  13416612212,

youngtsinghua 2007-12-22

打赏
举报

謝謝大家，昨天就搞定，忘了結帖。

JL99000 2007-12-22

打赏
举报

if object_id('t_stru') is not null
drop table t_stru
if object_id('f_getPHONE') is not null
drop function f_getPHONE
go
create table t_stru(FACTORY_NAME varchar(10),STOP_THING varchar(10),MOB_PHONE varchar(20))
insert t_stru
select 'HOA','機器固障','13416662327' union all
select 'HOA','機器固障','13416662328' union all
select 'HOA','來料不良','13416612212' union all
select 'HOA','測試面板','13654582454'
select * from t_stru

go
create function f_getPHONE(@STOP_THING varchar(10))
returns varchar(100)
as
begin
declare @s varchar(100)
select @s=isnull(@s,'')+A.MOB_PHONE+',' from (select MOB_PHONE from t_stru where STOP_THING=@STOP_THING) A
if @s!=''
set @s=substring(@s,1,len(@s)-1)
return @s
end

go
select A.FACTORY_NAME,A.STOP_THING,dbo.f_getPHONE(STOP_THING) from (select distinct STOP_THING,FACTORY_NAME from t_stru) A

-狙击手- 2007-12-21

打赏
举报

没错写个函数就行

create function f_hb(@FACTORY_NAME varchar(10) , @STOP_THING varchar(10))
returns varchar(8000)
as
begin
declare @str varchar(8000)
set @str = ''
select @str = @str + ',' + cast(MOB_PHONE as varchar) from tb where FACTORY_NAME = @FACTORY_NAME and STOP_THING = @STOP_THING
set @str = right(@str , len(@str) - 1)
return(@str)
End
go

dawugui 2007-12-21

打赏
举报

--SQL SERVER 2005中的写法.

create table tb(FACTORY_NAME varchar(10), STOP_THING varchar(10), MOB_PHONE varchar(20))

insert into tb values('HOA', '機器固障', '13416662327') 

insert into tb values('HOA', '機器固障', '13416662328') 

insert into tb values('HOA', '來料不良', '13416612212') 

insert into tb values('HOA', '測試面板', '13654582454') 

go

-- 查询处理

SELECT * FROM(SELECT DISTINCT FACTORY_NAME , STOP_THING FROM tb)A OUTER APPLY(

        SELECT [MOB_PHONE]= STUFF(REPLACE(REPLACE(

            (

                SELECT MOB_PHONE FROM tb N

                WHERE FACTORY_NAME = A.FACTORY_NAME and STOP_THING = A.STOP_THING

                FOR XML AUTO

            ), '<N MOB_PHONE="', ','), '"/>', ''), 1, 1, '')

)N





drop table tb



/*

FACTORY_NAME STOP_THING MOB_PHONE

------------ ---------- -----------------------

HOA          測試面板   13654582454

HOA          機器固障   13416662327,13416662328

HOA          來料不良   13416612212



(3 行受影响)

*/

dawugui 2007-12-21

打赏
举报

--SQL SERVER 2000中的写法.

create table tb(FACTORY_NAME varchar(10), STOP_THING varchar(10), MOB_PHONE varchar(20))

insert into tb values('HOA', '機器固障', '13416662327') 

insert into tb values('HOA', '機器固障', '13416662328') 

insert into tb values('HOA', '來料不良', '13416612212') 

insert into tb values('HOA', '測試面板', '13654582454') 

go

--创建一个合并的函数

create function f_hb(@FACTORY_NAME varchar(10) , @STOP_THING varchar(10))

returns varchar(8000)

as

begin

  declare @str varchar(8000)

  set @str = ''

  select @str = @str + ',' + cast(MOB_PHONE as varchar) from tb where FACTORY_NAME = @FACTORY_NAME and STOP_THING = @STOP_THING

  set @str = right(@str , len(@str) - 1)

  return(@str)

End

go



--调用自定义函数得到结果：

select distinct FACTORY_NAME , STOP_THING ,dbo.f_hb(FACTORY_NAME , STOP_THING) as MOB_PHONE from tb



drop table tb

drop function f_hb



/*

FACTORY_NAME STOP_THING MOB_PHONE

------------ ---------- -----------------------

HOA          測試面板   13654582454

HOA          機器固障   13416662327,13416662328

HOA          來料不良   13416612212



(3 行受影响)

*/

dawugui 2007-12-21

打赏
举报

自己参考上面的改改.

dawugui 2007-12-21

打赏
举报

合并列值

原著：邹建

改编：爱新觉罗.毓华  2007-12-16  广东深圳



表结构，数据如下：

id    value

----- ------

1     aa

1     bb

2     aaa

2     bbb

2     ccc



需要得到结果：

id     values

------ -----------

1      aa,bb

2      aaa,bbb,ccc

即：group by id, 求 value 的和（字符串相加）



1. 旧的解决方法(在sql server 2000中只能用函数解决。)

--1. 创建处理函数

create table tb(id int, value varchar(10))

insert into tb values(1, 'aa')

insert into tb values(1, 'bb')

insert into tb values(2, 'aaa')

insert into tb values(2, 'bbb')

insert into tb values(2, 'ccc')

go



CREATE FUNCTION dbo.f_str(@id int)

RETURNS varchar(8000)

AS

BEGIN

    DECLARE @r varchar(8000)

    SET @r = ''

    SELECT @r = @r + ',' + value FROM tb WHERE id=@id

    RETURN STUFF(@r, 1, 1, '')

END

GO



-- 调用函数

SELECt id, value = dbo.f_str(id) FROM tb GROUP BY id



drop table tb

drop function dbo.f_str



/*

id          value      

----------- -----------

1           aa,bb

2           aaa,bbb,ccc

（所影响的行数为 2 行）

*/



--2、另外一种函数.

create table tb(id int, value varchar(10))

insert into tb values(1, 'aa')

insert into tb values(1, 'bb')

insert into tb values(2, 'aaa')

insert into tb values(2, 'bbb')

insert into tb values(2, 'ccc')

go



--创建一个合并的函数

create function f_hb(@id int)

returns varchar(8000)

as

begin

  declare @str varchar(8000)

  set @str = ''

  select @str = @str + ',' + cast(value as varchar) from tb where id = @id

  set @str = right(@str , len(@str) - 1)

  return(@str)

End

go



--调用自定义函数得到结果：

select distinct id ,dbo.f_hb(id) as value from tb



drop table tb

drop function dbo.f_hb



/*

id          value      

----------- -----------

1           aa,bb

2           aaa,bbb,ccc

（所影响的行数为 2 行）

*/



2. 新的解决方法(在sql server 2005中用OUTER APPLY等解决。)

create table tb(id int, value varchar(10))

insert into tb values(1, 'aa')

insert into tb values(1, 'bb')

insert into tb values(2, 'aaa')

insert into tb values(2, 'bbb')

insert into tb values(2, 'ccc')

go

-- 查询处理

SELECT * FROM(SELECT DISTINCT id FROM tb)A OUTER APPLY(

        SELECT [values]= STUFF(REPLACE(REPLACE(

            (

                SELECT value FROM tb N

                WHERE id = A.id

                FOR XML AUTO

            ), '<N value="', ','), '"/>', ''), 1, 1, '')

)N

drop table tb



/*

id          values

----------- -----------

1           aa,bb

2           aaa,bbb,ccc



(2 行受影响)

*/

dawugui 2007-12-21

打赏
举报

/*

带符号合并行列转换(2007-11-19于海南三亚)



有表tb，其数据如下：

  a b

  1 1

  1 2

  1 3

  2 1

  2 2

  3 1

如何转换成如下结果:

  a b

  1 1,2,3

  2 1,2

  3 1 

*/



create table tb

(

   a int,

   b int

)

insert into tb(a,b) values(1,1)

insert into tb(a,b) values(1,2)

insert into tb(a,b) values(1,3)

insert into tb(a,b) values(2,1)

insert into tb(a,b) values(2,2)

insert into tb(a,b) values(3,1)

go



--创建一个合并的函数

create function f_hb(@a int)

returns varchar(8000)

as

begin

  declare @str varchar(8000)

  set @str = ''

  select @str = @str + ',' + cast(b as varchar) from tb where a = @a 

  set @str = right(@str , len(@str) - 1)

  return(@str)

End

go



--调用自定义函数得到结果：

select distinct a ,dbo.f_hb(a) as b from tb



drop table tb

drop function f_hb



/*

结果

a           b     

----------- ------

1           1,2,3

2           1,2

3           1



（所影响的行数为 3 行）

*/



----------------------------------------------------

/*

多个前列的合并

数据的原始状态如下：

ID  PR   CON  OP    SC 

001 p    c    差    6

001 p    c    好    2

001 p    c    一般  4

002 w    e    差    8

002 w    e    好    7

002 w    e    一般  1

用SQL语句实现，变成如下的数据

ID  PR   CON  OPS

001 p    c    差(6),好(2),一般(4)

002 w    e    差(8),好(7),一般(1)

*/



create table tb

(

  id  varchar(10),

  pr  varchar(10),

  con varchar(10),

  op  varchar(10),

  sc  int

)

 

insert into tb(ID,PR,CON,OP,SC) values('001', 'p',    'c',    '差',    6)

insert into tb(ID,PR,CON,OP,SC) values('001', 'p',    'c',    '好',    2)

insert into tb(ID,PR,CON,OP,SC) values('001', 'p',    'c',    '一般',  4)

insert into tb(ID,PR,CON,OP,SC) values('002', 'w',    'e',    '差',    8)

insert into tb(ID,PR,CON,OP,SC) values('002', 'w',    'e',    '好',    7)

insert into tb(ID,PR,CON,OP,SC) values('002', 'w',    'e',    '一般',  1)

go



--创建一个合并的函数

create function f_hb(@id varchar(10) , @pr varchar(10) , @con varchar(10))

returns varchar(8000)

as

begin

  declare @str varchar(8000)

  set @str = ''

  select @str = @str + ',' + cast(OP as varchar) + '(' 

                           + cast(sc as varchar) + ')' 

  from tb where id = @id and @pr = pr and @con = con

  set @str = right(@str , len(@str) - 1)

  return(@str)

End

go



--调用自定义函数得到结果：

select distinct id , pr , con , dbo.f_hb(id,pr,con) as ops from tb



drop table tb

drop function f_hb



/*

结果

id         pr         con        ops               

---------- ---------- ---------- ------------------

001        p          c          差(6),好(2),一般(4)

002        w          e          差(8),好(7),一般(1)



（所影响的行数为 2 行）

*/



----------------------------------------------------

/*如何将一列中所有的值一行显示

数据源

  a

  b

  c

  d

  e

结果

a,b,c,d,e

*/



create table tb(col varchar(20))

insert tb values ('a')

insert tb values ('b')

insert tb values ('c')

insert tb values ('d')

insert tb values ('e')

go



--方法一

declare @sql varchar(1000)

set @sql = ''

select @sql = @sql + t.col + ',' from (select col from tb) as t

set @sql='select result = ''' + @sql + ''''

exec(@sql)

/*

result     

---------- 

a,b,c,d,e,

*/



--方法二

declare @output varchar(8000)

select @output = coalesce(@output + ',' , '') + col from tb

print @output

/*

a,b,c,d,e

*/



drop table tb

youngtsinghua 2007-12-21

打赏
举报

急急！！！

youngtsinghua 2007-12-21

打赏
举报

急急！！！

youngtsinghua 2007-12-21

打赏
举报

急急！！！！！！！！

一個 sql查詢問題?

相关推荐