关于 sql2000开发与管理 书中 使用字符串 分页处理的几个困惑

newredhat 2008-01-27 03:32:13
CREATE PROC sp_PageView
@tbname sysname, --要分页显示的表名
@FieldKey sysname, --用于定位记录的主键(惟一键)字段,只能是单个字段
@PageCurrent int=1, --要显示的页码
@PageSize int=10, --每页的大小(记录数)
@FieldShow nvarchar(1000)='', --以逗号分隔的要显示的字段列表,如果不指定,则显示所有字段
@FieldOrder nvarchar(1000)='', --以逗号分隔的排序字段列表,可以指定在字段后面指定DESC/ASC
用于指定排序顺序
@Where nvarchar(1000)='', --查询条件
@PageCount int OUTPUT --总页数
AS
DECLARE @sql nvarchar(4000)
SET NOCOUNT ON
--检查对象是否有效
IF OBJECT_ID(@tbname) IS NULL
BEGIN
RAISERROR(N'对象"%s"不存在',1,16,@tbname)
RETURN
END
IF OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTable')=0
AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsView')=0
AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTableFunction')=0
BEGIN
RAISERROR(N'"%s"不是表、视图或者表值函数',1,16,@tbname)
RETURN
END

--分页字段检查
IF ISNULL(@FieldKey,N'')=''
BEGIN
RAISERROR(N'分页处理需要主键（或者惟一键）',1,16)
RETURN
END

--其他参数检查及规范
IF ISNULL(@PageCurrent,0)<1 SET @PageCurrent=1
IF ISNULL(@PageSize,0)<1 SET @PageSize=10
IF ISNULL(@FieldShow,N'')=N'' SET @FieldShow=N'*'
IF ISNULL(@FieldOrder,N'')=N''
SET @FieldOrder=N''
ELSE
SET @FieldOrder=N'ORDER BY '+LTRIM(@FieldOrder)
IF ISNULL(@Where,N'')=N''
SET @Where=N''
ELSE
SET @Where=N'WHERE ('+@Where+N')'

--如果@PageCount为NULL值,则计算总页数(这样设计可以只在第一次计算总页数,以后调用时,把总页数传回给存储过程,避免再次计算总页数,对于不想计算总页数的处理而言,可以给@PageCount赋值)
IF @PageCount IS NULL
BEGIN
SET @sql=N'SELECT @PageCount=COUNT(*)'
+N' FROM '+@tbname
+N' '+@Where
EXEC sp_executesql @sql,N'@PageCount int OUTPUT',@PageCount OUTPUT
SET @PageCount=(@PageCount+@PageSize-1)/@PageSize
END

--计算分页显示的TOPN值
DECLARE @TopN varchar(20),@TopN1 varchar(20)
SELECT @TopN=@PageSize,
@TopN1=@PageCurrent*@PageSize

