在线求一个建立作业的代码，在线等，解决马上给分

dcren118 2008-08-08 10:02:34
求一段代码 利用 T-SQL 语句建立一个 在每天的 00.01.00 执行 一个存储过程， 因为是租用的新网的服务器所以不能直接操作服务器 只能通过程序来实现 请高手指点 ！

最好是SQL2000 和 SQL2005 两个版本的 谢谢 ！
...全文
101 5 打赏 收藏 转发到动态 举报
写回复
用AI写文章
5 条回复
切换为时间正序
请发表友善的回复…
发表回复
Novelty 2008-08-08
  • 打赏
  • 举报
 回复
在本地手工建一个调度，然后用这个调度生成脚本。

注意修改脚本中几个地方的值为远程服务器的相应值:

@category_name
@owner_login_name
@server_name
bwu851 2008-08-08
  • 打赏
  • 举报
 回复
这是SQL2005里的:


USE [msdb]

GO

/****** Object:  Job [test]    Script Date: 08/07/2008 10:49:43 ******/

BEGIN TRANSACTION

DECLARE @ReturnCode INT

SELECT @ReturnCode = 0

/****** Object:  JobCategory [[Uncategorized (Local)]]]    Script Date: 08/07/2008 10:49:43 ******/

IF NOT EXISTS (SELECT name FROM msdb.dbo.syscategories WHERE name=N'[Uncategorized (Local)]' AND category_class=1)

BEGIN

EXEC @ReturnCode = msdb.dbo.sp_add_category @class=N'JOB', @type=N'LOCAL', @name=N'[Uncategorized (Local)]'

IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback



END



DECLARE @jobId BINARY(16)

EXEC @ReturnCode =  msdb.dbo.sp_add_job @job_name=N'test', 

		@enabled=1, 

		@notify_level_eventlog=0, 

		@notify_level_email=0, 

		@notify_level_netsend=0, 

		@notify_level_page=0, 

		@delete_level=0, 

		@description=N'No description available.', 

		@category_name=N'[Uncategorized (Local)]', 

		@owner_login_name=N'sa', @job_id = @jobId OUTPUT

IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback

/****** Object:  Step [step1]    Script Date: 08/07/2008 22:49:44 ******/

EXEC @ReturnCode = msdb.dbo.sp_add_jobstep @job_id=@jobId, @step_name=N'step1', 

		@step_id=1, 

		@cmdexec_success_code=0, 

		@on_success_action=1, 

		@on_success_step_id=0, 

		@on_fail_action=2, 

		@on_fail_step_id=0, 

		@retry_attempts=0, 

		@retry_interval=0, 

		@os_run_priority=0, @subsystem=N'TSQL', 

		@command=N'exec sp_test', 

		@database_name=N'AdventureWorks', 

		@flags=0

IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback

EXEC @ReturnCode = msdb.dbo.sp_update_job @job_id = @jobId, @start_step_id = 1

IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback

EXEC @ReturnCode = msdb.dbo.sp_add_jobschedule @job_id=@jobId, @name=N'schedule1', 

		@enabled=1, 

		@freq_type=4, 

		@freq_interval=1, 

		@freq_subday_type=1, 

		@freq_subday_interval=0, 

		@freq_relative_interval=0, 

		@freq_recurrence_factor=0, 

		@active_start_date=20080807, 

		@active_end_date=99991231, 

		@active_start_time=100, 

		@active_end_time=235959

IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback

EXEC @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @jobId, @server_name = N'(local)'

IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback

COMMIT TRANSACTION

GOTO EndSave

QuitWithRollback:

    IF (@@TRANCOUNT > 0) ROLLBACK TRANSACTION

EndSave:



go
bwu851 2008-08-08
  • 打赏
  • 举报
 回复
这是SQL2000的:


-- Script generated on 2008-8-7 22:40

-- By: CSDN\bwu851

-- Server: CSDNSQL01\TEST



BEGIN TRANSACTION            

  DECLARE @JobID BINARY(16)  

  DECLARE @ReturnCode INT    

  SELECT @ReturnCode = 0     

