如何在VB6.0窗体中设计成上下两部分结构

whd100 2008-04-09 10:44:08

在VB6.0窗体中，如何设计成上下两部分的布局，如下图所示
_____________
| |
| |
| |
| |
|_____________|
| |
| |
|_____________|

通过中间的横线可以自由调节这两个区域的上下高度？请指教！

...全文

203 点赞收藏 20

写回复

20 条回复

切换为时间正序

当前发帖距今超过3年，不再开放新的回复

发表回复

wfzhu2000 2008-04-12

做个记号

回复赞

东方之珠 2008-04-10

这个题目有意思.我没弄过,好像要专门控件...

回复赞

whd100 2008-04-10

谢谢楼上的几位

回复赞

嗷嗷叫的老马 2008-04-10

干脆打个包,免得以后要用时再花细胞去想.

http://www.m5home.com/blog/article.asp?id=88

是个完整工程....

回复赞

denken1015 2008-04-10

mouse事件大概代码（没有加越界判断）其中 Picture1为上窗体，Picture2为下窗体，Picture3为上下窗体中间的
拖动条。lable1为判断鼠标是否在Picture3上按下
Private Sub Picture3_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
Label1.Caption = 1
End Sub

Private Sub Picture3_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
If Label1.Caption = "1" Then
Picture3.Top = Picture3.Top + Y
Picture1.Height = Picture1.Height + Y
Picture2.Top = Picture2.Top + Y
Picture2.Height = Picture2.Height - Y
End If

End Sub

Private Sub Picture3_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
Picture3.Top = Picture3.Top + Y
Label1.Caption = 0
End Sub

回复赞

嗷嗷叫的老马 2008-04-10

Option Explicit



Private Const AsyncMove As Boolean = False      '实时移动控制



Dim mY As Long, AllHei As Long



Private Sub Form_Load()

    AllHei = Picture2.Top + Picture2.Height         '把大小极限先记录一下

End Sub



Private Sub Label1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)

    mY = Y          '鼠标按下时的鼠标坐标

End Sub



Private Sub Label1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)

    If Button And vbLeftButton Then

        Dim tmpTop As Long

        

        With Label1

            tmpTop = .Top + Y - mY      '计算应该移动到的坐标

            

            If tmpTop <= Picture1.Top Then tmpTop = Picture1.Top        '数值合法化

            If tmpTop >= AllHei - .Height Then tmpTop = AllHei - .Height

            

            .Move .Left, tmpTop             '先移动"分割条"

            

            If AsyncMove = False Then

                Picture1.Height = .Top - Picture1.Top       '再移动各控件

                Picture2.Top = .Top + .Height

                Picture2.Height = AllHei - Picture2.Top

            End If

        End With

    End If

End Sub



Private Sub Label1_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)

    If AsyncMove = True Then

        With Label1

            Picture1.Height = .Top - Picture1.Top       '再移动各控件

            Picture2.Top = .Top + .Height

            Picture2.Height = AllHei - Picture2.Top

        End With

    End If

End Sub