数据库通过日志还原到点的问题

[浪淘沙1997]

对数据库备分比较熟悉的人吗？SQL SERVER的 我通过日志备分想还原到点 可是一直失败 有经验的人可以谈谈吗
有按照网上做的 可是一直有问题 有哪位高手可以把全部过程说说吗

[netcup]

还原可以还原到上次日志备份时。

[liangCK]

--创建测试数据库
CREATE DATABASE Db
GO

--对数据库进行备份
BACKUP DATABASE Db TO DISK='c:\db.bak' WITH FORMAT
GO

--创建测试表
CREATE TABLE Db.dbo.TB_test(ID int)

--延时1秒钟,再进行后面的操作(这是由于SQL Server的时间精度最大为百分之三秒,不延时的话,可能会导致还原到时间点的操作失败)
WAITFOR DELAY '00:00:01'
GO

--假设我们现在误操作删除了 Db.dbo.TB_test 这个表
DROP TABLE Db.dbo.TB_test

--保存删除表的时间
SELECT dt=GETDATE() INTO #
GO

--在删除操作后,发现不应该删除表 Db.dbo.TB_test

--下面演示了如何恢复这个误删除的表 Db.dbo.TB_test

--首先,备份事务日志(使用事务日志才能还原到指定的时间点)
BACKUP LOG Db TO DISK='c:\db_log.bak' WITH FORMAT
GO

--接下来,我们要先还原完全备份(还原日志必须在还原完全备份的基础上进行)
RESTORE DATABASE Db FROM DISK='c:\db.bak' WITH REPLACE,NORECOVERY
GO

--将事务日志还原到删除操作前（这里的时间对应上面的删除时间，并比删除时间略早
DECLARE @dt datetime
SELECT @dt=DATEADD(ms,-20,dt) FROM #  --获取比表被删除的时间略早的时间
RESTORE LOG Db FROM DISK='c:\db_log.bak' WITH RECOVERY,STOPAT=@dt
GO

--查询一下,看表是否恢复
SELECT * FROM Db.dbo.TB_test

/*--结果:
ID          
----------- 

（所影响的行数为 0 行）
--*/

--测试成功
GO

--最后删除我们做的测试环境
DROP DATABASE Db
DROP TABLE #

[liangCK]

USE master

--创建数据库
CREATE DATABASE db
ON PRIMARY(
	NAME='db_data',
	FILENAME= 'c:\db_data.mdf')
LOG ON(
	NAME='db_log',
	FILENAME ='c:\db.ldf')
GO

--创建表
CREATE TABLE db.dbo.ta(id int)
INSERT db.dbo.ta SELECT id FROM sysobjects
GO
--做文件组备份
BACKUP DATABASE db TO DISK='c:\db.bak' WITH FORMAT

--备份后,再做数据处理
CREATE TABLE db.dbo.tb(id int)
INSERT db.dbo.tb SELECT id FROM sysobjects
GO

/*--下面演示了破坏数据文件的处理，这些操作在操作系统中进行

1. 停止SQL Server服务(msqlserver服务)
2. 删除文件 c:\db_data.ndf (模拟破坏)
3. 重新SQL Server服务,此时数据库DB置疑
--*/
GO

--下面演示了如何恢复数据
--首先要备份当前日志
BACKUP LOG db TO DISK='c:\db_log.bak' WITH FORMAT,NO_TRUNCATE
--利用文件组备份恢复破坏的文件
RESTORE DATABASE db FROM DISK='c:\db.bak' WITH NORECOVERY
--还原到日志点
RESTORE LOG db FROM DISK='c:\db_log.bak' WITH RECOVERY
--显示已经恢复的数据
SELECT COUNT(*) FROM db.dbo.ta
SELECT COUNT(*) FROM db.dbo.tb
GO

--删除测试
DROP DATABASE db

[liangCK]

USE master

--创建并完全备份数据库
CREATE DATABASE db
BACKUP DATABASE db TO DISK='c:\db.bak' WITH FORMAT
GO

--标记事务处理
BEGIN TRANSACTION Tran1 WITH MARK

CREATE TABLE db.dbo.tb(id int)

COMMIT TRAN Tran1

--事务完成后插入数据
INSERT db.dbo.tb SELECT id FROM sysobjects
GO

--还原数据到事务标记 Tran1 前
BACKUP LOG db TO DISK='c:\db_log.bak' WITH FORMAT
DROP DATABASE db
RESTORE DATABASE db FROM DISK='c:\db.bak' WITH NORECOVERY
RESTORE LOG db FROM DISK='c:\db_log.bak' WITH STOPBEFOREMARK='Tran1'
SELECT COUNT(*) FROM db.dbo.tb
/*--事务标记 Tran1 前没有创建表,所以会收到错误信息
对象名 'db.dbo.tb' 无效。
--*/
GO

--还原数据库到事务标记 Tran1 后
DROP DATABASE db
RESTORE DATABASE db FROM DISK='c:\db.bak' WITH NORECOVERY
RESTORE LOG db FROM DISK='c:\db_log.bak' WITH STOPATMARK='Tran1'
SELECT COUNT(*) FROM db.dbo.tb
/*--结果
----------- 
0

（所影响的行数为 1 行）
--*/
GO

--删除测试
DROP DATABASE db