IF (SELECT COUNT(*) FROM msdb.dbo.syscategories WHERE name = N'[Uncategorized (Local)]') < 1 

  EXECUTE msdb.dbo.sp_add_category @name = N'[Uncategorized (Local)]'



  -- Delete the job with the same name (if it exists)

  SELECT @JobID = job_id     

  FROM   msdb.dbo.sysjobs    

  WHERE (name = N'test')       

  IF (@JobID IS NOT NULL)    

  BEGIN  

  -- Check if the job is a multi-server job  

  IF (EXISTS (SELECT  * 

              FROM    msdb.dbo.sysjobservers 

              WHERE   (job_id = @JobID) AND (server_id <> 0))) 

  BEGIN 

    -- There is, so abort the script 

    RAISERROR (N'Unable to import job ''test'' since there is already a multi-server job with this name.', 16, 1) 

    GOTO QuitWithRollback  

  END 

  ELSE 

    -- Delete the [local] job 

    EXECUTE msdb.dbo.sp_delete_job @job_name = N'test' 

    SELECT @JobID = NULL

  END 



BEGIN 



  -- Add the job

  EXECUTE @ReturnCode = msdb.dbo.sp_add_job @job_id = @JobID OUTPUT , @job_name = N'test', @owner_login_name = N'sa', @description = N'No description available.', @category_name = N'[Uncategorized (Local)]', @enabled = 1, @notify_level_email = 0, @notify_level_page = 0, @notify_level_netsend = 0, @notify_level_eventlog = 2, @delete_level= 0

  IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback 



  -- Add the job steps

  EXECUTE @ReturnCode = msdb.dbo.sp_add_jobstep @job_id = @JobID, @step_id = 1, @step_name = N'step1', @command = N'exec sp_test', @database_name = N'Northwind', @server = N'', @database_user_name = N'', @subsystem = N'TSQL', @cmdexec_success_code = 0, @flags = 0, @retry_attempts = 0, @retry_interval = 1, @output_file_name = N'', @on_success_step_id = 0, @on_success_action = 1, @on_fail_step_id = 0, @on_fail_action = 2

  IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback 

  EXECUTE @ReturnCode = msdb.dbo.sp_update_job @job_id = @JobID, @start_step_id = 1 



  IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback 



  -- Add the job schedules

  EXECUTE @ReturnCode = msdb.dbo.sp_add_jobschedule @job_id = @JobID, @name = N'schedule1', @enabled = 1, @freq_type = 4, @active_start_date = 20080807, @active_start_time = 100, @freq_interval = 1, @freq_subday_type = 1, @freq_subday_interval = 0, @freq_relative_interval = 0, @freq_recurrence_factor = 0, @active_end_date = 99991231, @active_end_time = 235959

  IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback 



  -- Add the Target Servers

  EXECUTE @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @JobID, @server_name = N'(local)' 

  IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback 



END

COMMIT TRANSACTION          

GOTO   EndSave              

QuitWithRollback:

  IF (@@TRANCOUNT > 0) ROLLBACK TRANSACTION 

EndSave: 



go
水族杰纶 2008-08-08
  • 打赏
  • 举报
 回复
普通行列转换
问题：假设有张学生成绩表(tb)如下:
姓名 课程 分数
张三 语文 74
张三 数学 83
张三 物理 93
李四 语文 74
李四 数学 84
李四 物理 94
想变成(得到如下结果)：
姓名 语文 数学 物理
---- ---- ---- ----
李四 74 84 94
张三 74 83 93
-------------------
*/

create table tb(姓名 varchar(10) , 课程 varchar(10) , 分数 int)
insert into tb values('张三' , '语文' , 74)
insert into tb values('张三' , '数学' , 83)
insert into tb values('张三' , '物理' , 93)
insert into tb values('李四' , '语文' , 74)
insert into tb values('李四' , '数学' , 84)
insert into tb values('李四' , '物理' , 94)
go

--SQL SERVER 2000 静态SQL,指课程只有语文、数学、物理这三门课程。(以下同)
select 姓名 as 姓名 ,
max(case 课程 when '语文' then 分数 else 0 end) 语文,
max(case 课程 when '数学' then 分数 else 0 end) 数学,
max(case 课程 when '物理' then 分数 else 0 end) 物理
from tb
group by 姓名

