VB如何退出U盘

[huangyahai]

VB如何编程 退出U盘
本人想程序控制 退出U盘设备
请高手指点

[huangyahai]

有没有高手指点下哦。。。。

[yinweihong]

Option Explicit
Dim boTimeOut As Boolean

Private Const DRIVE_CDROM As Long = 5
Private Const DRIVE_REMOVABLE As Long = 2

Private Const GENERIC_READ As Long = &H80000000
Private Const GENERIC_WRITE As Long = &H40000000

Private Const OPEN_EXISTING As Long = 3
Private Const FILE_DEVICE_FILE_SYSTEM As Long = 9
Private Const FILE_DEVICE_MASS_STORAGE As Long = &H2D&
Private Const METHOD_BUFFERED As Long = 0
Private Const FILE_ANY_ACCESS As Long = 0
Private Const FILE_READ_ACCESS As Long = 1
Private Const LOCK_VOLUME As Long = 6
Private Const DISMOUNT_VOLUME As Long = 8
Private Const EJECT_MEDIA As Long = &H202
Private Const MEDIA_REMOVAL As Long = &H201
Private Const INVALID_HANDLE_VALUE As Long = -1

Private Const LOCK_TIMEOUT As Long = 1000
Private Const LOCK_RETRIES As Long = 20

Private Declare Function GetDriveType Lib "kernel32.dll" _
            Alias "GetDriveTypeA" _
            (ByVal nDrive As String) As Long
        
Private Declare Function CloseHandle Lib "kernel32.dll" _
            (ByVal hObject As Long) As Long

Private Declare Function CreateFile Lib "kernel32.dll" Alias "CreateFileA" _
            (ByVal lpFileName As String, _
             ByVal dwDesiredAccess As Long, _
             ByVal dwShareMode As Long, _
             ByRef lpSecurityAttributes As Long, _
             ByVal dwCreationDisposition As Long, _
             ByVal dwFlagsAndAttributes As Long, _
             ByVal hTemplateFile As Long) As Long
             
Private Declare Function DeviceIoControl Lib "kernel32.dll" _
            (ByVal hDevice As Long, _
             ByRef dwIoControlCode As Long, _
             ByRef lpInBuffer As Any, _
             ByVal nInBufferSize As Long, _
             ByRef lpOutBuffer As Any, _
             ByVal nOutBufferSize As Long, _
             ByRef lpBytesReturned As Long, _
             ByRef lpOverlapped As Long) As Long
Private Function CTL_CODE(lngDevFileSys As Long, lngFunction As Long, _
              lngMethod As Long, lngAccess As Long) As Long
CTL_CODE = (lngDevFileSys * (2 ^ 16)) Or (lngAccess * (2 ^ 14)) Or (lngFunction * (2 ^ 2)) Or lngMethod
End Function

Private Function OpenVolume(strLetter As String, lngVolHandle As Long) As Boolean
Dim lngDriveType As Long
Dim lngAccessFlags As Long
Dim strVolume As String
lngDriveType = GetDriveType(strLetter)
Select Case lngDriveType
    Case DRIVE_REMOVABLE
        lngAccessFlags = GENERIC_READ Or GENERIC_WRITE
    Case DRIVE_CDROM
        lngAccessFlags = GENERIC_READ
    Case Else
        OpenVolume = False
        Exit Function
End Select
strVolume = "\\.\" & strLetter
lngVolHandle = CreateFile(strVolume, lngAccessFlags, 0, _
                ByVal CLng(0), OPEN_EXISTING, ByVal CLng(0), ByVal CLng(0))
If lngVolHandle = INVALID_HANDLE_VALUE Then
    OpenVolume = False
    Exit Function
End If
OpenVolume = True
End Function

Private Function CloseVolume(lngVolHandle As Long) As Boolean
Dim lngReturn As Long
lngReturn = CloseHandle(lngVolHandle)
If lngReturn = 0 Then
    CloseVolume = False
Else
    CloseVolume = True
End If
End Function

Private Function LockVolume(ByRef lngVolHandle As Long) As Boolean
Dim lngBytesReturned As Long
Dim intCount As Integer
Dim intI As Integer
Dim boLocked As Boolean
Dim lngFunction As Long
lngFunction = CTL_CODE(FILE_DEVICE_FILE_SYSTEM, LOCK_VOLUME, METHOD_BUFFERED, FILE_ANY_ACCESS)
intCount = LOCK_TIMEOUT / LOCK_RETRIES
boLocked = False
For intI = 0 To LOCK_RETRIES
    boTimeOut = False
    Timer1.Interval = intCount
    Timer1.Enabled = True
    Do Until boTimeOut = True Or boLocked = True
        boLocked = DeviceIoControl(lngVolHandle, ByVal lngFunction, _
                    CLng(0), 0, CLng(0), 0, lngBytesReturned, ByVal CLng(0))
        DoEvents
    Loop
    If boLocked = True Then
        LockVolume = True
        Timer1.Enabled = False
        Exit Function
    End If
