求一个8086汇编语言写的时钟源程序

[bichongjunb]

求高手帮忙些一个8086汇编的时钟程序，可以正常显示时分秒和日期，如果用芯片可用8253，8255.8259等，急用，谢谢

[「已注销」]

用C好做。

[itxuuitdgdipwa]

assume cs:code
code segment
start:
;清屏
mov ah,6 ;
mov al,0 ;
mov ch,0
mov cl,0 ;
mov dh,24
mov dl,79
mov bh,7
int 10h
l:
;年
mov al,9
mov si,0
call s

mov byte ptr es:[160*12+2*40+4],'/'

;月
mov al,8
mov si,6
call s

mov byte ptr es:[160*12+2*40+10],'/'

;日
mov al,7
mov si,12
call s

mov byte ptr es:[160*12+2*40+16],' '

;取时数并送入显存
mov al,4
mov si,18
call s

mov byte ptr es:[160*12+2*40+22],':'

;取分数并送入显存
mov al,2
mov si,24
call s

mov byte ptr es:[160*12+2*40+28],':'

;取秒数并送入显存
mov al,0
mov si,30
call s
jmp l

mov ax,4c00h
int 21h

;*******************子程序******************
;名称：s
;作用：取出BCD码并送入显存
;入参:al为单元数，si为显存偏移地址变址
;*******************************************
s: push ax
push bx
push si

out 70h,al
in al,71h
mov cl,4
mov ah,al
shr ah,cl
and al,00001111b
add al,30h
add ah,30h

mov bx,0b800h
mov es,bx
mov bx,160*12+2*40
mov es:[bx+si],ah
mov es:[bx+si+2],al

pop si
pop bx
pop ax
ret

code ends
end start

[ufofind]

assume cs:code
code segment
time:out 70h,al
in al,71h
mov bl,al
mov cl,4
shr bl,cl
shl al,cl
shr al,cl
add bl,30h
add al,30h
mov es:[di],bl
mov es:[di+2],al
ret
start:mov ax,0b800h
mov es,ax
mov di,160*23
mov al,4
call time
mov byte ptr es:[di+4],':'
mov al,2
mov di,160*23+6
call time
mov byte ptr es:[di+4],':'
mov al,0
mov di,160*23+12
call time
mov cx,0
jcxz start
mov ax,4c00h
int 21h
code ends
end start