--SQL SERVER 2000 动态SQL,指课程不止语文、数学、物理这三门课程。(以下同)
declare @sql varchar(8000)
set @sql = 'select 姓名 '
select @sql = @sql + ' , max(case 课程 when ''' + 课程 + ''' then 分数 else 0 end) [' + 课程 + ']'
from (select distinct 课程 from tb) as a
set @sql = @sql + ' from tb group by 姓名'
exec(@sql)

--SQL SERVER 2005 静态SQL。
select * from (select * from tb) a pivot (max(分数) for 课程 in (语文,数学,物理)) b

--SQL SERVER 2005 动态SQL。
declare @sql varchar(8000)
select @sql = isnull(@sql + ',' , '') + 课程 from tb group by 课程
exec ('select * from (select * from tb) a pivot (max(分数) for 课程 in (' + @sql + ')) b')

---------------------------------

/*
问题：在上述结果的基础上加平均分，总分，得到如下结果：
姓名 语文 数学 物理 平均分 总分
---- ---- ---- ---- ------ ----
李四 74 84 94 84.00 252
张三 74 83 93 83.33 250
*/

--SQL SERVER 2000 静态SQL。
select 姓名 姓名,
max(case 课程 when '语文' then 分数 else 0 end) 语文,
max(case 课程 when '数学' then 分数 else 0 end) 数学,
max(case 课程 when '物理' then 分数 else 0 end) 物理,
cast(avg(分数*1.0) as decimal(18,2)) 平均分,
sum(分数) 总分
from tb
group by 姓名

--SQL SERVER 2000 动态SQL。
declare @sql varchar(8000)
set @sql = 'select 姓名 '
select @sql = @sql + ' , max(case 课程 when ''' + 课程 + ''' then 分数 else 0 end) [' + 课程 + ']'
from (select distinct 课程 from tb) as a
set @sql = @sql + ' , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名'
exec(@sql)

--SQL SERVER 2005 静态SQL。
select m.* , n.平均分 , n.总分 from
(select * from (select * from tb) a pivot (max(分数) for 课程 in (语文,数学,物理)) b) m,
(select 姓名 , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名) n
where m.姓名 = n.姓名

--SQL SERVER 2005 动态SQL。
declare @sql varchar(8000)
select @sql = isnull(@sql + ',' , '') + 课程 from tb group by 课程
exec ('select m.* , n.平均分 , n.总分 from
(select * from (select * from tb) a pivot (max(分数) for 课程 in (' + @sql + ')) b) m ,
(select 姓名 , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名) n
where m.姓名 = n.姓名')

drop table tb

------------------
------------------

/*
问题：如果上述两表互相换一下：即表结构和数据为：
姓名 语文 数学 物理
张三 74　　83　　93
李四 74　　84　　94
想变成(得到如下结果)：
姓名 课程 分数
---- ---- ----
李四 语文 74
李四 数学 84
李四 物理 94
张三 语文 74
张三 数学 83
张三 物理 93
--------------
*/

create table tb(姓名 varchar(10) , 语文 int , 数学 int , 物理 int)
insert into tb values('张三',74,83,93)
insert into tb values('李四',74,84,94)
go

--SQL SERVER 2000 静态SQL。
select * from
(
select 姓名 , 课程 = '语文' , 分数 = 语文 from tb
union all
select 姓名 , 课程 = '数学' , 分数 = 数学 from tb
union all
select 姓名 , 课程 = '物理' , 分数 = 物理 from tb
) t
order by 姓名 , case 课程 when '语文' then 1 when '数学' then 2 when '物理' then 3 end

--SQL SERVER 2000 动态SQL。
--调用系统表动态生态。
declare @sql varchar(8000)
select @sql = isnull(@sql + ' union all ' , '' ) + ' select 姓名 , [课程] = ' + quotename(Name , '''') + ' , [分数] = ' + quotename(Name) + ' from tb'
from syscolumns
where name! = N'姓名' and ID = object_id('tb') --表名tb，不包含列名为姓名的其它列
order by colid asc
exec(@sql + ' order by 姓名 ')

--SQL SERVER 2005 动态SQL。
select 姓名 , 课程 , 分数 from tb unpivot (分数 for 课程 in([语文] , [数学] , [物理])) t

--SQL SERVER 2005 动态SQL，同SQL SERVER 2000 动态SQL。