Next intI
LockVolume = False
End Function
Private Function DismountVolume(lngVolHandle As Long) As Boolean
Dim lngBytesReturned As Long
Dim lngFunction As Long
lngFunction = CTL_CODE(FILE_DEVICE_FILE_SYSTEM, DISMOUNT_VOLUME, METHOD_BUFFERED, FILE_ANY_ACCESS)
DismountVolume = DeviceIoControl(lngVolHandle, ByVal lngFunction, _
                    0, 0, 0, 0, lngBytesReturned, ByVal 0)
End Function
Private Function PreventRemovalofVolume(lngVolHandle As Long) As Boolean
Dim boPreventRemoval As Boolean
Dim lngBytesReturned As Long
Dim lngFunction As Long
boPreventRemoval = False
lngFunction = CTL_CODE(FILE_DEVICE_MASS_STORAGE, MEDIA_REMOVAL, METHOD_BUFFERED, FILE_READ_ACCESS)
PreventRemovalofVolume = DeviceIoControl(lngVolHandle, ByVal lngFunction, _
                        boPreventRemoval, Len(boPreventRemoval), 0, 0, lngBytesReturned, ByVal 0)
End Function
Private Function AutoEjectVolume(lngVolHandle As Long) As Boolean
Dim lngFunction As Long
Dim lngBytesReturned As Long
lngFunction = CTL_CODE(FILE_DEVICE_MASS_STORAGE, EJECT_MEDIA, METHOD_BUFFERED, FILE_READ_ACCESS)
AutoEjectVolume = DeviceIoControl(lngVolHandle, ByVal lngFunction, _
                    0, 0, 0, 0, lngBytesReturned, ByVal 0)
End Function

Private Sub Eject(strVol As String)
Dim lngVolHand As Long
Dim boResult As Boolean
Dim boSafe As Boolean
strVol = strVol & ":"
'
' Open and get a Handle for the Volume
'
boResult = OpenVolume(strVol, lngVolHand)
If boResult = False Then
    MsgBox "Error Opening Volume " & Err.LastDllError
    Exit Sub
End If
'
' Lock the Volume
'
boResult = LockVolume(lngVolHand)
If boResult = False Then
    MsgBox "Error Dismounting Volume " & Err.LastDllError
    CloseVolume (lngVolHand)
    Exit Sub
End If
'
'Dismount the Volume
'
boResult = DismountVolume(lngVolHand)
If boResult = False Then
    MsgBox "Error Dismounting Volume " & Err.LastDllError
    CloseVolume (lngVolHand)
    Exit Sub
End If
'
' Set to allow the Volume to be Removed
'
boResult = PreventRemovalofVolume(lngVolHand)
If boResult = False Then
    MsgBox "Error Allowing Removal of Volume " & Err.LastDllError
    CloseVolume (lngVolHand)
    Exit Sub
End If
boSafe = True
'
' Eject the Volume
'
boResult = AutoEjectVolume(lngVolHand)
If boSafe = True Then
    MsgBox "Media may be Safely Removed from Drive " & UCase(strVol)
End If
'
' Close the Handle
'
boResult = CloseVolume(lngVolHand)
If boResult = False Then
    MsgBox "Error Closing Volume " & Err.LastDllError
    Exit Sub
End If
Unload Me
End Sub

Private Sub Timer1_Timer()
boTimeOut = True
End Sub
It's called by 

Code:
Call Eject(drive letter without the colon)

[yinweihong]

http://support.microsoft.com/default.aspx?scid=kb;en-us;165721 C的

[huangyahai]

谢谢楼上的朋友
不过好复杂，本人初学者
卸载U盘 竟然 要这么复杂
好好学习中

[东方之珠]

这儿有简单的。http://blog.csdn.net/chenhui530/archive/2007/12/13/1932917.aspx

[tanjiunnya]

'Module

Option Explicit

Public Const IOCTL_STORAGE_EJECT_MEDIA As Long = &H2D4808
Public Const IOCTL_STORAGE_LOAD_MEDIA As Long = &H2D480C

Public Function DeviceSetMedia(sDrive As String, ctrlCode As Long) As Boolean

Dim hDevice As Long
Dim bytesReturned As Long
Dim success As Long

'the drive letter has to be passed
'without a trailing slash (ie 'G:')
sDrive = UnQualifyPath(sDrive)

'obtain a handle to the device
hDevice = CreateFile("\\.\" & sDrive, _
GENERIC_READ, _
FILE_SHARE_READ Or FILE_SHARE_WRITE, _
ByVal 0&, _
OPEN_EXISTING, _
0&, 0&)

If hDevice <> INVALID_HANDLE_VALUE Then

'If the operation succeeds,
'DeviceIoControl returns zero
success = DeviceIoControl(hDevice, _
ctrlCode, _
0&, _
0&, _
ByVal 0&, _
0&, _
bytesReturned, _
ByVal 0&)

End If

Call CloseHandle(hDevice)
DeviceSetMedia = success <> 0

End Function

[tanjiunnya]

'Form
Option Explicit

Private Sub Command2_Click(Index As Integer)

Dim sDrive As String

If List1.ListIndex > -1 Then

sDrive = List1.List(List1.ListIndex)

Select Case Index
Case 0
Call DeviceSetMedia(sDrive, IOCTL_STORAGE_EJECT_MEDIA)
Case 1
Call DeviceSetMedia(sDrive, IOCTL_STORAGE_LOAD_MEDIA)
End Select

End If

End Sub

[bob008]

MARK