--第一页直接显示
IF @PageCurrent=1
EXEC(N'SELECT TOP '+@TopN
+N' '+@FieldShow
+N' FROM '+@tbname
+N' '+@Where
+N' '+@FieldOrder)
ELSE
BEGIN
SELECT @PageCurrent=@TopN1,
@sql=N'SELECT @n=@n-1,@s=CASE WHEN @n<'+@TopN
+N' THEN @s+N'',''+QUOTENAME(RTRIM(CAST('+@FieldKey
+N' as varchar(8000))),N'''''''') ELSE N'''' END FROM '+@tbname
+N' '+@Where
+N' '+@FieldOrder
SET ROWCOUNT @PageCurrent
EXEC sp_executesql @sql,
N'@n int,@s nvarchar(4000) OUTPUT',
@PageCurrent,@sql OUTPUT
SET ROWCOUNT 0
IF @sql=N''
EXEC(N'SELECT TOP 0'
+N' '+@FieldShow
+N' FROM '+@tbname)
ELSE
BEGIN
SET @sql=STUFF(@sql,1,1,N'')
--执行查询
EXEC(N'SELECT TOP '+@TopN
+N' '+@FieldShow
+N' FROM '+@tbname
+N' WHERE '+@FieldKey
+N' IN('+@sql
+N') '+@FieldOrder)
END
END
-----------------
中这一段
1 @n 没有声明 没有给值 在这是怎么用的 能给讲讲吗？
2 N'''''''' 这8个分号能给讲讲吗

SELECT @PageCurrent=@TopN1,
@sql=N'SELECT @n=@n-1,@s=CASE WHEN @n<'+@TopN
+N' THEN @s+N'',''+QUOTENAME(RTRIM(CAST('+@FieldKey
+N' as varchar(8000))),N'''''''') ELSE N'''' END FROM '+@tbname
+N' '+@Where
+N' '+@FieldOrder
SET ROWCOUNT @PageCurrent
EXEC sp_executesql @sql,
N'@n int,@s nvarchar(4000) OUTPUT',
@PageCurrent,@sql OUTPUT
...全文
75 14 打赏 收藏 转发到动态 举报
写回复
用AI写文章
14 条回复
切换为时间正序
请发表友善的回复…
发表回复
一品梅 2008-01-27
  • 打赏
  • 举报
 回复
收藏...
newredhat 2008-01-27
  • 打赏
  • 举报
 回复
谢谢 老大 明白了
zjcxc 元老 2008-01-27
  • 打赏
  • 举报
 回复
注意字符串是按顺序相加的
所以先加1, 2, 但这两条记录不在显示范围, 不满足 @n < @TopN, 故满足 ELSE 部分, =空字符串, 也就是什么都不要, 处理到 3, 4 的时候, 已经满足 @n < @TopN 了, 所以把值加到字符串 @s 中
zjcxc 元老 2008-01-27
  • 打赏
  • 举报
 回复
加空字符串到结果中

例如有数据
1
2
3
4
5

假设2条记录一页, 当前显示第2而
则取的数据是
1
2
3
4

很显然, 只要最后两个, 所以有条件 @n<@TopN, 即在两条记录范围内, 把值加起来, 否则加空字符串上去
newredhat 2008-01-27
  • 打赏
  • 举报
 回复
ELSE N''''
空的意思吗
newredhat 2008-01-27
  • 打赏
  • 举报
 回复
@n 明白了
ELSE N'''' 起到什么作用？？
newredhat 2008-01-27
  • 打赏
  • 举报
 回复
n 明白了
非常感谢



 @sql=N'SELECT @n=@n-1,@s=CASE WHEN @n<'+@TopN

            +N' THEN @s+N'',''+QUOTENAME(RTRIM(CAST('+@FieldKey

            +N' as varchar(8000))),N'''''''') ELSE N'''' END FROM '+@tbname

            +N' '+@Where

            +N' '+@FieldOrder
@



QUOTENAME(RTRIM(CAST('+@FieldKey

            +N' as varchar(8000))),N''''''''

目的就是想 select '10','9','8' 这个样是吧
那么
ELSE N'''' 起到什么作用 能给讲讲吗
xiaoku 2008-01-27
  • 打赏
  • 举报
 回复