--------------------
/*
问题：在上述的结果上加个平均分，总分，得到如下结果：
姓名 课程 分数
---- ------ ------
李四 语文 74.00
李四 数学 84.00
李四 物理 94.00
李四 平均分 84.00
李四 总分 252.00
张三 语文 74.00
张三 数学 83.00
张三 物理 93.00
张三 平均分 83.33
张三 总分 250.00
------------------
*/

select * from
(
select 姓名 as 姓名 , 课程 = '语文' , 分数 = 语文 from tb
union all
select 姓名 as 姓名 , 课程 = '数学' , 分数 = 数学 from tb
union all
select 姓名 as 姓名 , 课程 = '物理' , 分数 = 物理 from tb
union all
select 姓名 as 姓名 , 课程 = '平均分' , 分数 = cast((语文 + 数学 + 物理)*1.0/3 as decimal(18,2)) from tb
union all
select 姓名 as 姓名 , 课程 = '总分' , 分数 = 语文 + 数学 + 物理 from tb
) t
order by 姓名 , case 课程 when '语文' then 1 when '数学' then 2 when '物理' then 3 when '平均分' then 4 when '总分' then 5 end

drop table tb
hyqwan11112 2008-08-08
  • 打赏
  • 举报
 回复 


--给你个模板哈！

--定义创建作业

DECLARE @jobid uniqueidentifier

EXEC msdb.dbo.sp_add_job

	@job_name = N'作业名称',

	@job_id = @jobid OUTPUT



--定义作业步骤

DECLARE @sql nvarchar(400),@dbname sysname

SELECT @dbname=DB_NAME(),  --作业步骤在当前数据库中执行

	@sql=N'--作业步骤内容'  --一般定义的是使用TSQL处理的作业,这里定义要执行的Transact-SQL语句

EXEC msdb.dbo.sp_add_jobstep

	@job_id = @jobid,

	@step_name = N'作业步骤名称',

	@subsystem = 'TSQL', --步骤的类型,一般为TSQL

	@database_name=@dbname,

	@command = @sql



--创建调度(使用后面专门定义的几种作业调度模板)

EXEC msdb..sp_add_jobschedule

	@job_id = @jobid,

	@name = N'调度名称',

	@freq_type=4,                --每天

	@freq_interval=1,            --指定每多少天发生一次,这里是1天.

	@freq_subday_type=0x8,       --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次

	@freq_subday_interval=1,     --重复周期数,这里每小时执行一次

	@active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

	@active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD

	@active_start_time = 00000,  --作业执行的开始时间,格式为HHMMSS

	@active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS



--添加目标服务器

DECLARE @servername sysname

SET @servername=CONVERT(nvarchar(128),SERVERPROPERTY(N'ServerName'))

EXEC msdb.dbo.sp_add_jobserver 

	@job_id = @jobid,

	@server_name = @servername --使用当前SQL实例





--调度模板定义

--/*--日调度

EXEC msdb..sp_add_jobschedule

	@job_id = @jobid,

	@name = N'调度名称',

	@freq_type=4,                --每天

	@freq_interval=1,            --指定每多少天发生一次,这里是1天.

	@freq_subday_type=0x8,       --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次

	@freq_subday_interval=1,     --重复周期数,这里每小时执行一次

	@active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

	@active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD

	@active_start_time = 00000,  --作业执行的开始时间,格式为HHMMSS

	@active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--*/



--/*--周调度

EXEC msdb.dbo.sp_add_jobschedule

	@job_id = @jobid,

	@name = N'调度名称', 

	@freq_type = 8,              --每周

	@freq_recurrence_factor = 1, --每多少周执行一次,这里是每周

	@freq_interval = 62,         --在星期几执行,由POWER(2,N)表示,N的值为0~6,代表星期日~星期六,如果指定两个,则将值相加,例如,值为65表示在星期天和星期日执行(POWER(2,0)+POWER(2,6))

	@freq_subday_type = 0x8,     --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次

	@freq_subday_interval = 1,   --重复周期数,这里每小时执行一次

	@active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

	@active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD

	@active_start_time = 00000,  --作业执行的开始时间,格式为HHMMSS

	@active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--*/



