请教各位大侠们一个关于“列转行”的问题

chenxin2835 2008-03-26 11:22:50
请教一下,下面的数据要列转行,除了我这个法子,还有没有更简洁,更有效率的法子?(小弟菜虫一条,分不多,只能10分意思一下,请勿怪)
/*
create table ProductAttribute(productid int , ProductAttribute varchar(10))
insert into ProductAttribute values(44 ,'圆形')
insert into ProductAttribute values(44 ,'SI')
insert into ProductAttribute values(44 ,'VG')
insert into ProductAttribute values(45 ,'方形')
insert into ProductAttribute values(45 ,'SI')
insert into ProductAttribute values(45 ,'VG')
insert into ProductAttribute values(46 ,'圆形')
insert into ProductAttribute values(46 ,'SI')
insert into ProductAttribute values(46 ,'VG')
go
*/
Select * from ProductAttribute

DECLARE lzh SCROLL CURSOR FOR
Select distinct productid from ProductAttribute

Declare @s nvarchar(1000),
@a int,
@b int
Set @s=''
Set @a=0
Set @b=0
open lzh
Fetch first From lzh into @a
Set @b=@a
while @@fetch_status =0
Begin
if @b=@a
Begin
Set @s='Select distinct productid'
Select @s=@s+','''+productattribute+''''
From(Select productid,productattribute
From productattribute
Where productid=@a
) as aa
set @s = @s + ' From productattribute where productid= convert(int,''' + convert(varchar(5),@a) + ''')'-- 拼接的必须是字符串类型
End
else
Begin
Set @s=@s+' Union Select distinct productid'
Select @s=@s+','''+productattribute+''''
From(Select productid,productattribute
From productattribute
Where productid=@a
) as bb
set @s = @s + ' From productattribute where productid= convert(int,''' + convert(varchar(5),@a) + ''')'
End

Fetch Next From lzh into @a
End
close lzh
deallocate lzh

exec(@s)
print(@s)
...全文
64 7 点赞 打赏 收藏 举报
写回复
7 条回复
切换为时间正序
当前发帖距今超过3年,不再开放新的回复
发表回复
chenxin2835 2008-03-26
没人接着回复了吗
  • 打赏
  • 举报
回复
chenxin2835 2008-03-26
小梁,谢谢你的回复,不过你给的这个老乌龟写的我都看过了,可是我觉得不合适我这种情况,我这个是2个列的
  • 打赏
  • 举报
回复
liangCK 2008-03-26
这个...似乎不需要用游标.
  • 打赏
  • 举报
回复
chenxin2835 2008-03-26
补充一下结果:
productid 无列名 无列名 无列名
44 圆形 SI VG
45 方形 SI VG
46 圆形 SI VG
47 菱形 XYZ NB
  • 打赏
  • 举报
回复
liangCK 2008-03-26
/*
标题:普通行列转换(version 2.0)
作者:爱新觉罗.毓华
时间:2008-03-09
地点:广东深圳
说明:普通行列转换(version 1.0)仅针对sql server 2000提供静态和动态写法,version 2.0增加sql server 2005的有关写法。

问题:假设有张学生成绩表(tb)如下:
姓名 课程 分数
张三 语文 74
张三 数学 83
张三 物理 93
李四 语文 74
李四 数学 84
李四 物理 94
想变成(得到如下结果):
姓名 语文 数学 物理
---- ---- ---- ----
李四 74 84 94
张三 74 83 93
-------------------
*/

create table tb(姓名 varchar(10) , 课程 varchar(10) , 分数 int)
insert into tb values('张三' , '语文' , 74)
insert into tb values('张三' , '数学' , 83)
insert into tb values('张三' , '物理' , 93)
insert into tb values('李四' , '语文' , 74)
insert into tb values('李四' , '数学' , 84)
insert into tb values('李四' , '物理' , 94)
go

--SQL SERVER 2000 静态SQL,指课程只有语文、数学、物理这三门课程。(以下同)
select 姓名 as 姓名 ,
max(case 课程 when '语文' then 分数 else 0 end) 语文,
max(case 课程 when '数学' then 分数 else 0 end) 数学,
max(case 课程 when '物理' then 分数 else 0 end) 物理
from tb
group by 姓名

--SQL SERVER 2000 动态SQL,指课程不止语文、数学、物理这三门课程。(以下同)
declare @sql varchar(8000)
set @sql = 'select 姓名 '
select @sql = @sql + ' , max(case 课程 when ''' + 课程 + ''' then 分数 else 0 end) [' + 课程 + ']'
from (select distinct 课程 from tb) as a
set @sql = @sql + ' from tb group by 姓名'
exec(@sql)

--SQL SERVER 2005 静态SQL。
select * from (select * from tb) a pivot (max(分数) for 课程 in (语文,数学,物理)) b

--SQL SERVER 2005 动态SQL。
declare @sql varchar(8000)
select @sql = isnull(@sql + ',' , '') + 课程 from tb group by 课程
exec ('select * from (select * from tb) a pivot (max(分数) for 课程 in (' + @sql + ')) b')

---------------------------------

/*
问题:在上述结果的基础上加平均分,总分,得到如下结果:
姓名 语文 数学 物理 平均分 总分
---- ---- ---- ---- ------ ----
李四 74 84 94 84.00 252
张三 74 83 93 83.33 250
*/

--SQL SERVER 2000 静态SQL。
select 姓名 姓名,
max(case 课程 when '语文' then 分数 else 0 end) 语文,
max(case 课程 when '数学' then 分数 else 0 end) 数学,
max(case 课程 when '物理' then 分数 else 0 end) 物理,
cast(avg(分数*1.0) as decimal(18,2)) 平均分,
sum(分数) 总分
from tb
group by 姓名

--SQL SERVER 2000 动态SQL。
declare @sql varchar(8000)
set @sql = 'select 姓名 '
select @sql = @sql + ' , max(case 课程 when ''' + 课程 + ''' then 分数 else 0 end) [' + 课程 + ']'
from (select distinct 课程 from tb) as a
set @sql = @sql + ' , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名'
exec(@sql)

--SQL SERVER 2005 静态SQL。
select m.* , n.平均分 , n.总分 from
(select * from (select * from tb) a pivot (max(分数) for 课程 in (语文,数学,物理)) b) m,
(select 姓名 , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名) n
where m.姓名 = n.姓名

--SQL SERVER 2005 动态SQL。
declare @sql varchar(8000)
select @sql = isnull(@sql + ',' , '') + 课程 from tb group by 课程
exec ('select m.* , n.平均分 , n.总分 from
(select * from (select * from tb) a pivot (max(分数) for 课程 in (' + @sql + ')) b) m ,
(select 姓名 , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名) n
where m.姓名 = n.姓名')

drop table tb

------------------
------------------

/*
问题:如果上述两表互相换一下:即表结构和数据为:
姓名 语文 数学 物理
张三 74  83  93
李四 74  84  94
想变成(得到如下结果):
姓名 课程 分数
---- ---- ----
李四 语文 74
李四 数学 84
李四 物理 94
张三 语文 74
张三 数学 83
张三 物理 93
--------------
*/

create table tb(姓名 varchar(10) , 语文 int , 数学 int , 物理 int)
insert into tb values('张三',74,83,93)
insert into tb values('李四',74,84,94)
go

--SQL SERVER 2000 静态SQL。
select * from
(
select 姓名 , 课程 = '语文' , 分数 = 语文 from tb
union all
select 姓名 , 课程 = '数学' , 分数 = 数学 from tb
union all
select 姓名 , 课程 = '物理' , 分数 = 物理 from tb
) t
order by 姓名 , case 课程 when '语文' then 1 when '数学' then 2 when '物理' then 3 end

--SQL SERVER 2000 动态SQL。
--调用系统表动态生态。
declare @sql varchar(8000)
select @sql = isnull(@sql + ' union all ' , '' ) + ' select 姓名 , [课程] = ' + quotename(Name , '''') + ' , [分数] = ' + quotename(Name) + ' from tb'
from syscolumns
where name! = N'姓名' and ID = object_id('tb') --表名tb,不包含列名为姓名的其它列
order by colid asc
exec(@sql + ' order by 姓名 ')