老大来了,我闪...
xiaoku 2008-01-27
  • 打赏
  • 举报
 回复 


    SELECT @PageCurrent=@TopN1,

        @sql=N'SELECT @n=@n-1,@s=CASE WHEN @n<'+@TopN

            +N' THEN @s+N'',''+QUOTENAME(RTRIM(CAST('+@FieldKey

            +N' as varchar(8000))),N'''''''') ELSE N'''' END FROM '+@tbname

            +N' '+@Where

            +N' '+@FieldOrder

    SET ROWCOUNT @PageCurrent

    EXEC sp_executesql @sql,

        N'@n int,@s nvarchar(4000) OUTPUT',

        @PageCurrent,@sql OUTPUT



@n 是上面@sql 这个字符串的变量,是通过     EXEC sp_executesql @sql,

        N'@n int,@s nvarchar(4000) OUTPUT',传值进去的.



2   N''''''''   这8个分号能给讲讲吗 

---------------

--这些分号,是拼凑字符串需要的,不明白,你可以先打印出来看看...
zjcxc 元老 2008-01-27
  • 打赏
  • 举报
 回复
@n
没有给值？
-----------------------------------------------
值是参数传进去的, 看调用就知道, 变量 @PageCurrent 的值传给参数 @n, 参数 @s 为输出参数, 输出结果传递给变量 @sql

	EXEC sp_executesql @sql,

		N'@n int,@s nvarchar(4000) OUTPUT',

		@PageCurrent,@sql OUTPUT
zjcxc 元老 2008-01-27
  • 打赏
  • 举报
 回复
关于" N'''''''' 这8个分号能给讲讲吗 "

字符串中的一个', 需要用两个来表示
那一段拿出来, 其实做的是下面这个处理, 由于要放在字符中中, 所以要加倍, 所以由四个变成8个
QUOTENAME(RTRIM(CAST(FieldKey as varchar(8000))),N'''')


newredhat 2008-01-27
  • 打赏
  • 举报
 回复
@n
没有给值？

select @n=@n-1
@n 值从哪来？？
zjcxc 元老 2008-01-27
  • 打赏
  • 举报
 回复 
	EXEC sp_executesql @sql,

		N'@n int,@s nvarchar(4000) OUTPUT',


看到这段了吗? @n 是执行时, 通过参数指定的
如果不清楚 sp_executesql 如何使用, 则需要看看联机丛书上关于 sp_executesql 的说明才好理解
newredhat 2008-01-27
  • 打赏
  • 举报
 回复 




CREATE PROC sp_PageView

@tbname     sysname,           	--要分页显示的表名

@FieldKey   sysname,           	--用于定位记录的主键(惟一键)字段,只能是单个字段

@PageCurrent int=1,             	--要显示的页码

@PageSize   int=10,            	--每页的大小(记录数)

@FieldShow  nvarchar(1000)='',  	--以逗号分隔的要显示的字段列表,如果不指定,则显示所有字段

@FieldOrder  nvarchar(1000)='', 	--以逗号分隔的排序字段列表,可以指定在字段后面指定DESC/ASC

                                          用于指定排序顺序

@Where     nvarchar(1000)='',  	--查询条件

@PageCount  int OUTPUT        	--总页数

AS

DECLARE @sql nvarchar(4000)

SET NOCOUNT ON

--检查对象是否有效

IF OBJECT_ID(@tbname) IS NULL

BEGIN

	RAISERROR(N'对象"%s"不存在',1,16,@tbname)

	RETURN

END

IF OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTable')=0

	AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsView')=0

	AND OBJECTPROPERTY(OBJECT_ID(@tbname),N'IsTableFunction')=0

BEGIN

	RAISERROR(N'"%s"不是表、视图或者表值函数',1,16,@tbname)

	RETURN

END



--分页字段检查

IF ISNULL(@FieldKey,N'')=''

BEGIN

	RAISERROR(N'分页处理需要主键（或者惟一键）',1,16)

	RETURN

END



--其他参数检查及规范

IF ISNULL(@PageCurrent,0)<1 SET @PageCurrent=1

IF ISNULL(@PageSize,0)<1 SET @PageSize=10

IF ISNULL(@FieldShow,N'')=N'' SET @FieldShow=N'*'

IF ISNULL(@FieldOrder,N'')=N''

	SET @FieldOrder=N''

ELSE

	SET @FieldOrder=N'ORDER BY '+LTRIM(@FieldOrder)

IF ISNULL(@Where,N'')=N''

	SET @Where=N''

ELSE

	SET @Where=N'WHERE ('+@Where+N')'



--如果@PageCount为NULL值,则计算总页数(这样设计可以只在第一次计算总页数,以后调用时,把总页数传回给存储过程,避免再次计算总页数,对于不想计算总页数的处理而言,可以给@PageCount赋值)

IF @PageCount IS NULL