--/*--月调度(每X个月的每月几号)

EXEC msdb.dbo.sp_add_jobschedule

	@job_id = @jobid,

	@name = N'调度名称', 

	@freq_type = 16,             --每月

	@freq_recurrence_factor = 2, --每多少月执行一次,这里是每2个月

	@freq_interval = 2,          --在执行月的第几天执行,这里是第2天

	@freq_subday_type = 0x8,     --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次

	@freq_subday_interval = 1,   --重复周期数,这里每小时执行一次

	@active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

	@active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD

	@active_start_time = 00000,  --作业执行的开始时间,格式为HHMMSS

	@active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--*/



--/*--月调度(每X个月的相对时间)

EXEC msdb.dbo.sp_add_jobschedule

	@job_id = @jobid,

	@name = N'调度名称', 

	@freq_type = 32,             --每月

	@freq_recurrence_factor = 2, --每多少月执行一次,这里是每2个月

	@freq_interval = 9,          --在当月的那个时间执行,1~7=星期日至星期六,8=日 ,9=工作日,10=周末

	@freq_relative_interval = 1, --在第几个相对时间执行,允许的值为1,2,4,8代表第1~4个相对时间,16表示最后一个相对时间

	@freq_subday_type = 0x8,     --重复方式,0x1=在指定的时间,0x4=多少分钟,0x8=多少小时执行一次

	@freq_subday_interval = 1,   --重复周期数,这里每小时执行一次

	@active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

	@active_end_date = 99991231, --作业执行的停止日期,默认为99991231,格式为YYYYMMDD

	@active_start_time = 00000,  --作业执行的开始时间,格式为HHMMSS

	@active_end_time = 235959    --作业执行的停止时间,格式为HHMMSS

--*/



--/*--在特定时候执行的作业调度

EXEC msdb.dbo.sp_add_jobschedule

	@job_id = @jobid,

	@name = N'调度名称', 

	@freq_type = 64     --64=在SQLServerAgent 服务启动时运行,128=计算机空闲时运行

--*/



--/*--只执行一次的作业调度

EXEC msdb..sp_add_jobschedule

	@job_id = @jobid,

	@name = N'调度名称',

	@freq_type=1,                --仅执行一次

	@active_start_date = NULL,   --作业执行的开始日期,为NULL时表示当前日期,格式为YYYYMMDD

	@active_start_time = 00000   --作业执行的开始时间,格式为HHMMSS

--*/
React hook 实战【作业+传授经验】
本套课程通过实践，讲解...而经验需要通过做作业，你不只提高开发经验，而且老师会根据你的作业，因材施教，传授你真正的经验，也会通过你的代码，发现你的问题，有针对性的指出你的问题，这种提高是飞速的、根本性的！
HTML5期末大作业：旅游网页设计——西安旅游9页(代码质量好) 学生DW网页设计作业源码 web课程设计网页规划与设计
HTML5期末大作业：网站——西安旅游...原始HTML+CSS+JS页面设计, web大学生网页设计作业源码，这是一个不错的网页制作，画面精明，非常适合初学者学习使用。 作品介绍 1.网页作品简介方面 ：HTML期末大学生网页设计作业
使用回溯法解决批处理作业调度问题
要求每个作业Ji 的第一项任务在机器1上处理，第二项任务在机器2上处理，并且第一项任务在机器1上处理完后，第二项任务才能在机器2上开始处理。规定每个作业Ji用 f(1,i)记录其在机器1上的处理时...
HTML学生个人网站作业设计：HTML做一个公司官网首页页面（纯html代码）
️ 网页中包含：Div+CSS、鼠标滑过特效、Table、导航栏效果、banner、表单、二级三级页面等，视频音频元素，同时设计了logo（源文件），基本期末作业所需的知识点全覆盖。 一套优质的网页设计应该包含 (具体可根据...
机器学习之文本分类（附带训练集+数据集+所有代码）
我本次对4类文本进行分类（（所有截图代码和数据集最后附带免费下载地址）） 主要步骤： 1.各种读文件，写文件 2.使用jieba分词将中文文本切割 ...遍历的读取一个文件下的每个文本 中文分词 ...
MS-SQL Server

34,576

社区成员

254,587

社区内容

发帖
与我相关
我的任务
社区描述
MS-SQL Server相关内容讨论专区
社区管理员
  • 基础类社区
  • 二月十六
  • 卖水果的net
加入社区
  • 近7日
  • 近30日
  • 至今

加载中

查看更多榜单
社区公告
暂无公告

试试用AI创作助手写篇文章吧

+ 用AI写文章