--SQL SERVER 2005 动态SQL。
select 姓名 , 课程 , 分数 from tb unpivot (分数 for 课程 in([语文] , [数学] , [物理])) t

--SQL SERVER 2005 动态SQL,同SQL SERVER 2000 动态SQL。

--------------------
/*
问题:在上述的结果上加个平均分,总分,得到如下结果:
姓名 课程 分数
---- ------ ------
李四 语文 74.00
李四 数学 84.00
李四 物理 94.00
李四 平均分 84.00
李四 总分 252.00
张三 语文 74.00
张三 数学 83.00
张三 物理 93.00
张三 平均分 83.33
张三 总分 250.00
------------------
*/

select * from
(
select 姓名 as 姓名 , 课程 = '语文' , 分数 = 语文 from tb
union all
select 姓名 as 姓名 , 课程 = '数学' , 分数 = 数学 from tb
union all
select 姓名 as 姓名 , 课程 = '物理' , 分数 = 物理 from tb
union all
select 姓名 as 姓名 , 课程 = '平均分' , 分数 = cast((语文 + 数学 + 物理)*1.0/3 as decimal(18,2)) from tb
union all
select 姓名 as 姓名 , 课程 = '总分' , 分数 = 语文 + 数学 + 物理 from tb
) t
order by 姓名 , case 课程 when '语文' then 1 when '数学' then 2 when '物理' then 3 when '平均分' then 4 when '总分' then 5 end

drop table tb
  • 打赏
  • 举报
回复
chenxin2835 2008-03-26
泪如雨下,搞了半天反而越来越复杂了
Declare @s nvarchar(1000),
@n nvarchar(20),
@a int,
@b int,
@h Int
Set @s=''
Set @n=''
Set @a=0
Set @h=0
Select @h=Count(*)*3,@b=min(productid) From(Select distinct productid from ProductAttribute)as yy

While @h>0
Begin
Set Rowcount @h

Select *
Into #temp
From productattribute order by productid desc

Select Top 3 @a=productid,@n=ProductAttribute
From #temp
order by productid

if @b=@a
Begin
Set @s='Select distinct productid'
Select @s=@s+','''+productattribute+''''
From(Select productid,productattribute
From productattribute
Where productid=@a
) as aa
set @s = @s + ' From productattribute where productid= convert(int,''' + convert(varchar(5),@a) + ''')'
End
else
Begin
Set @s=@s+' Union Select distinct productid'
Select @s=@s+','''+productattribute+''''
From(Select productid,productattribute
From productattribute
Where productid=@a
) as bb
set @s = @s + ' From productattribute where productid= convert(int,''' + convert(varchar(5),@a) + ''')'
End

Set @h=@h-3
Drop Table #temp
Set rowcount 0
End

exec(@s)
print(@s)
  • 打赏
  • 举报
回复
chenxin2835 2008-03-26
郁闷了,我还是搞不定啊,乌龟啊,救救我吧@,@
  • 打赏
  • 举报
回复
相关推荐
发帖
应用实例
加入

2.7w+

社区成员

MS-SQL Server 应用实例
申请成为版主
帖子事件
创建了帖子
2008-03-26 11:22
社区公告
暂无公告