高手求救一个sql的问题（关于编号，如1.1，1.11，1.12，1.2）

[yifeng2006]

我想在程序中实现编号自动生成，在数据中间插入的时候，后面的数据编号自动改变
例如1.1，后面是1.11，1.12，我在中间插入1.11，后面的1.11，1.12自动变成1.12，1.13。
如果1.1后面是1.2，1.3，那就自动变成1.3，1.4。
谁有办法？

[XLYT]

有点象word文档里的编号规则。但是你只有一个分隔符，如果有“1.7,1.8,1.9”,那么再插入1.7，后面的怎么办？变成“1.7，1.8，1.9，1.10”？？？

这个问题想想是比较复杂，中间要考虑的情况比较多。

[cson_cson]

create function dbo.addid(@addid varchar(30),@id varchar(30))
returns varchar(30)
as
begin
declare @newid varchar(30),@mid int
--@addid = 1.2.1 @id = 1.2.2.1
 if @addid >= @id return @id
-- [1.2.1 => 1.2.] @addid去尾 
 if charindex('.',@addid)>0 set @addid = left(@addid,len(@addid)+1-charindex('.',reverse(@addid)))
 --[1.2.2.1 =>2.1 @newid = 1.2.]@id去头，并将头存入@newid  
 select @newid = @addid+'.',@id = stuff(@id,1,len(@addid)+1,'')
 --@id去中间部分,并存入@mid [2.1=>.1 @mid = 2]
 if charindex('.',@id)> 1
 begin
  set @mid = left(@id,charindex('.',@id)-1)
  set @id = stuff(@id,1,charindex('.',@id)-1)
 end
 else
 begin
  set @mid = @id
  set @id = ''
 end
 --[@newid = 1.2. + 3 + .1 中间部门加1合并 
 set @newid = @newid+rtrim(@mid+1)+@id
 return @newid
end
go
--例子，可以将UPDATE 语句放入表的INSERT 触发器。
declare @id varchar(30)
insert tb(id) select  @id
update tb set id = dbo.addid(@id,id) where id > @id

[cson_cson]

create table tb(id varchar(30))
insert tb select '1'
union all select '1.1'
union all select '2'
union all select '2.1'
union all select '2.1.2'
union all select '2.2'
union all select '3'
union all select '3.1'
go
create function dbo.addid(@addid varchar(30),@id varchar(30))
returns varchar(30)
as
begin
declare @newid varchar(30),@mid int
--@addid = 1.2.1 @id = 1.2.2.1
 if @addid > @id return @id
-- [1.2.1 => 1.2.] @addid去尾 
 if charindex('.',@addid)>0 set @addid = left(@addid,len(@addid)+1-charindex('.',reverse(@addid)))
 --[1.2.2.1 =>2.1 @newid = 1.2.]@id去头，并将头存入@newid  
 --前缀不同的直接返回 
 if @addid <> left(@id,len(@addid)) return @id
 select @newid = @addid,@id = stuff(@id,1,len(@addid),'')
 --@id去中间部分,并存入@mid [2.1=>.1 @mid = 2]
 if charindex('.',@id)> 1
 begin
  set @mid = left(@id,charindex('.',@id)-1)
  set @id = stuff(@id,1,charindex('.',@id)-1,'')
 end
 else
 begin
  set @mid = @id
  set @id = ''
 end
 --[@newid = 1.2. + 3 + .1 中间部门加1合并 
 set @newid = @newid+rtrim(@mid+1)+@id
 return @newid
end
go
create trigger t_tb on tb  instead of insert
as
begin
 --只支持单行插入，如果多行对inserted表使用游标
 update a set id = dbo.addid(b.id,a.id) from tb a,inserted b where a.id >= b.id
 insert tb select * from inserted
end
go
select * from tb order by id
/*
id                             
------------------------------ 
1
1.1
2
2.1
2.1.2
2.2
3
3.1
*/
insert tb(id) select  '2.1'
select * from tb order by id
/*
id                             
------------------------------ 
1
1.1
2
2.1
2.2
2.2.2
2.3
3
3.1
*/
go
drop table tb
drop function dbo.addid

[cson_cson]

create table tb(id varchar(30))
insert tb select '1'
union all select '1.1'
union all select '2'
union all select '2.1'
union all select '2.1.2'
union all select '2.2'
union all select '3'
union all select '3.1'
go
create function dbo.addid(@addid varchar(30),@id varchar(30))
returns varchar(30)
as
begin
declare @newid varchar(30),@mid int
--@addid = 1.2.1 @id = 1.2.2.1
 if @addid > @id return @id
-- [1.2.1 => 1.2.] @addid去尾 
 if charindex('.',@addid)>0 
      set @addid = left(@addid,len(@addid)+1-charindex('.',reverse(@addid))) 
 else set @addid = ''
 --[1.2.2.1 =>2.1 @newid = 1.2.]@id去头，并将头存入@newid  
 --前缀不同的直接返回 
 if @addid <> left(@id,len(@addid)) return @id
 select @newid = @addid,@id = stuff(@id,1,len(@addid),'')
 --@id去中间部分,并存入@mid [2.1=>.1 @mid = 2]
 if charindex('.',@id)> 1
 begin
  set @mid = left(@id,charindex('.',@id)-1)
  set @id = stuff(@id,1,charindex('.',@id)-1,'')
 end
 else
 begin
  set @mid = @id
  set @id = ''
 end
 --[@newid = 1.2. + 3 + .1 中间部门加1合并 
 set @newid = @newid+rtrim(@mid+1)+@id
 return @newid
end
go
create trigger t_tb on tb  instead of insert
as
begin
 --只支持单行插入，如果多行对inserted表使用游标
 update a set id = dbo.addid(b.id,a.id) from tb a,inserted b where a.id >= b.id
 insert tb select * from inserted
end
go
select * from tb order by id
/*
id                             
------------------------------ 
1
1.1
2
2.1
2.1.2
2.2
3
3.1
*/
insert tb(id) select  '2.1'
select * from tb order by id
/*
id                             
------------------------------ 
1
1.1
2
2.1
2.2
2.2.2
2.3
3
3.1
*/
insert tb(id) select '2'
select * from tb order by id
/*
id                             
------------------------------ 
1
1.1
2
3
3.1
3.2
3.2.2
3.3
4
4.1
*/
go
drop table tb
drop function dbo.addid

[liangCK]

使用触发器。

[dawugui]

楼主想法很好.

----------

如果1.1后面是1.2，1.3，那就自动变成1.3，1.4。

如果有1.21,1.31,是不是更新成1.31,1.41?

[liangCK]

--自已做标识列的例子:

--创建得到最大id的函数
create function f_getid()
returns int
as
begin
	return(select isnull(max(id),0)+1 from tb)
end
go

--创建表
create table tb(id int default dbo.f_getid() primary key,name varchar(10))
go

--创建触发器,在删除表中的记录时,自动更新记录的id(**如果不要此功能,则删除此触发器)
create trigger t_delete on tb
AFTER delete
as
declare @id int,@mid int
select @mid=min(id),@id=@mid-1 from deleted
update tb set id=@id,@id=@id+1 where id>@mid
go

--插入记录测试
insert into tb(name) values('张三')
insert into tb(name) values('张四')
insert into tb(name) values('张五')
insert into tb(name) values('张六')
insert into tb(name) values('张七')
insert into tb(name) values('张八')
insert into tb(name) values('张九')
insert into tb(name) values('张十')

--显示插入的结果
select * from tb

--删除部分记录
delete from tb where name in('张五','张七','张八','张十')

--显示删除后的结果
select * from tb

--删除环境
drop table tb
drop function f_getid

/*--测试结果
id          name       
----------- ---------- 
1           张三
2           张四
3           张五
4           张六
5           张七
6           张八
7           张九
8           张十

（所影响的行数为 8 行）

id          name       
----------- ---------- 
1           张三
2           张四
3           张六
4           张九

（所影响的行数为 4 行）
--*/

[-狙击手-]

想想

[yifeng2006]

2楼，不是那样。如果1.21，1.31，那只要1.21变成1.22，1.31不变

[yifeng2006]

触发器好象很难实现吧

[yifeng2006]

有没有好的方法，程序里实现也可以。

[cson_cson]

原数据：
1
2
2.1
2.1.1
2.2
3
3.1
插入 2
变成
原 现
1 1
插入 2
2 3
2.1 3.1
2.1.1 3.1.1
2.2 3.2
3 4
3.1 4.1
对否？

[yifeng2006]

对

[zccmy22]

要拼接自符串了，自己写一个函数好了。

给出父节点。
反回给子节点。

和树遍历应有点像吧。

[tim_spac]

既然是“插入”，那么就存在记录的秩序问题。你如何标识记录的顺序及层次就成为解决问题的关键。