SQL 查询结果横向显示？？？

[我的小黑]

假设一张表
A
id name count
1 衣服 100
2 裤子 300
3 鞋子 200
4 帽子 120
5 链子 110
... ... ...

查询出来的结果应该就像上面一样，我想横向显示，而且最后还要显示一条count的汇总，SQL语句怎么写，要最简洁的办法？

[qinhl99]

case when 行列转置

[richnaly]

楼上回答的好啊

[wer123q]

declare 
	@str varchar(1000),
	@str2 varchar(1000)
	set @str = 'select '
	set @str2 = ''
	select @str2 = @str2+','+'max(case name when '''+name+''' then count else 0 end)as'''+name+''''
	from(select distinct name from tb)a
exec(@str + @str2 + 'sum(count)as''zs'' from tb')

[-狙击手-]

------------------------------------
-- Author:  happyflsytone  
-- Date:2008-09-28 00:00:27
------------------------------------

-- Test Data: ta
IF OBJECT_ID('ta') IS NOT NULL 
    DROP TABLE ta
Go
CREATE TABLE ta(id INT,name NVARCHAR(2),count INT)
Go
INSERT INTO ta
SELECT 1,'衣服',100 UNION ALL
SELECT 2,'裤子',300 UNION ALL
SELECT 3,'鞋子',200 UNION ALL
SELECT 4,'帽子',120 UNION ALL
SELECT 5,'链子',110 
GO
--Start
declare @s varchar(8000)
select @s = isnull(@s+',','') + '['+name+']= max(case when name = '''+name+''' then count else 0 end)'
from ta
exec('select '+@s + ',sum(count) as s_count from ta')


--Result:
/*

衣服          裤子          鞋子          帽子          链子          s_count
----------- ----------- ----------- ----------- ----------- -----------
100         300         200         120         110         830

(1 行受影响)
*/
--End 

[-狙击手-]

select [衣服],[裤子],[鞋子],[帽子],[链子]
from ( select name,count from ta ) p
pivot ( max(count) for name in([衣服],[裤子],[鞋子],[帽子],[链子])) as pvt

[-狙击手-]

衣服          裤子          鞋子          帽子          链子
----------- ----------- ----------- ----------- -----------
100         300         200         120         110

(1 行受影响)

[hyqwan11112]

select [衣服],[裤子],[鞋子],[帽子],[链子]
from ( select name,count from ta ) p
pivot ( max(count) for name in([衣服],[裤子],[鞋子],[帽子],[链子])) as pvt

[我的小黑]

都不对呀~~~
我要ID也横向显示呀？

[我的小黑]

高人出来指点下呀~

[wxg22526451]

这样?

declare @s varchar(8000),@s2 varchar(8000)
select @s = isnull(@s+',','') + '['+ltrim(id)+']= max('''+[name]+''')'
,@s2=isnull(@s2+',','') + 'max('''+ltrim([count])+''') '
from ta 

exec('select '+@s + ',sum(count) as s_count from ta union all select '+@s2+',null')

/*
1    2    3    4    5    s_count
---- ---- ---- ---- ---- -----------
衣服   裤子   鞋子   帽子   链子   830
100  300  200  120  110  NULL
*/

[我的小黑]

谢谢大家