赋予一个数据库用户权限

[Laughing]

赋予一个数据库用户这样的权限：
可查询某一数据库中所有表、视图，执行所有的存储过程

T-SQL语句该怎么写？

[wzy_love_sly]

/*--示例说明
		示例在数据库pubs中创建一个拥有表jobs的所有权限、拥有表titles的SELECT权限的角色r_test
	随后创建了一个登录l_test，然后在数据库pubs中为登录l_test创建了用户账户u_test
	同时将用户账户u_test添加到角色r_test中，使其通过权限继承获取了与角色r_test一样的权限
	最后使用DENY语句拒绝了用户账户u_test对表titles的SELECT权限。
	经过这样的处理，使用l_test登录SQL Server实例后，它只具有表jobs的所有权限。
--*/

USE pubs

--创建角色 r_test
EXEC sp_addrole 'r_test'

--授予 r_test 对 jobs 表的所有权限
GRANT ALL ON jobs TO r_test
--授予角色 r_test 对 titles 表的 SELECT 权限
GRANT SELECT ON titles TO r_test

--添加登录 l_test,设置密码为pwd,默认数据库为pubs
EXEC sp_addlogin 'l_test','pwd','pubs'

--为登录 l_test 在数据库 pubs 中添加安全账户 u_test
EXEC sp_grantdbaccess 'l_test','u_test'

--添加 u_test 为角色 r_test 的成员
EXEC sp_addrolemember 'r_test','u_test'

--拒绝安全账户 u_test 对 titles 表的 SELECT 权限
DENY SELECT ON titles TO u_test

/*--完成上述步骤后,用 l_test 登录,可以对jobs表进行所有操作,但无法对titles表查询,虽然角色 r_test 有titles表的select权限,但已经在安全账户中明确拒绝了对titles的select权限,所以l_test无titles表的select权限--*/

--从数据库 pubs 中删除安全账户
EXEC sp_revokedbaccess 'u_test'

--删除登录 l_test
EXEC sp_droplogin 'l_test'

--删除角色 r_test
EXEC sp_droprole 'r_test'

[中国风]

要控制对数据库的权限,   可以参考下面的:   
    
  --   防止访问他不该访问的数据库(总控制,明细还可以控制他对于某个数据库的具体对象具有的权限)       
      
  --切换到你新增的用户要控制的数据库       
  use     你的库名       
  go       
      
  --新增用户       
  exec     sp_addlogin     'test'                         --添加登录       
  exec     sp_grantdbaccess     N'test'                         --使其成为当前数据库的合法用户       
  exec     sp_addrolemember     N'db_owner',     N'test'                         --授予对自己数据库的所有权限       
      
  --这样创建的用户就只能访问自己的数据库,及数据库中包含了guest用户的公共表       
  go       
      
  --删除测试用户       
  exec     sp_revokedbaccess     N'test'                         --移除对数据库的访问权限       
  exec     sp_droplogin     N'test'                         --删除登录       
    
    
  如果在企业管理器中创建的话,就用:   
    
  企业管理器--安全性--右键登录--新建登录   
    
  常规项   
  --名称中输入用户名   
  --身份验证方式根据你的需要选择(如果是使用windows身份验证,则要先在操作系统的用户中新建用户)   
  --默认设置中,选择你新建的用户要访问的数据库名   
    
  服务器角色项   
  这个里面不要选择任何东西   
    
  数据库访问项   
  勾选你创建的用户需要访问的数据库名   
  数据库角色中允许,勾选"public","db_ownew"   
    
  确定,这样建好的用户与上面语句建立的用户一样     
  ---------------------------------------------------------------------------       
    
  最后一步,为具体的用户设置具体的访问权限,这个可以参考下面的最简示例:     
      
  --添加只允许访问指定表的用户:       
  exec     sp_addlogin     '用户名','密码','默认数据库名'       
      
  --添加到数据库       
  exec     sp_grantdbaccess     '用户名'   
      
  --分配整表权限       
  GRANT     SELECT   ,     INSERT   ,     UPDATE   ,     DELETE     ON   table1   TO   [用户名]   
    
  --分配权限到具体的列   
  GRANT     SELECT   ,     UPDATE     ON   table1(id,AA)   TO   [用户名]   
      
      
  -------------------------------------------------------------------       
  至于具体的安全设置和理论知道,参考SQL联机帮助

[wzy_love_sly]

直接在库名-安全性-用户里添加也可以，加用户时设置要加的角色和对象，
然后勾选select ,update等权限

[rainlovesea]

收藏

[bwu851]

[Quote=引用 4 楼 rainlovesea 的回复:]
收藏
[/Quote]

这个.....

[bwu851]

偶给个所有的存储过程的例子吧: (其他的自己推导吧)

/* Procedure Name:	sp_GrantSProcExec
Description: 这个存储过程是赋于某用户对本库中所有存储过程的EXEC权力 
Input: @UserName
Output:	(print out)
Return: 
Dependencies:	  
Comments:	

MODIFICATIONS:
20060925	xxxxxxx		
New
20080104	bwu851
1.Added User existence checking
2.Added [dbo].[   ]
3.Excludes some spp_admin_* sprocs	  		
*/ 
CREATE  PROCEDURE spp_Admin_GrantSprocExec 
	 @UserName varchar(50)
AS

Set NOCOUNT On
BEGIN

	Declare @ProcName varchar(100)
	Declare @SQL varchar(5000)
	
	If EXISTS(SELECT 1 FROM sysusers WHERE name = @UserName)
	BEGIN
		Declare GetProc cursor for
		Select Name 
		From SysObjects
		Where xtype = 'P'
			and name not like 'dt_%' 
			and name not in ('sp_Admin_GrantSprocExec',
					 'sp_Admin_FindDBObject',
					 'sp_Admin_FixOrphanedUsers',
					 'sp_Admin_GetTableInfo',
					 'sp_Admin_GrantFuncExec') --01/04/2008 bwu851
		Order by Name
		
		Open GetProc	
		Fetch next from GetProc into @ProcName
		
		While (@@fetch_status = 0)
			Begin
				Set @SQL = ''
				-- 01/04/2008 BWU851 added [dbo].[   ]
				Set @SQL = 'Grant Exec on [dbo].[' + @ProcName + '] to [' + @UserName +']'
		
				Exec (@SQL)
		
				If @@Error <> 0 
					Begin
						Print 'Error when granting rights on ' + @ProcName + ' to ' + @UserName
					End
				Else
					Begin
						Print 'Granted exec on [dbo].[' + @ProcName + '] to [' + @UserName + ']'
					End
		
				Fetch next from GetProc into @ProcName
			End
		
		Close GetProc
		Deallocate GetProc
	END
	ELSE
		PRINT 'NO such user: ['+@username+'] in database: '+db_name()
END

Set NOCOUNT Off
GO

[-狙击手-]

和尚会降龙十八掌吗？