再求一SQL语句 搞不定

ykwang 2008-10-13 03:40:57
有两个表
A表如下
Datefield
2007-10-01
2008-01-05
2008-03-05
2008-07-05
2008-10-05

A表就一个字段 Datefield ,其中的值为日期, 日期会有所变动

B表如下

Name datefield prices
a 2007-05-03 3
a 2008-02-01 4
a 2008-03-05 5
a 2008-08-10 3.5
a 2008-10-15 3.6
b 2007-06-01 3
b 2008-01-01 3.6
b 2008-05-03 4.1
b 2008-10-01 4.5

要求达到如下的结果值
Name 2007-10-01 2008-01-05 2008-03-05 2008-07-05 2008-10-05 (注列名来自A表记录)
a 3 3 5 5 3.5
b 3 3.6 3.6 4.1 4.5

如A产品的 2007-10-01 ,就是取B表中2007-10-01 日期以前的 price,在这之前只有2007-05-03的3数据,所以取3,其它字段一样,目的就是取这个日期前的 price, 想了一下午,还是搞不定,特求教.谢谢.
...全文
90 7 打赏 收藏 转发到动态 举报
写回复
用AI写文章
7 条回复
切换为时间正序
请发表友善的回复…
发表回复
jiang5311 2008-10-13
  • 打赏
  • 举报
 回复
mark
ykwang 2008-10-13
  • 打赏
  • 举报
 回复
唉,我还是搞不懂这语句的意思,还得努力,问题解决.
非常感谢.
csdyyr 2008-10-13
  • 打赏
  • 举报
 回复 


create table ta(datefield smalldatetime)

insert ta

select '2007-10-01' union all

select '2008-01-05' union all

select '2008-03-05' union all

select '2008-07-05' union all

select '2008-10-05' 





create table tb(Name    varchar(2),datefield smalldatetime,    prices numeric(10,2))

insert tb

select 'a',        '2007-05-03' ,   3 union all

select 'a',        '2008-02-01'  ,  4 union all

select 'a',        '2008-03-05'   , 5 union all

select 'a',        '2008-08-10'   , 3.5 union all

select 'a',        '2008-10-15'    ,3.6 union all

select 'b',        '2007-06-01'   , 3 union all

select 'b',        '2008-01-01'   , 3.6 union all

select 'b',        '2008-05-03'    ,4.1 union all

select 'b',        '2008-10-01'   , 4.5 



declare @sql varchar(8000)

set @sql=''

select @sql=@sql+','+' (select top 1 prices from tb where Name=a.Name and datefield<='''+convert(varchar(10),datefield,120)+''' order by datefield desc) as '''+convert(varchar(10),datefield,120)+''''

from ta

group by datefield



set @sql='select Name'+@sql+' from tb as a group by name'

--print @sql

exec(@sql)



drop table ta

drop table tb

/*

Name 2007-10-01   2008-01-05   2008-03-05   2008-07-05   2008-10-05   

---- ------------ ------------ ------------ ------------ ------------ 

a    3.00         3.00         5.00         5.00         3.50

b    3.00         3.60         3.60         4.10         4.50



*/
中国风 2008-10-13
  • 打赏
  • 举报
 回复 
--> --> 

 

if not object_id('A') is null

	drop table A

Go

Create table A([Datefield] Datetime)

Insert A

select '2007-10-01' union all

select '2008-01-05' union all

select '2008-03-05' union all

select '2008-07-05' union all

select '2008-10-05'

Go

--> --> 

 

if not object_id('B') is null

	drop table B

Go

Create table B([Name] nvarchar(1),[datefield] Datetime,[prices] decimal(18,1))

Insert B

select N'a','2007-05-03',3 union all

select N'a','2008-02-01',4 union all

select N'a','2008-03-05',5 union all

select N'a','2008-08-10',3.5 union all

select N'a','2008-10-15',3.6 union all

select N'b','2007-06-01',3 union all

select N'b','2008-01-01',3.6 union all

select N'b','2008-05-03',4.1 union all

select N'b','2008-10-01',4.5

Go



declare @s nvarchar(4000)

set @s='select [Name]'

select @s=@s+','+quotename(convert(varchar(10),[Datefield],120))+'=(select top 1 [prices] from B where [Name]=t.[Name] and  [Datefield]<='+quotename(convert(varchar(10),[Datefield],120),'''')+ ' order by [Datefield] desc)'

from A

exec(@s+' from B t group by [Name]' )



