创建数据库的小问题.

[cnjsnt1995]

create project 文件1 ---可以创建项目
create database 文件2---可以创建数据库
create table 文件3----可以创建表

那么如何用命令将文件3添加到数据库文件2中,如何再将数据库文件2添加到项目文件文件1中呢?

指点一下.谢谢.

[WWWWA]

create database 文件2---可以创建数据库
create table 文件3----可以创建表
文件3已经在文件2中，用建立项目，将文件2加入项目中即可

[十豆三]

将文件3添加到数据库文件2中
----------------------------------------
ADD TABLE 命令

添加一个自由表到当前数据库中。


ADD TABLE TableName | ? [NAME LongTableName]


参数
TableName
指定要添加到数据库的表的名称。
?
显示打开对话框，从中可以选择要添加到数据库中的表。
NAME LongTableName
指定表的长名。长名可以包含最多 128 个字符，并且可以用来取代扩展名为 .DBF 的短文件名。
说明
将表添加到数据库中后，可以像其他数据库表一样对该表进行操作。

一旦表被添加到数据库中，就不再是自由表。不过，可以使用 REMOVE TABLE 使数据库中的任何一个表成为自由表。

要添加的表必须具备下列条件：

必须是有效的 .DBF 文件。
除非为表指定一个唯一的长名，否则表不能与打开的数据库中已有的表同名。
不能存在于另外一个数据库中。使用 REMOVE TABLE 可以从另外一个数据库中移去表。
要添加表的数据库不能在一个事务处理中被调用。

示例
下面的示例创建两个名为 mydbc1 和 mydbc2的数据库 ，和一个名为 table1的表。在创建表时，把表添加到 mydbc1 数据库中。然后关闭表，并从 mydbc1.中移去。再使用 ADD TABLE 把表添加到数据库 mydbc2中。最后使用 RENAME TABLE 把表名由 table1 改为 table2。

　 复制代码
CREATE DATABASE mydbc1
CREATE DATABASE mydbc2
SET DATABASE TO mydbc1
CREATE TABLE table1 (cField1 C(10), n N(10)) && 添加表到 mydbc1中
CLOSE TABLES && 从数据库中移去表时它必须是关闭的
REMOVE TABLE table1
SET DATABASE TO mydbc2
ADD TABLE table1
RENAME TABLE table1 TO table2

[十豆三]

将数据库文件2添加到项目文件文件1中
---------------------------------
Add 方法 (文件对象) 将一个文件添加到项目中。

Object.Add(cFileName)

参数
cFileName
指定要添加到项目中的文件的名称。如果所指定的文件不存在，会产生一个错误。如果打开了项目管理器窗口，则在添加了该文件之后刷新该窗口。
返回值
对象型

说明
应用于：Files 集合

Add 方法是文件集合的方法。当使用 Add 方法将一个文件添加到项目中时，会为该文件创建一个 File 对象，并且该 File 对象添加到文件集合中。

如果新文件成功地添加到项目，则会返回该文件的一个对象引用。如果该文件不能添加到项目中，会返回 null 值。

当一个文件添加到项目之前，会发生 QueryAddFile 事件。如果在 QueryAddFile 事件中指定了 NODEFAULT，则该文件就不会添加到项目中。

在 QueryAddFile 事件中包含 NODEFAULT，会防止将一个文件添加到项目中。

示例
下面示例编程地创建一个项目然后从项目联编为一个可执行文件 (EXE)。它使用 Add 方法来添加程序代码到项目。
SET SAFETY OFF
LOCAL lcCode
TEXT TO lcCode NOSHOW
CLEAR
PUBLIC loForm
SET TALK OFF
SET DELETED ON
SET EXCLUSIVE OFF
SET CENTURY ON
ON SHUTDOWN clear events
loForm = CREATEOBJECT('Test1')
loForm.Show(0)
READ EVENTS
ON SHUTDOWN
RETURN
DEFINE CLASS Test1 as Form
Top = 0
Left = 0
Width = 240
Height = 150
Caption = 'Add 方法 sample'
ShowWindow = 2
ADD OBJECT cmdClose as CommandButton WITH ;
Caption = '\<Close', ;
Top = 80, ;
Left = 80, ;
Height = 24, ;
Width = 80
ADD OBJECT lblTitle as Label WITH ;
Top = 30, ;
Left = 40, ;
Height = 34, ;
Width = 160, ;
Caption = 'This sample was made programmatically.';
WordWrap = .t.
PROCEDURE Init
SET TALK off
ThisForm.AutoCenter = .t.
ENDPROC
PROCEDURE Unload
CLEAR EVENTS
ENDPROC
PROCEDURE cmdClose.Click
ThisForm.Release()
ENDPROC
ENDDEFINE
ENDTEXT
STRTOFILE(lcCode, 'addsample.prg')
CREATE PROJECT 'AddSample' NOSHOW NOWAIT SAVE
LOCAL loPJX
loPJX = _VFP.ActiveProject
WITH loPJX
.Files.Add('addsample.prg')
.SetMain('addsample.prg')
.Build('addsample.exe',3,.t.,.t.,.f.)
.Close()
ENDWITH
RUN /n addsample.exe

[cnjsnt1995]

将数据库文件2添加到项目文件文件1中
能够简单说一下吗?

[WWWWA]

[Quote=引用 4 楼 cnjsnt1995 的回复:]
将数据库文件2添加到项目文件文件1中
能够简单说一下吗?
[/Quote]
你不会是用代码加入项目中吧？

[cnjsnt1995]

不是.有没有一个类似add table这样的简单命令,将将数据库文件2添加到项目文件文件1中 ?

[WWWWA]

CREATE PROJECT 'AddSample' NOSHOW NOWAIT SAVE
LOCAL loPJX
loPJX = _VFP.ActiveProject
WITH loPJX
.Files.Add('tt.dbc')
.Files.Add('tt.dbf')
.Files.Add('addsample.prg')
.SetMain('addsample.prg')
.Build('addsample.exe',3,.t.,.t.,.f.)
.Close()
ENDWITH

[十豆三]

[Quote=引用 6 楼 cnjsnt1995 的回复:]
不是.有没有一个类似add table这样的简单命令,将将数据库文件2添加到项目文件文件1中 ?
[/Quote]

这就是代码方式嘛。

Close All
Create Project '文件1' Noshow Nowait Save
Create Database '文件2'
Create Table '文件3' (mytest i)
Local loPJX
loPJX = _vfp.ActiveProject
With loPJX
	.Files.Add('文件2.dbc')
	.Close()
Endwith
Modify Project '文件1'