关于Font对象(二)

[TrueZq]

看起来更简单的一个问题。
题：
设UFont1为一ActiveX 控件
其中字体属性接口为
Public Property Get Font() As StdFont
'......
End Property

Public Property Set Font(ByVal New_Font As StdFont)
'......
End Property
'////////////////////////

Private Sub Form_Load()
UFont1.Font.Size = 18
Command1.Font.Size = 12
End Sub

Private Sub Command1_Click()
Set UFont1.Font = Command1.Font
UFont1.Font.Size = 24
Command1.Caption = Command1.Font.Size
问：'此时Command1.Caption为多少?
End Sub

[zyl910]

24吧

[TrueZq]

现在贴出 控件UFont的所有代码：
注意：UFont上面没有任何子控件，所有属性为默认值
Private WithEvents m_stdFont As StdFont

Private Sub m_stdFont_FontChanged(ByVal PropertyName As String)
Set UserControl.Font = m_stdFont
UserControl.Refresh
End Sub

Private Sub UserControl_Initialize()
Set m_stdFont = New StdFont
End Sub

Private Sub UserControl_Terminate()
Set m_stdFont = Nothing
End Sub

Private Sub UserControl_Paint()
Cls ' 清除原来显示的内容
Print m_stdFont.Name & m_stdFont.Size
End Sub

'为用户控件初始化属性
Private Sub UserControl_InitProperties()
Set m_stdFont = Ambient.Font
End Sub

Private Sub UserControl_ReadProperties(PropBag As PropertyBag)
Set m_stdFont = PropBag.ReadProperty("Font", Ambient.Font)
End Sub

Private Sub UserControl_WriteProperties(PropBag As PropertyBag)
Call PropBag.WriteProperty("Font", m_stdFont, Ambient.Font)
End Sub

Private Sub UserControl_Show()
Set UserControl.Font = m_stdFont
End Sub


Public Property Get Font() As StdFont
Set Font = m_stdFont
End Property

Public Property Set Font(ByVal New_Font As StdFont)
方法 A:
Set m_stdFont = New_Font
PropertyChanged "Font"
End Property

[TrueZq]

如果照上面的一般做法，答案就是24
但如果控件作者这样实现 Font属性的话
结果就不同了。

方法 B:
'Set m_stdFont = New_Font
'拷贝字体属性
With m_stdFont
.Bold = New_Font.Bold
.Italic = New_Font.Italic
.Name = New_Font.Name
.Size = New_Font.Size
'......
End With

[zyl910]

那就没变——12