来论坛半年了，第一次发帖，当生猩猩散分了，呵呵！

也不能白散，前天闲得无聊，写了个简单的批处理玩玩，用来结束伪装正常进程名的进程。（注:在家庭版下无效）

散分规则：

1、提出修改建议的50分。（跑题的不算，呵呵）
2、纯JF的5分。（不能重复发帖）
3、分算满了结贴，后面的跟贴作废。^_^

[code=BatchFile]
@echo off
title 清理伪装系统进程名的进程...
cls
rem 在下面输入需要防止伪装的进程名和正确路径
rem
rem 格式：:::进程名=正常的进程路径

:::EXPLORER.EXE=%SYSTEMROOT%\EXPLORER.EXE
:::SVCHOST.EXE=%SYSTEMROOT%\SYSTEM32\SVCHOST.EXE
:::CTFMON.EXE=%SYSTEMROOT%\SYSTEM32\CTFMON.EXE
:::LSASS.EXE=%SYSTEMROOT%\SYSTEM32\LSASS.EXE
:::WINLOGON.EXE=%SYSTEMROOT%\SYSTEM32\WINLOGON.EXE
:::SMSS.EXE=%SYSTEMROOT%\SYSTEM32\SMSS.EXE
:::CSRSS.EXE=%SYSTEMROOT%\SYSTEM32\CSRSS.EXE
:::SERVICES.EXE=%SYSTEMROOT%\SYSTEM32\SERVICES.EXE
:::CMD.EXE=%SYSTEMROOT%\SYSTEM32\CMD.EXE
:::CONIME.EXE=%SYSTEMROOT%\SYSTEM32\CONIME.EXE
:::ALG.EXE=%SYSTEMROOT%\SYSTEM32\ALG.EXE
:::IEXPLORE.EXE=%PROGRAMFILES%\Internet Explorer\IEXPLORE.EXE
:::REGEDIT.EXE=%SYSTEMROOT%\REGEDIT.EXE
:::MMC.EXE=%SYSTEMROOT%\SYSTEM32\MMC.EXE

color 0A
for /f "tokens=1* delims==" %%a in ('findstr /b ":::" "%~nx0"') do (
call :DoIt "%%a" "%%b"
)
goto end

:end
echo.&echo.&echo 检查完毕，按任意键退出...
pause>nul
exit

:DoIt
set pname=%1
set pname=%pname::::=%
set pname=%pname:"='%
set ppath=%2
set ppath=%ppath:"='%
echo 正在检查进程名: %pname:'=%
wmic process where "name=%pname% and executablepath<>%ppath:\=\\%" call terminate>nul
[/code]