UPDATE更新所有表所有字段的全角半角问题。

[cbxmir]

转换的函数已经找到。问题是怎么写这个sql语句把所有字段都转了。最好是所有表。总不能一个字段一个字段都写出来吧？
---------------------------------------------------------------------------------转换函数
if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[f_convert]') and xtype in (N'FN', N'IF', N'TF'))
drop function [dbo].[f_convert]
GO

/*--全角/半角转换

转换说明
全角字符从的unicode编码从65281~65374
半角字符从的unicode编码从 33~126
空格比较特殊,全角为 12288,半角为 32
而且除空格外,全角/半角按unicode编码排序在顺序上是对应的
所以可以直接通过用+-法来处理非空格数据,对空格单独处理
like的时候,指定排序规则 COLLATE Latin1_General_BIN
是保证字符顺序按unicode编码排序

*/
Create FUNCTION f_Convert(
@str NVARCHAR(4000), --要转换的字符串
@flag bit --转换标志,0转换成半角,1转换成全角
)RETURNS nvarchar(4000)
AS
BEGIN
DECLARE @pat nvarchar(8),@step int,@i int,@spc int
IF @flag=0
Select @pat=N'%[！-～]%',@step=-65248,
@str=REPLACE(@str,N'　',N' ')
ELSE
Select @pat=N'%[!-~]%',@step=65248,
@str=REPLACE(@str,N' ',N'　')
SET @i=PATINDEX(@pat COLLATE LATIN1_GENERAL_BIN,@str)
WHILE @i>0
Select @str=REPLACE(@str,
SUBSTRING(@str,@i,1),
NCHAR(UNICODE(SUBSTRING(@str,@i,1))+@step))
,@i=PATINDEX(@pat COLLATE LATIN1_GENERAL_BIN,@str)
RETURN(@str)
END
GO
---------------------------------------------------------------------------------转换函数

---------------------------------------------------------------------------------转换语句
update 表 set 字段1=dbo.f_convert(字段1,0)
---------------------------------------------------------------------------------转换语句

问题是怎么写转换全部字段？而不是一个一个写出来
在线等待。测试成功马上给分。

[等不到来世]

declare @sql nvarchar(max)
select @sql=isnull(@sql+';','')+'update 表 set '+name+'=dbo.f_convert('+name+',0)'
from syscolumns
where id=object_id('表')
--print @sql
exec(@sql)

[水族杰纶]

--try
declare @s varchar(8000)
select @s=isnull(@s,'')+'update 表 set '+name+'=dbo.f_convert('+name+',0)' from syscolumns where id=object_id('test') 
print @s
exec(@s)

[水族杰纶]

--try
declare @s varchar(8000)
select @s=isnull(@s,'')+'update 表 set '+name+'=dbo.f_convert('+name+',0)' from syscolumns where id=object_id('表') 
print @s
exec(@s)

[cbxmir]

可以用。结贴给分。。哈哈。多谢楼山。又学一招啊。

[csdyyr]

--未测试，请先备份数据库
exec sp_msforeachtable N'declare @s varchar(8000) select @s=isnull(@s,'''')+''update ? set ''+name+''=dbo.f_convert(''+name+'',0)'' from syscolumns where id=object_id(N''?'') print @s exec(@s)'