Name 2007-10-01                              2008-01-05                              2008-03-05                              2008-07-05                              2008-10-05

---- --------------------------------------- --------------------------------------- --------------------------------------- --------------------------------------- ---------------------------------------

a    3.0                                     3.0                                     5.0                                     5.0                                     3.5

b    3.0                                     3.6                                     3.6                                     4.1                                     4.5



(2 個資料列受到影響)
hyde100 2008-10-13
  • 打赏
  • 举报
 回复
又是行列转换
水族杰纶 2008-10-13
  • 打赏
  • 举报
 回复 
普通行列转换

问题：假设有张学生成绩表(tb)如下:

姓名 课程 分数

张三 语文 74

张三 数学 83

张三 物理 93

李四 语文 74

李四 数学 84

李四 物理 94

想变成(得到如下结果)： 

姓名 语文 数学 物理 

---- ---- ---- ----

李四 74   84   94

张三 74   83   93

-------------------

*/



create table tb(姓名 varchar(10) , 课程 varchar(10) , 分数 int)

insert into tb values('张三' , '语文' , 74)

insert into tb values('张三' , '数学' , 83)

insert into tb values('张三' , '物理' , 93)

insert into tb values('李四' , '语文' , 74)

insert into tb values('李四' , '数学' , 84)

insert into tb values('李四' , '物理' , 94)

go



--SQL SERVER 2000 静态SQL,指课程只有语文、数学、物理这三门课程。(以下同)

select 姓名 as 姓名 ,

  max(case 课程 when '语文' then 分数 else 0 end) 语文,

  max(case 课程 when '数学' then 分数 else 0 end) 数学,

  max(case 课程 when '物理' then 分数 else 0 end) 物理

from tb

group by 姓名



--SQL SERVER 2000 动态SQL,指课程不止语文、数学、物理这三门课程。(以下同)

declare @sql varchar(8000)

set @sql = 'select 姓名 '

select @sql = @sql + ' , max(case 课程 when ''' + 课程 + ''' then 分数 else 0 end) [' + 课程 + ']'

from (select distinct 课程 from tb) as a

set @sql = @sql + ' from tb group by 姓名'

exec(@sql) 



--SQL SERVER 2005 静态SQL。

select * from (select * from tb) a pivot (max(分数) for 课程 in (语文,数学,物理)) b



--SQL SERVER 2005 动态SQL。

declare @sql varchar(8000)

select @sql = isnull(@sql + ',' , '') + 课程 from tb group by 课程

exec ('select * from (select * from tb) a pivot (max(分数) for 课程 in (' + @sql + ')) b')



---------------------------------



/*

问题：在上述结果的基础上加平均分，总分，得到如下结果：

姓名 语文 数学 物理 平均分 总分 

---- ---- ---- ---- ------ ----

李四 74   84   94   84.00  252

张三 74   83   93   83.33  250

*/



--SQL SERVER 2000 静态SQL。

select 姓名 姓名,

  max(case 课程 when '语文' then 分数 else 0 end) 语文,

  max(case 课程 when '数学' then 分数 else 0 end) 数学,

  max(case 课程 when '物理' then 分数 else 0 end) 物理,

  cast(avg(分数*1.0) as decimal(18,2)) 平均分,

  sum(分数) 总分

from tb

group by 姓名



--SQL SERVER 2000 动态SQL。

declare @sql varchar(8000)

set @sql = 'select 姓名 '

select @sql = @sql + ' , max(case 课程 when ''' + 课程 + ''' then 分数 else 0 end) [' + 课程 + ']'

from (select distinct 课程 from tb) as a

set @sql = @sql + ' , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名'

exec(@sql) 



--SQL SERVER 2005 静态SQL。

select m.* , n.平均分 , n.总分 from

(select * from (select * from tb) a pivot (max(分数) for 课程 in (语文,数学,物理)) b) m,

(select 姓名 , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名) n

where m.姓名 = n.姓名



--SQL SERVER 2005 动态SQL。

declare @sql varchar(8000)

select @sql = isnull(@sql + ',' , '') + 课程 from tb group by 课程

exec ('select m.* , n.平均分 , n.总分 from

(select * from (select * from tb) a pivot (max(分数) for 课程 in (' + @sql + ')) b) m , 

(select 姓名 , cast(avg(分数*1.0) as decimal(18,2)) 平均分 , sum(分数) 总分 from tb group by 姓名) n

where m.姓名 = n.姓名')



drop table tb    



------------------

------------------



/*

问题：如果上述两表互相换一下：即表结构和数据为：

姓名 语文 数学 物理

张三 74　　83　　93

李四 74　　84　　94

想变成(得到如下结果)： 

姓名 课程 分数 

---- ---- ----

李四 语文 74

李四 数学 84

李四 物理 94

张三 语文 74

张三 数学 83

张三 物理 93

--------------

*/



create table tb(姓名 varchar(10) , 语文 int , 数学 int , 物理 int)

insert into tb values('张三',74,83,93)

insert into tb values('李四',74,84,94)

go



--SQL SERVER 2000 静态SQL。

select * from

(

select 姓名 , 课程 = '语文' , 分数 = 语文 from tb 

union all

select 姓名 , 课程 = '数学' , 分数 = 数学 from tb

union all

select 姓名 , 课程 = '物理' , 分数 = 物理 from tb

) t

order by 姓名 , case 课程 when '语文' then 1 when '数学' then 2 when '物理' then 3 end



--SQL SERVER 2000 动态SQL。

--调用系统表动态生态。

declare @sql varchar(8000)

select @sql = isnull(@sql + ' union all ' , '' ) + ' select 姓名 , [课程] = ' + quotename(Name , '''') + ' , [分数] = ' + quotename(Name) + ' from tb'

