变量赋值 输出问题.

[andyhooo]

.......
declare @totalCounts int
................
set @sql =N'select '+str(@totalCounts)+'=count(*) from '+@tblname

exec sp_executesql @sql,N'@totalcounts int output',@totalcounts output
select @totalcounts

请问我这里@totalcount 输出 是 Null 的??应该是 count(*) 的结果.

为什么是这样的??谢谢

[andyhooo]

[Quote=引用 1 楼 dawugui 的回复:]
SQL code--最后一段.

动态sql语句基本语法
1 :普通SQL语句可以用Exec执行

eg: Select * from tableName
Exec('select * from tableName')
Exec sp_executesql N'select * from tableName' -- 请注意字符串前一定要加N

2:字段名，表名，数据库名之类作为变量时，必须用动态SQL

eg:
declare @fname varchar(20)
set @fname = 'FiledName'
Select @fname from tableName …
[/Quote]

[pt1314917]

declare @sql nvarchar(4000)
declare @totalCounts int
set @sql =N'select @cnt=count(*) from '+@tblname
exec sp_executesql @sql,N'@cnt int output',@totalCounts output
select @totalcounts

[wzy_love_sly]

create table tb(id int,name varchar(20))
insert into tb select 1,'小磊'

declare @JobEnd varchar(50) ,@id int,@sql nvarchar(4000)
set @id=1
set @sql='select @JobEnd=name from tb where id='+ltrim(@id)
exec sp_executesql @sql,N'@JobEnd varchar(50) output',@JobEnd output 
print @JobEnd 

小磊

[dawugui]

--最后一段.

动态sql语句基本语法 
1 :普通SQL语句可以用Exec执行 

eg:   Select * from tableName 
         Exec('select * from tableName') 
         Exec sp_executesql N'select * from tableName'    -- 请注意字符串前一定要加N 

2:字段名，表名，数据库名之类作为变量时，必须用动态SQL 

eg:   
declare @fname varchar(20) 
set @fname = 'FiledName' 
Select @fname from tableName              -- 错误,不会提示错误，但结果为固定值FiledName,并非所要。 
Exec('select ' + @fname + ' from tableName')     -- 请注意 加号前后的 单引号的边上加空格 

当然将字符串改成变量的形式也可 
declare @fname varchar(20) 
set @fname = 'FiledName' --设置字段名 

declare @s varchar(1000) 
set @s = 'select ' + @fname + ' from tableName' 
Exec(@s)                -- 成功 
exec sp_executesql @s   -- 此句会报错 



declare @s Nvarchar(1000)  -- 注意此处改为nvarchar(1000) 
set @s = 'select ' + @fname + ' from tableName' 
Exec(@s)                -- 成功     
exec sp_executesql @s   -- 此句正确 

3. 输出参数 
declare @num int, 
        @sqls nvarchar(4000) 
set @sqls='select count(*) from tableName' 
exec(@sqls) 
--如何将exec执行结果放入变量中？ 

declare @num int, 
               @sqls nvarchar(4000) 
set @sqls='select @a=count(*) from tableName ' 
exec sp_executesql @sqls,N'@a int output',@num output 
select @num 

[andyhooo]

declare @num int, 
               @sqls nvarchar(4000) 
set @sqls='select @a=count(*) from tableName ' 
exec sp_executesql @sqls,N'@a int output',@num output 
select @num 

里面的@a是什么来的

[dawugui]

declare @num int, @sqls nvarchar(4000) 
set @sqls='select @a=count(*) from authors ' 
exec sp_executesql @sqls,N'@a int output',@num output 
select 'sql server 2000 自带示例库pubs的表ahthors的行数 = ' + cast(@num as varchar)

/*
sql server 2000 自带示例库pubs的表ahthors的行数 = 23

（所影响的行数为 1 行）
*/