Imports System.Xml

Imports System.Text



Public Class ExcelXmlWriter



    Dim ssns As String = "urn:schemas-microsoft-com:office:spreadsheet"

    Dim xmlns As String = "urn:schemas-microsoft-com:office:spreadsheet"



    Dim _doc As New XmlDocument



    Dim _currentSheet As XmlNode = Nothing

    Dim _currentRow As XmlNode = Nothing



    Public Sub New()



        'excel的xml模版，你需要了解xml的Attributes怎么用 

        Dim sbody As New StringBuilder

        sbody.Append("<?xml version=""1.0""?>" & vbCrLf)

        sbody.Append("<?mso-application progid=""Excel.Sheet""?>" & vbCrLf)

        sbody.Append("<Workbook xmlns=""urn:schemas-microsoft-com:office:spreadsheet""" & vbCrLf)

        sbody.Append("xmlns:o=""urn:schemas-microsoft-com:office:office""" & vbCrLf)

        sbody.Append("xmlns:x=""urn:schemas-microsoft-com:office:excel""" & vbCrLf)

        sbody.Append("xmlns:ss=""urn:schemas-microsoft-com:office:spreadsheet""" & vbCrLf)

        sbody.Append("xmlns:html=""http://www.w3.org/TR/REC-html40"">" & vbCrLf)

        sbody.Append("<Styles>" & vbCrLf)

        sbody.Append("<Style ss:ID=""Default"" ss:Name=""Normal"">" & vbCrLf)

        sbody.Append("<Alignment ss:Vertical=""Center""/>" & vbCrLf)

        sbody.Append("<Borders/>" & vbCrLf)

        sbody.Append("<Font ss:FontName=""宋体"" x:CharSet=""134"" ss:Size=""10""/>" & vbCrLf)

        sbody.Append("<Interior/>" & vbCrLf)

        sbody.Append("<NumberFormat/>" & vbCrLf)

        sbody.Append("<Protection/>" & vbCrLf)

        sbody.Append("</Style>" & vbCrLf)

        sbody.Append("</Styles>" & vbCrLf)

        sbody.Append("</Workbook>" & vbCrLf)

        _doc.LoadXml(sbody.ToString())



    End Sub



    '''<summary> 

    ''' 增加一个工作表 

    '''</summary> 

    ''' <param name="sheetName">工作表名称</param> 

    Public Sub CreateSheet(ByVal sheetName As String)

        Dim node As System.Xml.XmlNode = _doc.CreateNode(XmlNodeType.Element, "Worksheet", ssns)

        Dim xa As System.Xml.XmlAttribute = _doc.CreateAttribute("ss", "Name", xmlns)

        xa.Value = sheetName

        node.Attributes.Append(xa)

        _doc.ChildNodes(2).AppendChild(node)

        node.AppendChild(_doc.CreateNode(XmlNodeType.Element, "Table", xmlns))

        _currentSheet = node

    End Sub





    '''<summary> 

    '''增加一行 

    '''</summary> 

    Public Sub CreateRow()

        Dim node As System.Xml.XmlNode = _doc.CreateNode(XmlNodeType.Element, "Row", xmlns)

        _currentSheet.ChildNodes(0).AppendChild(node)

        _currentRow = node

    End Sub





    '''<summary> 

    '''增加一列 

    '''</summary> 

    '''<param name="index">索引</param> 

    '''<param name="width">宽度</param> 

    Public Sub CreateColumn(ByVal index As Integer, ByVal width As Single)

        Dim node As System.Xml.XmlNode = _doc.CreateNode(XmlNodeType.Element, "Column", xmlns)

        Dim xa As System.Xml.XmlAttribute = _doc.CreateAttribute("ss", "Index", xmlns)

        xa.Value = index.ToString()

        node.Attributes.Append(xa)

        xa = _doc.CreateAttribute("ss", "Width", xmlns)

        xa.Value = width.ToString()

        node.Attributes.Append(xa)

        _currentSheet.ChildNodes(0).AppendChild(node)

    End Sub





    '''<summary> 

    '''增加一个单元格 

    '''</summary> 

    '''<param name="value">值</param> 

    '''<param name="Type">类型</param> 

    '''<param name="Expression">公式</param> 

    '''<param name="rowSpan">跨行</param> 

    '''<param name="colSpan">跨列</param> 

    Public Sub CreateCell(ByVal value As Object, ByVal type As String, ByVal expression As String, ByVal rowSpan As Integer, ByVal colSpan As Integer)



        Dim xa As System.Xml.XmlAttribute = Nothing

        Dim nodeCell As System.Xml.XmlNode = _doc.CreateNode(XmlNodeType.Element, "Cell", xmlns)

        _currentRow.AppendChild(nodeCell)



        If (Not String.IsNullOrEmpty(Expression)) Then

            xa = _doc.CreateAttribute("ss", "Formula", xmlns)

            xa.Value = "=" + expression

            nodeCell.Attributes.Append(xa)

        End If



        colSpan -= 1

        If (colSpan > 0) Then

            xa = _doc.CreateAttribute("ss", "MergeAcross", xmlns)

            xa.Value = colSpan.ToString()

            nodeCell.Attributes.Append(xa)

        End If



        rowSpan -= 1

        If (--rowSpan > 0) Then

            xa = _doc.CreateAttribute("ss", "MergeDown", xmlns)

            xa.Value = rowSpan.ToString()

            nodeCell.Attributes.Append(xa)

        End If



        Dim nodeData As System.Xml.XmlNode = _doc.CreateNode(XmlNodeType.Element, "Data", xmlns)

        xa = _doc.CreateAttribute("ss", "Type", xmlns)

        xa.Value = type

        nodeData.Attributes.Append(xa)

        nodeData.InnerText = value.ToString()

        nodeCell.AppendChild(nodeData)

    End Sub





    '''<summary> 

    '''增加一个数字单元格 

    ''' </summary> 

    ''' <param name="value"></param> 

    Public Sub CreateCellNumber(ByVal value As Double)

        CreateCell(value, "Number", Nothing, 1, 1)

    End Sub



    ''' <summary> 

    ''' 增加一个字符串单元格 

    ''' </summary> 

    ''' <param name="value"></param> 

    Public Sub CreateCellString(ByVal value As String)

        CreateCell(value, "String", Nothing, 1, 1)

    End Sub





    ''' <summary> 

    ''' 保存 

    ''' </summary> 

    ''' <param name="strFile"></param> 

    Public Sub Save(ByVal strFile As String)

        _doc.Save(strFile)

    End Sub



End Class