34,838
社区成员
发帖
与我相关
我的任务
分享行列转换
原表：
地区 初级人数 中级人数 高级人数 ...
北京 0 12 15
上海 2 5 7
...
转为：
级别 北京 上海 ...
初级人数 0 2
中级人数 12 5
高级人数 15 7
...
基本要求：地区动态，级别不变
高级要求：地区动态，级别动态
有点难度，请教高高手
地区 初级人数 中级人数 高级人数 ...
北京 0 12 15
上海 2 5 7
...
转为：
级别 北京 上海 ...
初级人数 0 2
中级人数 12 5
高级人数 15 7
...
基本要求：地区动态，级别不变
高级要求：地区动态，级别动态
有点难度，请教高高手
...全文
请发表友善的回复…
发表回复
dulei115 2008-04-16
- 打赏
- 举报
select '北京' as 地区, 0 as 初级人数, 12 as 中级人数, 15 as 高级人数
into 表
union select '上海', 2, 5, 7
go
declare @s varchar(8000), @tmp1 varchar(8000), @tmp2 varchar(10)
select @tmp1 = '', @tmp2 = '级别人数'
select @tmp1 = @tmp1 + ', sum(case 地区 when ''' + 地区 + ''' then ' + @tmp2 + ' else 0 end) as ' + 地区
from (select distinct 地区 from 表) a
order by 地区
set @s = ''
select @s = @s + ' union select ''' + [name] + ''' as 级别' + replace(@tmp1, @tmp2, [name]) + ' from 表'
from syscolumns
where [id] = object_id('表') and colid > 1
order by colid
set @s = right(@s, len(@s) - 7)
exec(@s)
/*
级别 北京 上海
-------- ---- ----
初级人数 0 2
高级人数 15 7
中级人数 12 5
*/
go
drop table 表
suchabbs 2008-04-16
- 打赏
- 举报
哈 爱新觉罗.毓华 好眼熟
liangCK 2008-04-16
- 打赏
- 举报
--处理示例
--示例数据
create table tb(A int,B int,C int,D int)
insert tb select 1,2 ,3 ,4
union all select 5,6 ,7 ,8
union all select 9,10,11,12
go
--查询处理
declare @s1 varchar(8000),@s2 varchar(8000)
,@s3 varchar(8000),@s4 varchar(8000),@s5 varchar(8000)
,@i varchar(10)
select @s1='',@s2='',@s3='',@s4='',@s5='',@i='0'
select @s1=@s1+',@'+@i+' varchar(8000)'
,@s2=@s2+',@'+@i+'=''[字段1]='''''+name+''''''''
,@s3=@s3+'
,@'+@i+'=@'+@i+'+'',[字段''+cast(@i as varchar)+'']=''+cast(['+name+'] as varchar)'
,@s4=@s4+',@'+@i+'=''select ''+@'+@i
,@s5=@s5+'+'' union all ''+@'+@i
,@i=cast(@i as int)+1
from syscolumns
where object_id('tb')=id
select @s1=stuff(@s1,1,1,'')
,@s2=stuff(@s2,1,1,'')
,@s4=stuff(@s4,1,1,'')
,@s5=stuff(@s5,1,15,'')
exec('declare '+@s1+',@i int
select '+@s2+'
set @i=1
select @i=@i+1'+@s3+'
from tb
select '+@s4+'
exec('+@s5+')')
go
--删除测试表
drop table tb
/*--测试结果
字段1 字段2 字段3 字段4
---- ----------- ----------- -----------
A 1 5 9
B 2 6 10
C 3 7 11
D 4 8 12
（所影响的行数为 4 行）
--*/
bfdhh 2008-04-16
- 打赏
- 举报
前二个回复不对题
liangCK 2008-04-16
- 打赏
- 举报
create table tb(地区 varchar(20),初级人数 int,中级人数 int,高级人数 int)
insert tb select '北京',0,12,15
insert tb select '上海',2,5,7
declare @f1 varchar(8000),@f2 varchar(8000),@f3 varchar(8000)
select @f1='',@f2='',@f3=''
select @f1=@f1+',['+地区+']='''+ltrim([初级人数])+''''
,@f2=@f2+','''+ltrim([中级人数])+''''
,@f3=@f3+','''+ltrim([高级人数])+''''
from tb
exec('select 地区=''初级人数'''+@f1
+' union all select ''中级人数'''+@f2
+' union all select ''高级人数'''+@f3)
go
drop table tb
/*
地区 北京 上海
-------- ---- ----
初级人数 0 2
中级人数 12 5
高级人数 15 7
*/
zccmy22 2008-04-16
- 打赏
- 举报
兄弟帮你顶一下吧。你看一下，要是有看不明白的，发一下，看能不能帮你看看。好像每一个人的问，他们也是这样告诉我的好像。呵呵。不过也应这样，自己解决了才是自己的。加油。
liangCK 2008-04-16
- 打赏
- 举报
--行列互换
/*--有表
indust 200301 200302 200303
---------- ---------- ---------- ----------
a 111 222 333
b 444 555 666
c 777 888 999
d 789 910 012
--要求得到结果
日期 a b c d
------ ---- ---- ---- ----
200301 111 444 777 789
200302 222 555 888 910
200303 333 666 999 012
--*/
--创建测试表
create table test(indust varchar(10)
,[200301] varchar(10)
,[200302] varchar(10)
,[200303] varchar(10))
insert test select 'a','111','222','333'
union all select 'b','444','555','666'
union all select 'c','777','888','999'
union all select 'd','789','910','012'
go
--数据处理
declare @f1 varchar(8000),@f2 varchar(8000),@f3 varchar(8000)
select @f1='',@f2='',@f3=''
select @f1=@f1+',['+indust+']='''+[200301]+''''
,@f2=@f2+','''+[200302]+''''
,@f3=@f3+','''+[200303]+''''
from test
exec('select 日期=''200301'''+@f1
+' union all select ''200302'''+@f2
+' union all select ''200303'''+@f3)
go
--删除测试表
select * from test
drop table test
/*--测试结果
日期 a b c d
------ ---- ---- ---- ----
200301 111 444 777 789
200302 222 555 888 910
200303 333 666 999 012
--*/
wlinglong 2008-04-16
- 打赏
- 举报
两种比较特殊的交叉数据报表处理 --示例数据:
CREATE TABLE tb(ID varchar(10),NGNO char(1),QTY int)
INSERT tb SELECT '200505','A',10
UNION ALL SELECT '200505','B',20
UNION ALL SELECT '200505','C',30
UNION ALL SELECT '200506','B',10
UNION ALL SELECT '200506','C',20
UNION ALL SELECT '200506','D',30
UNION ALL SELECT '200506','E',40
GO
交叉数据报表要求1:
按ID列分组，将NGNO列水平显示为多列，但每列由NGNO的大小顺序决定，而不是由NGNO的值决定，对于示例数据，最终的结果要求如下：
ID col1 col2 col3 col4
---------- ------- ------- ------- -------
200505 A(10) B(20) C(30)
200506 B(10) C(20) D(30) E(40)
--实现代码
DECLARE @i varchar(10),@s nvarchar(4000)
SELECT TOP 1 @s='',@I=COUNT(*) FROM tb
GROUP BY ID
ORDER BY COUNT(*) DESC
WHILE @i>0
SELECT @s=N',col'+@i
+N'=ISNULL(MAX(CASE GID WHEN '+@i
+N' THEN QTY END),'''')'+@s,
@i=@i-1
EXEC(N'SELECT ID'+@s+N'
FROM(
SELECT ID,QTY=RTRIM(NGNO)+QUOTENAME(QTY,N''()''),
GID=(SELECT COUNT(DISTINCT NGNO) FROM TB WHERE ID=a.ID AND NGNO<=a.NGNO)
FROM tb a
)a GROUP BY ID')
GO
交叉数据报表要求2:
按ID列分组，将NGNO及QTY列合并显示在一个列中，最终的结果要求如下：
ID Value
---------- -----------------------------------------------
200505 A(10) B(20) C(30)
200506 B(10) C(20) D(30) E(40)
（所影响的行数为 2 行）
--实现处理的函数
CREATE FUNCTION f_Str(@ID varchar(10))
RETURNS varchar(8000)
AS
BEGIN
DECLARE @r varchar(8000)
SET @r=''
SELECT @r=@r+SPACE(8)+RTRIM(NGNO)+QUOTENAME(QTY,'()')
FROM tb
WHERE ID=@ID
RETURN(STUFF(@r,1,8,''))
END
GO
--调用实现查询
SELECT ID,Value=dbo.f_Str(ID) FROM tb GROUP BY ID
GO
CREATE TABLE tb(ID varchar(10),NGNO char(1),QTY int)
INSERT tb SELECT '200505','A',10
UNION ALL SELECT '200505','B',20
UNION ALL SELECT '200505','C',30
UNION ALL SELECT '200506','B',10
UNION ALL SELECT '200506','C',20
UNION ALL SELECT '200506','D',30
UNION ALL SELECT '200506','E',40
GO
交叉数据报表要求1:
按ID列分组，将NGNO列水平显示为多列，但每列由NGNO的大小顺序决定，而不是由NGNO的值决定，对于示例数据，最终的结果要求如下：
ID col1 col2 col3 col4
---------- ------- ------- ------- -------
200505 A(10) B(20) C(30)
200506 B(10) C(20) D(30) E(40)
--实现代码
DECLARE @i varchar(10),@s nvarchar(4000)
SELECT TOP 1 @s='',@I=COUNT(*) FROM tb
GROUP BY ID
ORDER BY COUNT(*) DESC
WHILE @i>0
SELECT @s=N',col'+@i
+N'=ISNULL(MAX(CASE GID WHEN '+@i
+N' THEN QTY END),'''')'+@s,
@i=@i-1
EXEC(N'SELECT ID'+@s+N'
FROM(
SELECT ID,QTY=RTRIM(NGNO)+QUOTENAME(QTY,N''()''),
GID=(SELECT COUNT(DISTINCT NGNO) FROM TB WHERE ID=a.ID AND NGNO<=a.NGNO)
FROM tb a
)a GROUP BY ID')
GO
交叉数据报表要求2:
按ID列分组，将NGNO及QTY列合并显示在一个列中，最终的结果要求如下：
ID Value
---------- -----------------------------------------------
200505 A(10) B(20) C(30)
200506 B(10) C(20) D(30) E(40)
（所影响的行数为 2 行）
--实现处理的函数
CREATE FUNCTION f_Str(@ID varchar(10))
RETURNS varchar(8000)
AS
BEGIN
DECLARE @r varchar(8000)
SET @r=''
SELECT @r=@r+SPACE(8)+RTRIM(NGNO)+QUOTENAME(QTY,'()')
FROM tb
WHERE ID=@ID
RETURN(STUFF(@r,1,8,''))
END
GO
--调用实现查询
SELECT ID,Value=dbo.f_Str(ID) FROM tb GROUP BY ID
GO
liangCK 2008-04-16
- 打赏
- 举报
/*
标题：普通行列转换(version 2.0)
作者：爱新觉罗.毓华
时间：2008-03-09
地点：广东深圳
说明：普通行列转换(version 1.0)仅针对sql server 2000提供静态和动态写法，version 2.0增加sql server 2005的有关写法。
问题：假设有张学生成绩表(tb)如下:
姓名 课程 分数
张三 语文 74
张三 数学 83
张三 物理 93
李四 语文 74
李四 数学 84
李四 物理 94
想变成(得到如下结果)：
姓名 语文 数学 物理
---- ---- ---- ----
李四 74 84 94
张三 74 83 93
-------------------
*/
create table tb(姓名 varchar(10) , 课程 varchar(10) , 分数 int)
insert into tb values('张三' , '语文' , 74)
insert into tb values('张三' , '数学' , 83)
insert into tb values('张三' , '物理' , 93)
insert into tb values('李四' , '语文' , 74)
insert into tb values('李四' , '数学' , 84)
insert into tb values('李四' , '物理' , 94)
go
--SQL SERVER 2000 静态SQL,指课程只有语文、数学、物理这三门课程。(以下同)
select 姓名 as 姓名 ,
max(case 课程 when '语文' then 分数 else 0 end) 语文,
max(case 课程 when '数学' then 分数 else 0 end) 数学,
max(case 课程 when '物理' then 分数 else 0 end) 物理
from tb
group by 姓名
--SQL SERVER 2000 动态SQL,指课程不止语文、数学、物理这三门课程。(以下同)
declare @sql varchar(8000)
set @sql = 'select 姓名 '
select @sql = @sql + ' , max(case 课程 when ''' + 课程 + ''' then 分数 else 0 end) [' + 课程 + ']'
from (select distinct 课程 from tb) as a
set @sql = @sql + ' from tb group by 姓名'
exec(@sql)
--SQL SERVER 2005 静态SQL。
select * from (select * from tb) a pivot (max(分数) for 课程 in (语文,数学,物理)) b
--SQL SERVER 2005 动态SQL。
declare @sql varchar(8000)
select @sql = isnull(@sql + ',' , '') + 课程 from tb group by 课程
exec ('select * from (select * from tb) a pivot (max(分数) for 课程 in (' + @sql + ')) b')
---------------------------------
/*
问题：在上述结果的基础上加平均分，总分，得到如下结果：
姓名 语文 数学 物理 平均分 总分
---- ---- ---- ---- ------ ----
李四 74 84 94 84.00 252
张三 74 83 93 83.33 250
*/
--SQL SERVER 2000 静态SQL。
select 姓名 姓名,
max(case 课程 when '语文' then 分数 else 0 end) 语文,
max(case 课程 when '数学' then 分数 else 0 end) 数学,
max(case 课程 when '物理' then 分数 else 0 end) 物理,
cast(avg(分数*1.0) as decimal(18,2)) 平均分,
sum(分数) 总分
from tb
group by 姓名
--SQL SERVER 2000 动态SQL。
declare @sql varchar(8000)
set @sql = 'select 姓名 '
select @sql = @sql + ' , max(case 课程 when ''' + 课程 + ''' then 分数 else 0 end) [' + 课程 + ']'
from (select distinct 课程 from tb) as a
set @sql = @sql + ' , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名'
exec(@sql)
--SQL SERVER 2005 静态SQL。
select m.* , n.平均分 , n.总分 from
(select * from (select * from tb) a pivot (max(分数) for 课程 in (语文,数学,物理)) b) m,
(select 姓名 , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名) n
where m.姓名 = n.姓名
--SQL SERVER 2005 动态SQL。
declare @sql varchar(8000)
select @sql = isnull(@sql + ',' , '') + 课程 from tb group by 课程
exec ('select m.* , n.平均分 , n.总分 from
(select * from (select * from tb) a pivot (max(分数) for 课程 in (' + @sql + ')) b) m ,
(select 姓名 , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名) n
where m.姓名 = n.姓名')
drop table tb
------------------
------------------
/*
问题：如果上述两表互相换一下：即表结构和数据为：
姓名 语文 数学 物理
张三 74 83 93
李四 74 84 94
想变成(得到如下结果)：
姓名 课程 分数
---- ---- ----
李四 语文 74
李四 数学 84
李四 物理 94
张三 语文 74
张三 数学 83
张三 物理 93
--------------
*/
create table tb(姓名 varchar(10) , 语文 int , 数学 int , 物理 int)
insert into tb values('张三',74,83,93)
insert into tb values('李四',74,84,94)
go
--SQL SERVER 2000 静态SQL。
select * from
(
select 姓名 , 课程 = '语文' , 分数 = 语文 from tb
union all
select 姓名 , 课程 = '数学' , 分数 = 数学 from tb
union all
select 姓名 , 课程 = '物理' , 分数 = 物理 from tb
) t
order by 姓名 , case 课程 when '语文' then 1 when '数学' then 2 when '物理' then 3 end
--SQL SERVER 2000 动态SQL。
--调用系统表动态生态。
declare @sql varchar(8000)
select @sql = isnull(@sql + ' union all ' , '' ) + ' select 姓名 , [课程] = ' + quotename(Name , '''') + ' , [分数] = ' + quotename(Name) + ' from tb'
from syscolumns
where name! = N'姓名' and ID = object_id('tb') --表名tb，不包含列名为姓名的其它列
order by colid asc
exec(@sql + ' order by 姓名 ')
--SQL SERVER 2005 动态SQL。
select 姓名 , 课程 , 分数 from tb unpivot (分数 for 课程 in([语文] , [数学] , [物理])) t
--SQL SERVER 2005 动态SQL，同SQL SERVER 2000 动态SQL。
--------------------
/*
问题：在上述的结果上加个平均分，总分，得到如下结果：
姓名 课程 分数
---- ------ ------
李四 语文 74.00
李四 数学 84.00
李四 物理 94.00
李四 平均分 84.00
李四 总分 252.00
张三 语文 74.00
张三 数学 83.00
张三 物理 93.00
张三 平均分 83.33
张三 总分 250.00
------------------
*/
select * from
(
select 姓名 as 姓名 , 课程 = '语文' , 分数 = 语文 from tb
union all
select 姓名 as 姓名 , 课程 = '数学' , 分数 = 数学 from tb
union all
select 姓名 as 姓名 , 课程 = '物理' , 分数 = 物理 from tb
union all
select 姓名 as 姓名 , 课程 = '平均分' , 分数 = cast((语文 + 数学 + 物理)*1.0/3 as decimal(18,2)) from tb
union all
select 姓名 as 姓名 , 课程 = '总分' , 分数 = 语文 + 数学 + 物理 from tb
) t
order by 姓名 , case 课程 when '语文' then 1 when '数学' then 2 when '物理' then 3 when '平均分' then 4 when '总分' then 5 end
drop table tb
