sql 语句 问题

[zhouzhijian888]

a b
1 a,b,c,,,d,ab,bc,,a

b长度没有限制 如何等到如下结果 行转列 两个逗号之间的数据取出
a b

1 a
1 b
1 c
1 null
1 null
1 d
1 ab
1 bc
1 null
1 a

[shinlgienls]

    @ids varchar(1000) -- such as 1 修改的ID
    ,@types varchar(8000) -- such as '123,456,789' 插入的数据

    declare @tb table(id int, iDAmout nvarchar) 
     declare @index_1 int, @index_2 int 
    select @index_1=ids, @index_2=charindex(',',@types) 
    while @index_2>0 
    begin 
        insert @tb select @ids,substring(@types,1, @index_2-1) 
        select @types=stuff(@types,1,@index_2,'') 
        select @index_2=charindex(',',@types) 
    end 

select @tb

你适当修改 修改吧

[zhouzhijian888]

你的程序 编译都过不去

[中国风]

參照
http://topic.csdn.net/u/20080612/22/c850499f-bce3-4877-82d5-af2357857872.html

[中国风]

use Test
go
--> --> 
 
if not object_id('Tempdb..#') is null
	drop table #
Go
Create table #([a] int,[b] nvarchar(18))
Insert #
select 1,N'a,b,c,,,d,ab,bc,,a'
Go

;with roy as 
(select [a],[b]=cast(left([b],charindex(',',[b]+',')-1) as nvarchar(100)),Split=cast(stuff([b]+',',1,charindex(',',[b]+','),'') as nvarchar(100)) from #
union all
select [a],[b]=cast(left(Split,charindex(',',Split)-1) as nvarchar(100)),Split= cast(stuff(Split,1,charindex(',',Split),'') as nvarchar(100)) from Roy where split>''
)
select [a],[b]=nullif(b,'') from roy order by [a] option (MAXRECURSION 0)


(1 個資料列受到影響)
a           b
----------- ----------------------------------------------------------------------------------------------------
1           a
1           b
1           c
1           NULL
1           NULL
1           d
1           ab
1           bc
1           NULL
1           a

(10 個資料列受到影響)

[中国风]

2000方法
use Test
go
--> --> 
 
if not object_id('Tempdb..#') is null
	drop table #
Go
Create table #([a] int,[b] nvarchar(18))
Insert #
select 1,N'a,b,c,,,d,ab,bc,,a'
Go
if object_id('Tempdb..#Num') is not null
    drop table #Num
select top 100 ID=Identity(int,1,1) into #Num from syscolumns a,syscolumns b

Select 
    a.[a],[b]=nullif(substring(a.[b],b.ID,charindex(',',a.[b]+',',b.ID)-b.ID),'')
from 
    # a,#Num b
where
    charindex(',',','+a.[b],b.ID)=b.ID

a           b
----------- ------------------
1           a
1           b
1           c
1           NULL
1           NULL
1           d
1           ab
1           bc
1           NULL
1           a

(10 個資料列受到影響)

[zhouzhijian888]

我再研究下 ！~~

[dawugui]

分拆列值

原著：邹建
改编：爱新觉罗.毓华(十八年风雨,守得冰山雪莲花开)  2007-12-16  广东深圳

有表tb, 如下:
id          value
----------- -----------
1           aa,bb
2           aaa,bbb,ccc
欲按id,分拆value列, 分拆后结果如下:
id          value
----------- --------
1           aa
1           bb
2           aaa
2           bbb
2           ccc

1. 旧的解决方法(sql server 2000)
SELECT TOP 8000 id = IDENTITY(int, 1, 1) INTO # FROM syscolumns a, syscolumns b 

SELECT A.id, SUBSTRING(A.[values], B.id, CHARINDEX(',', A.[values] + ',', B.id) - B.id)
FROM tb A, # B
WHERE SUBSTRING(',' + A.[values], B.id, 1) = ','

DROP TABLE #

2. 新的解决方法(sql server 2005) 

create table tb(id int,value varchar(30))
insert into tb values(1,'aa,bb')
insert into tb values(2,'aaa,bbb,ccc')
go
SELECT A.id, B.value
FROM(
    SELECT id, [value] = CONVERT(xml,'<root><v>' + REPLACE([value], ',', '</v><v>') + '</v></root>') FROM tb
)A
OUTER APPLY(
    SELECT value = N.v.value('.', 'varchar(100)') FROM A.[value].nodes('/root/v') N(v)
)B

DROP TABLE tb

/*
id          value
----------- ------------------------------
1           aa
1           bb
2           aaa
2           bbb
2           ccc

(5 行受影响)
*/

[dawugui]

/*
功能：实现split功能的函数
*/

create function dbo.fn_split 
(
@inputstr varchar(8000), 
@seprator varchar(10)
)
returns @temp table (a varchar(200))
as 

begin
declare @i int

set @inputstr = rtrim(ltrim(@inputstr))
set @i = charindex(@seprator, @inputstr)

while @i >= 1
begin
insert @temp values(left(@inputstr, @i - 1))

set @inputstr = substring(@inputstr, @i + 1, len(@inputstr) - @i)
set @i = charindex(@seprator, @inputstr)
end

if @inputstr <> '\'
insert @temp values(@inputstr)

return 
end
go

--调用

declare @s varchar(1000)

set @s='1,2,3,4,5,6,7,8,55'

select * from dbo.fn_split(@s,',')

drop function dbo.fn_split 

[zhouzhijian888]

老大 有不用系统表和临时表的办法么？

[zhouzhijian888]

快下班了 我先结贴 给大家散分

[zhouzhijian888]

select