BEGIN

	SET @sql=N'SELECT @PageCount=COUNT(*)'

		+N' FROM '+@tbname

		+N' '+@Where

	EXEC sp_executesql @sql,N'@PageCount int OUTPUT',@PageCount OUTPUT

	SET @PageCount=(@PageCount+@PageSize-1)/@PageSize

END



--计算分页显示的TOPN值

DECLARE @TopN varchar(20),@TopN1 varchar(20)

SELECT @TopN=@PageSize,

	@TopN1=@PageCurrent*@PageSize	



--第一页直接显示

IF @PageCurrent=1

	EXEC(N'SELECT TOP '+@TopN

		+N' '+@FieldShow

		+N' FROM '+@tbname

		+N' '+@Where

		+N' '+@FieldOrder)

ELSE

BEGIN

	SELECT @PageCurrent=@TopN1,

		@sql=N'SELECT @n=@n-1,@s=CASE WHEN @n<'+@TopN

			+N' THEN @s+N'',''+QUOTENAME(RTRIM(CAST('+@FieldKey

			+N' as varchar(8000))),N'''''''') ELSE N'''' END FROM '+@tbname

			+N' '+@Where

			+N' '+@FieldOrder

	SET ROWCOUNT @PageCurrent

	EXEC sp_executesql @sql,

		N'@n int,@s nvarchar(4000) OUTPUT',

		@PageCurrent,@sql OUTPUT

	SET ROWCOUNT 0

	IF @sql=N''

		EXEC(N'SELECT TOP 0'

			+N' '+@FieldShow

			+N' FROM '+@tbname)

	ELSE

	BEGIN

		SET @sql=STUFF(@sql,1,1,N'')		

		--执行查询

		EXEC(N'SELECT TOP '+@TopN

			+N' '+@FieldShow

			+N' FROM '+@tbname

			+N' WHERE '+@FieldKey

			+N' IN('+@sql

			+N') '+@FieldOrder)

	END

END
亮剑.NET深入体验与实战精要3
本书既考虑到实际开发中经常遇到的困惑和难题，也分析了解决问题的思路和方法，更总结出项目开发中不可或缺的技术点及思想。读者可以在欣赏一个个有趣例子的过程中，不知不觉具备开发真正商业项目的能力。 本书集...
亮剑.NET深入体验与实战精要2
本书既考虑到实际开发中经常遇到的困惑和难题，也分析了解决问题的思路和方法，更总结出项目开发中不可或缺的技术点及思想。读者可以在欣赏一个个有趣例子的过程中，不知不觉具备开发真正商业项目的能力。 本书集...
c#Winform程序调用app.config文件配置数据库连接字符串 SQL Server文章目录 浅谈SQL Server中统计对于查询的影响 有关索引的DMV SQL Server中...
c#Winform程序调用app.config文件配置数据库连接字符串 你新建winform项目的时候，会有一个app.config的配置文件,写在里面的&lt;connectionStrings name=" " connectionString=" "&gt...
access mysql连接字符串_access 数据库连接字符串
解决Access连接 accdb 不可识别的数据库格式异常在Access07之前的数据库后缀名均为*.mdb 而连接字符串写成Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\myFolder\*.mdb;Persist Security Info=False;但是Access...
全面解析C/S结构的图书馆管理系统
...使用SQL Server 2000作为服务器端数据库，负责数据管理和复杂逻辑运算。介绍了管理员登录、书籍管理、查询模块等主要功能，展示了VB与SQL Server通信的过程。该系统通过客户端与服务器端的...
MS-SQL Server

34,870

社区成员

254,638

社区内容

发帖
与我相关
我的任务
社区描述
MS-SQL Server相关内容讨论专区
社区管理员
  • 基础类社区
  • 二月十六
  • 卖水果的net
加入社区
  • 近7日
  • 近30日
  • 至今

加载中

查看更多榜单
社区公告
暂无公告

试试用AI创作助手写篇文章吧

+ 用AI写文章