from syscolumns 

where name! = N'姓名' and ID = object_id('tb') --表名tb，不包含列名为姓名的其它列

order by colid asc

exec(@sql + ' order by 姓名 ')



--SQL SERVER 2005 动态SQL。

select 姓名 , 课程 , 分数 from tb unpivot (分数 for 课程 in([语文] , [数学] , [物理])) t



--SQL SERVER 2005 动态SQL，同SQL SERVER 2000 动态SQL。



--------------------

/*

问题：在上述的结果上加个平均分，总分，得到如下结果：

姓名 课程   分数

---- ------ ------

李四 语文   74.00

李四 数学   84.00

李四 物理   94.00

李四 平均分 84.00

李四 总分   252.00

张三 语文   74.00

张三 数学   83.00

张三 物理   93.00

张三 平均分 83.33

张三 总分   250.00

------------------

*/



select * from

(

select 姓名 as 姓名 , 课程 = '语文' , 分数 = 语文 from tb 

union all

select 姓名 as 姓名 , 课程 = '数学' , 分数 = 数学 from tb

union all

select 姓名 as 姓名 , 课程 = '物理' , 分数 = 物理 from tb

union all

select 姓名 as 姓名 , 课程 = '平均分' , 分数 = cast((语文 + 数学 + 物理)*1.0/3 as decimal(18,2)) from tb

union all

select 姓名 as 姓名 , 课程 = '总分' , 分数 = 语文 + 数学 + 物理 from tb

) t

order by 姓名 , case 课程 when '语文' then 1 when '数学' then 2 when '物理' then 3 when '平均分' then 4 when '总分' then 5 end



drop table tb
C# 使用参数化SQL语句
单击“登录“按钮后，你会发现竟然也能进入主窗体！... 登录成功后，显示的主窗体，如下图： ...我们在程序中存在着大量拼接产生SQL语句的代码，这就会导致一个比较大的安全隐患，容易遭受SQL注入攻击。就这个窗体例
Android：Room动态拼写原生sql语句
如果不用Room提供的注解方式去查询sql，根据需求要写冗长复杂的查询语句（比如查询的条件数量不是固定的，语句不定长），注解的方式去写实现不了需求，那么就要用Room动态拼写原生sql语句去查询： 使用...
常用SQL语句大全
前言： ...可能有些SQL你还不常用，但还是希望对你有所帮助，说不定某日有需求就可以用到。 注：下文分享的SQL适用于MySQL 5.7 版本，低版本可能稍许不同。有些SQL可能执行需要较高权限。 1.show...
Linux系统中的SQL语句
本节主要学习，SQL语句的语句类型，数据库操作，数据表操作，和数据操作等。
MySQL数据库的SQL语句(详细介绍)
MySQL数据库的SQL语句(详细介绍)
MS-SQL Server

34,590

社区成员

254,589

社区内容

发帖
与我相关
我的任务
社区描述
MS-SQL Server相关内容讨论专区
社区管理员
  • 基础类社区
  • 二月十六
  • 卖水果的net
加入社区
  • 近7日
  • 近30日
  • 至今

加载中

查看更多榜单
社区公告
暂无公告

试试用AI创作助手写篇文章吧

+ 用AI写文章