我要用VB6做一个拨号程序，用来打电话用的，应该怎样做？高分求教！

[perrylee]

例如我的通信录里每一个有个联系电话，然后我可以点击进行拨号，拨出联系电话，应该怎样做？

是用控件实现？还是用API？

请大家告诉我。

[of123]

API:
Public Declare Function tapiRequestMakeCall Lib "TAPI32.DLL" (ByVal Dest As String, ByVal AppName As String, ByVal CalledParty As String, ByVal Comment As String) As Long

Public Sub PhoneCall(sNumber As String, sName As String)
Dim lRetVal As Long
lRetVal = tapiRequestMakeCall(Trim$(sNumber), App.Title, Trim$(sName), "")
If lRetVal <> 0 Then 'Couldn't make the call.
'Take appropriate action
End If
End Sub

[Sean918]

http://expert.csdn.net/expert/forum.asp

[perrylee]

wxy_xiaoyu(然也)：

什么？是不是给错了地址？

[aibangde]

我看用控件MSCOMM，可以很容易写一个终端仿真程序。拨号很容易实现的

[Ringfo]

关注

[zyh9188]

up

[of123]

可以用MSCOMM控件发送modem的AT命令，其中有拨号命令。
msdn有一个Dialer例子。

Private Sub Dial(Number$)
Dim DialString$, FromModem$, dummy

' AT 是贺氏兼容 ATTENTION 命令并且要求发送命令到调制解调器。
' DT 意味着"音频拨号。" 这个拨号命令用于音频, 相对的是脉冲 (DP = 脉冲拨号)。
' Numbers$ 为要拨的电话号码。
' 分号告知调制解调器拨号后返回命令模式(这一点很重要)。
' 一个回车, vbCr, 当发送命令到调制解调器时被要求。
DialString$ = "ATDT" + Number$ + ";" + vbCr

' 通信端口设置
' 假设鼠标器连接到 COM1, 那么通信端口设置为 COM2
MSComm1.CommPort = 2
MSComm1.Settings = "9600,N,8,1"

' 打开通信端口
On Error Resume Next
MSComm1.PortOpen = True
If Err Then
MsgBox " COM2: 不可用。 更改 CommPort 属性使其使用 COM1。"
Exit Sub
End If

' 清空输入缓冲区。
MSComm1.InBufferCount = 0

' 拨电话号码。
MSComm1.Output = DialString$

' 等待从调制解调器返回"OK" 。
Do
dummy = DoEvents()
' 如果缓冲区中有数据，则把它读出来。
If MSComm1.InBufferCount Then
FromModem$ = FromModem$ + MSComm1.Input
' 检查 "OK"。
If InStr(FromModem$, "OK") Then
' 提醒用户摘电话。
Beep
MsgBox "请您摘电话然后按“回车”键或单击“确定”"
Exit Do
End If
End If

' 用户是否选择“取消”?
If CancelFlag Then
CancelFlag = False
Exit Do
End If
Loop

' 断开与调制解调器的连接。
MSComm1.Output = "ATH" + vbCr

' 关闭端口。
MSComm1.PortOpen = False
End Sub