大家帮忙过来瞧瞧吧!这是什么东东啊?

[fruit89]

我想问一下大家,我的电脑的D盘和其它的盘不能够双击打开?还出现"window 找不到"copy.exe"请确定文件名是否正确....."这怎么回事,请大家帮帮忙,谢谢

[zara]

鼠标右键 D: 盘, 选择 "打开" 后进去, 将 autorun.inf 删除了

[blackfox0322]

给楼上的补充一下，可能autorun.inf是隐藏的，你要先把它设置为可见

[liujie625]

如果看不到的话可以运行CMD
DEL /F/S/Q /A:H D:\autorun.inf

[Forever_Young]

去年给人家写了一个清理autorun.inf的批处理，楼主用得着，复制下面的，粘贴到记事本里另存为BAT文件，双击运行就可以清理了

[code=BatchFile]
@echo off

title 清理AUTORUN.INF --- BY 佛爱我羊 [2007]

cls

color fc

echo.&echo.

for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
if exist %%a:\ (
if exist %%a:\autorun.inf (
echo 发现%%a盘上有AUTORUN.INF,正在清理...
attrib %%a:\autorun.inf -s -h -r
for /f "tokens=2* delims==" %%b in (%%a:\autorun.inf) do (
if exist %%a:\%%b (
attrib %%a:\%%b -s -h -r
del %%a:\%%b
echo 清理了%%a盘上AUTORUN.INF相关联的%%b
)
)
del %%a:\autorun.inf
echo %%a盘上AUTORUN.INF清理成功！
) else (
echo %%a盘上没有发现AUTORUN.INF。
)
echo.&echo.
)
)

reg query "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\">nul
if %ERRORLEVEL%==0 (
echo Y|reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\" /f>nul
echo 磁盘卷装入点清理完成！)

echo.&echo.&echo 完成清理，按任意键退出！&pause>nul
[/code]

[ljc007]

我也来一个，呵呵。

[code=BatchFile]@echo off
rem 代码将用for循环遍历所有的磁盘分区
set AllDrive=c d e f g h i j k l m n o p q r s t u v w x y z
for %%a in (%AllDrive%) do (
rem 取消关键文件的所有属性
attrib %%a:\autorun.inf -r -h -s -a
rem 删除关键文件
del /f /q %%a:\autorun.inf
rem 创建保护目录以防止被病毒再次感染
md %%a:\autorun.inf
md %%a:\autorun.inf\lszf..\
rem 取消保护目录的读写权限以防止病毒破坏保护目录
echo y|cacls %%a:\autorun.inf /d everyone
rem 清空回收站里面的病毒余孽
del /f /s /q %%a:\RECYCLER\*.*
)

rem 禁止U盘自动运行
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v NoDriveTypeAutoRun /t reg_dword /d 255 /f

rem 取消所有的自启动项
reg delete HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Run /va /f
reg delete HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /va /f

rem 重新启动计算机
echo Press "Enter" key to restart the computer
pause>nul
start shutdown -r -f -t 0[/code]

[下一站西单]

受教了