全部
基础类
应用实例
新技术前沿

转换表的结构

wnba1983 2008-03-04 09:13:15

有一个表，结构如下：

姓名课程分数
---------------------------
张三语文 80
张三数学 80
张三英语 80
李四语文 90
李四数学 90
李四英语 90

要求转换了以后变成以下结构

姓名语文数学英语
------------------------------
张三 80 80 90
李四 90 90 90

...全文

58 点赞收藏 11

写回复

11 条回复

切换为时间正序

当前发帖距今超过3年，不再开放新的回复

发表回复

knowledge_Is_Life 2008-05-01

以后需再关注，现在先帮你顶一下

回复赞

kavguodawei 2008-04-29

使用了group by和max，通过case语句筛选。不知道这个总结对不？

回复赞

wingtech520 2008-04-24

if object_id('tempdb..#')is not null

exec ('drop table #')

 create table # (姓名 nvarchar(15),课程 nvarchar(15),分数 float(10))

 insert  #  select '张三','数学' ,89 union  select '李四','语文',65 union  select '张三','语文',78 union  select '李四','数学',87 union  select '王五','生物',100

 declare @sql nvarchar(4000)

 set @sql='select 姓名 '

 select @sql=@sql+',''['+课程+']''=isnull(max(case when 课程='''+课程+''' then 分数 else 0 end),0)' from (select distinct 课程 from #)A

 set @sql= @sql+' from # group by 姓名'

 exec (@sql)

姓名 [生物] [数学] [语文]
--------------- ------------------------ ------------------------ ------------------------
李四 0.0 87.0 65.0
王五 100.0 0.0 0.0
张三 0.0 89.0 78.0

回复赞

wnba1983 2008-04-23

[Quote=引用 1 楼 dawugui 的回复:]
SQL code/*
普通行列转换
(爱新觉罗.毓华 2007-11-18于海南三亚)

假设有张学生成绩表(tb)如下:
Name Subject Result
张三语文　　74
张三数学　　83
张三物理　　93
李四语文　　74
李四数学　　84
李四物理　　94
*/

-------------------------------------------------------------------------
/*
想变成
姓名语文数学物理
---------- ----------- ----------…
[/Quote]

你测试一下发个给我好么，我测试没有一个能通过。。。

回复赞

cxmcxm 2008-03-04

--设表名为tb

select 姓名,

    语文=(select top 1 分数 from tb where 姓名=a.姓名 and 课程='语文'),

    数学=(select top 1 分数 from tb where 姓名=a.姓名 and 课程='数学'),

	英语=(select top 1 分数 from tb where 姓名=a.姓名 and 课程='英语')



from (select distinct 姓名 from tb) a

回复赞

Limpire 2008-03-04

--> 测试数据: #T

if object_id('tempdb.dbo.#T') is not null drop table #T

create table #T (姓名 varchar(4),课程 varchar(4),分数 int)

insert into #T

select '张三','语文',81 union all

select '张三','数学',82 union all

select '张三','英语',83 union all

select '李四','语文',91 union all

select '李四','数学',92 union all

select '李四','英语',93



--> 2000 静态

select

	姓名,

	语文=max(case 课程 when '语文' then 分数 else 0 end),

	数学=max(case 课程 when '数学' then 分数 else 0 end),

	英语=max(case 课程 when '英语' then 分数 else 0 end)

from #T

group by 姓名



--> 2000 动态

declare @2000 nvarchar(4000)

select @2000=isnull(@2000+',','')+'['+课程+']=max(case 课程 when '''+课程+''' then 分数 else 0 end)' from #T group by 课程

exec ('select 姓名,'+@2000+' from #T group by 姓名')



--> 2005 静态

select * from (select * from #T) a pivot (max(分数) for 课程 in (语文,数学,英语)) b



--> 2005 动态

declare @2005 nvarchar(4000)

select @2005=isnull(@2005+',','')+课程 from #T group by 课程

exec ('select * from (select * from #T) a pivot (max(分数) for 课程 in ('+@2005+')) b')

回复赞

ssyqcwj 2008-03-04

好厉害啊!佩服,佩服!

回复赞

dawugui 2008-03-04

create table tb(姓名 varchar(10) , 课程 varchar(10) , 分数 int)

insert into tb values('张三', '语文', 80 )

insert into tb values('张三', '数学', 80 )

insert into tb values('张三', '英语', 80 )

insert into tb values('李四', '语文', 90 )

insert into tb values('李四', '数学', 90 )

insert into tb values('李四', '英语', 90 )

go



--静止SQL，指课程只有语文，数学，英语三科

select 姓名,

  max(case 课程 when '语文' then 分数 else 0 end) '语文',

  max(case 课程 when '数学' then 分数 else 0 end) '数学',

  max(case 课程 when '英语' then 分数 else 0 end) '英语'

from tb

group by 姓名

/*

姓名         语文          数学          英语          

---------- ----------- ----------- ----------- 

李四         90          90          90

张三         80          80          80

（所影响的行数为 2 行）

*/



--动态SQL，指课程不只语文，数学，英语三科

declare @sql varchar(8000)

set @sql = 'select 姓名'

select @sql = @sql + ' , max(case 课程 when ''' + 课程 + ''' then 分数 else 0 end) [' + 课程 + ']'

from (select distinct 课程 from tb) as a

set @sql = @sql + ' from tb group by 姓名'

exec(@sql) 

/*

姓名         数学          英语          语文          

---------- ----------- ----------- ----------- 

李四         90          90          90

张三         80          80          80

*/



drop table tb

回复赞

dawugui 2008-03-04

create table tb(姓名 varchar(10) , 课程 varchar(10) , 分数 int)

insert into tb values('张三', '语文', 80 )

insert into tb values('张三', '数学', 80 )

insert into tb values('张三', '英语', 80 )

insert into tb values('李四', '语文', 90 )

insert into tb values('李四', '数学', 90 )

insert into tb values('李四', '英语', 90 )

go



select 姓名,

  max(case 课程 when '语文' then 分数 else 0 end) '语文',

  max(case 课程 when '数学' then 分数 else 0 end) '数学',

  max(case 课程 when '英语' then 分数 else 0 end) '英语'

from tb

group by 姓名



drop table tb



/*

姓名         语文          数学          英语          

---------- ----------- ----------- ----------- 

李四         90          90          90

张三         80          80          80



（所影响的行数为 2 行）

*/

回复赞

dawugui 2008-03-04

select 姓名,

  max(case 课程 when '语文' then 分数 else 0 end) '语文',

  max(case 课程 when '数学' then 分数 else 0 end) '数学',

  max(case 课程 when '英语' then 分数 else 0 end) '英语'

from tb

group by 姓名

回复赞

dawugui 2008-03-04

/*

普通行列转换

(爱新觉罗.毓华 2007-11-18于海南三亚)



假设有张学生成绩表(tb)如下:

Name Subject Result

张三 语文　　74

张三 数学　　83

张三 物理　　93

李四 语文　　74

李四 数学　　84

李四 物理　　94

*/



-------------------------------------------------------------------------

/*

想变成 

姓名         语文        数学        物理          

---------- ----------- ----------- ----------- 

李四         74          84          94

张三         74          83          93

*/



create table tb

(

   Name    varchar(10) ,

   Subject varchar(10) ,

   Result  int

)



insert into tb(Name , Subject , Result) values('张三' , '语文' , 74)

insert into tb(Name , Subject , Result) values('张三' , '数学' , 83)

insert into tb(Name , Subject , Result) values('张三' , '物理' , 93)

insert into tb(Name , Subject , Result) values('李四' , '语文' , 74)

insert into tb(Name , Subject , Result) values('李四' , '数学' , 84)

insert into tb(Name , Subject , Result) values('李四' , '物理' , 94)

go



--静态SQL,指subject只有语文、数学、物理这三门课程。

select name 姓名,

  max(case subject when '语文' then result else 0 end) 语文,

  max(case subject when '数学' then result else 0 end) 数学,

  max(case subject when '物理' then result else 0 end) 物理

from tb

group by name

/*

姓名         语文        数学        物理          

---------- ----------- ----------- ----------- 

李四         74          84          94

张三         74          83          93

*/



--动态SQL,指subject不止语文、数学、物理这三门课程。

declare @sql varchar(8000)

set @sql = 'select Name as ' + '姓名'

select @sql = @sql + ' , max(case Subject when ''' + Subject + ''' then Result else 0 end) [' + Subject + ']'

from (select distinct Subject from tb) as a

set @sql = @sql + ' from tb group by name'

exec(@sql) 

/*

姓名         数学        物理        语文          

---------- ----------- ----------- ----------- 

李四         84          94          74

张三         83          93          74

*/



-------------------------------------------------------------------

/*加个平均分，总分

姓名         语文        数学        物理        平均分                总分          

---------- ----------- ----------- ----------- -------------------- ----------- 

李四         74          84          94          84.00                252

张三         74          83          93          83.33                250

*/



--静态SQL,指subject只有语文、数学、物理这三门课程。

select name 姓名,

  max(case subject when '语文' then result else 0 end) 语文,

  max(case subject when '数学' then result else 0 end) 数学,

  max(case subject when '物理' then result else 0 end) 物理,

  cast(avg(result*1.0) as decimal(18,2)) 平均分,

  sum(result) 总分

from tb

group by name

/*

姓名         语文        数学        物理        平均分                总分          

---------- ----------- ----------- ----------- -------------------- ----------- 

李四         74          84          94          84.00                252

张三         74          83          93          83.33                250

*/



--动态SQL,指subject不止语文、数学、物理这三门课程。

declare @sql1 varchar(8000)

set @sql1 = 'select Name as ' + '姓名'

select @sql1 = @sql1 + ' , max(case Subject when ''' + Subject + ''' then Result else 0 end) [' + Subject + ']'

from (select distinct Subject from tb) as a

set @sql1 = @sql1 + ' , cast(avg(result*1.0) as decimal(18,2)) 平均分,sum(result) 总分 from tb group by name'

exec(@sql1) 

/*

姓名         数学        物理        语文        平均分                总分          

---------- ----------- ----------- ----------- -------------------- ----------- 

李四         84          94          74          84.00                252

张三         83          93          74          83.33                250

*/



drop table tb	



---------------------------------------------------------

---------------------------------------------------------

/*

如果上述两表互相换一下：即



姓名 语文 数学 物理

张三 74　　83　　93

李四 74　　84　　94



想变成 

Name       Subject Result      

---------- ------- ----------- 

李四         语文      74

李四         数学      84

李四         物理      94

张三         语文      74

张三         数学      83

张三         物理      93

*/



create table tb1

(

   姓名 varchar(10) ,

   语文 int ,

   数学 int ,

   物理 int

)



insert into tb1(姓名 , 语文 , 数学 , 物理) values('张三',74,83,93)

insert into tb1(姓名 , 语文 , 数学 , 物理) values('李四',74,84,94)



select * from

(

  select 姓名 as Name , Subject = '语文' , Result = 语文 from tb1 

  union all

  select 姓名 as Name , Subject = '数学' , Result = 数学 from tb1

  union all

  select 姓名 as Name , Subject = '物理' , Result = 物理 from tb1

) t

order by name , case Subject when '语文' then 1 when '数学' then 2 when '物理' then 3 when '总分' then 4 end



--------------------------------------------------------------------

/*加个平均分,总分

Name       Subject     Result               

---------- -------    -------------------- 

李四         语文      74.00

李四         数学      84.00

李四         物理      94.00

李四         平均分    84.00

李四         总分      252.00

张三         语文      74.00

张三         数学      83.00

张三         物理      93.00

张三         平均分    83.33

张三         总分      250.00

*/



select * from

(

  select 姓名 as Name , Subject = '语文' , Result = 语文 from tb1 

  union all

  select 姓名 as Name , Subject = '数学' , Result = 数学 from tb1

  union all

  select 姓名 as Name , Subject = '物理' , Result = 物理 from tb1

  union all

  select 姓名 as Name , Subject = '平均分' , Result = cast((语文 + 数学 + 物理)*1.0/3 as decimal(18,2)) from tb1

  union all

  select 姓名 as Name , Subject = '总分' , Result = 语文 + 数学 + 物理 from tb1

) t

order by name , case Subject when '语文' then 1 when '数学' then 2 when '物理' then 3 when '平均分' then 4 when '总分' then 5 end



drop table tb1