本人初学存储过程，能否给个存储过程分页的实例，谢谢了！（最好能给个demo）

[li5206610]

我是菜鸟，大家指点我一下，能否给个存储过程分页的实例

[杏鲍菇]

/*--用存儲過程實現的分頁程式
 顯示指定表、視圖、查詢結果的第X頁
 對於表中主鍵或標識列的情況,直接從原表取數查詢，其他情況使用臨時表的方法
 如果視圖或查詢結果中有主鍵,不推薦此方法

--鄒建 2003.09(引用請保留此資訊)--*/

/**//*--調用示例

select top 20 * from product_schedule where brand='oem'
exec p_show 'product_schedule',10,2,'','schedule_id'

select top 20 * from product_schedule where brand='oem' and 1=2
exec p_show 'select schedule_id, priority, merchandising_team, merchandizer, customer,brand from product_schedule where brand=''oem'' and 1=1 ',
10,2,' priority, merchandising_team, merchandizer, customer','schedule_id'

select * from uv_product_report order by year,month,day,product_dest,brand,styling,qty
exec p_show 'uv_product_report',1500,4,'year,month,day,product_dest,brand,styling,qty','year,month,day,product_dest,brand,styling,qty'
--*/

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_show]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_show]
GO

CREATE Proc dbo. p_show
@QueryStr nvarchar(4000), --表名、視圖名、查詢語句
@PageSize int=10,   --每頁的大小(行數)
@PageCurrent int=1,   --要顯示的頁
@FdShow nvarchar (4000)='',--要顯示的欄位列表,如果查詢結果有標識欄位,需要指定此值,且不包含標識欄位
@FdOrder nvarchar (1000)='' --排序欄位列表
as
declare @FdName nvarchar(250) --表中的主鍵或表、臨時表中的標識列名
 ,@Id1 varchar(20),@Id2 varchar(20) --開始和結束的記錄號
 ,@Obj_ID int    --對象ID
--表中有複合主鍵的處理
declare @strfd nvarchar(2000) --複合主鍵列表
 ,@strjoin nvarchar(4000) --連接欄位
 ,@strwhere nvarchar(2000) --查詢條件


select @Obj_ID=object_id(@QueryStr)
 ,@FdShow=case isnull(@FdShow,'') when '' then ' *' else ' '+@FdShow end
 ,@FdOrder=case isnull(@FdOrder,'') when '' then '' else ' order by '+@FdOrder end
 ,@QueryStr=case when @Obj_ID is not null then ' '+@QueryStr else ' ('+@QueryStr+') a' end

--如果顯示第一頁，可以直接用top來完成
if @PageCurrent=1 
begin
 select @Id1=cast(@PageSize as varchar(20))
 exec('select top '+@Id1+@FdShow+' from '+@QueryStr+@FdOrder)
 return
end

--如果是表,則檢查表中是否有標識更或主鍵
if @Obj_ID is not null and objectproperty(@Obj_ID,'IsTable')=1
begin
 select @Id1=cast(@PageSize as varchar(20))
  ,@Id2=cast((@PageCurrent-1)*@PageSize as varchar(20))

 select @FdName=name from syscolumns where id=@Obj_ID and status=0x80
 if @@rowcount=0   --如果表中無標識列,則檢查表中是否有主鍵
 begin
  if not exists(select 1 from sysobjects where parent_obj=@Obj_ID and xtype='PK')
   goto lbusetemp  --如果表中無主鍵,則用臨時表處理

  select @FdName=name from syscolumns where id=@Obj_ID and colid in(
   select colid from sysindexkeys where @Obj_ID=id and indid in(
    select indid from sysindexes where @Obj_ID=id and name in(
     select name from sysobjects where xtype='PK' and parent_obj=@Obj_ID
   )))
  if @@rowcount>1  --檢查表中的主鍵是否為複合主鍵
  begin
   select @strfd='',@strjoin='',@strwhere=''
   select @strfd=@strfd+',['+name+']'
    ,@strjoin=@strjoin+' and a.['+name+']=b.['+name+']'
    ,@strwhere=@strwhere+' and b.['+name+'] is null'
    from syscolumns where id=@Obj_ID and colid in(
    select colid from sysindexkeys where @Obj_ID=id and indid in(
     select indid from sysindexes where @Obj_ID=id and name in(
      select name from sysobjects where xtype='PK' and parent_obj=@Obj_ID
    )))
   select @strfd=substring(@strfd,2,2000)
    ,@strjoin=substring(@strjoin,5,4000)
    ,@strwhere=substring(@strwhere,5,4000)
   goto lbusepk
  end
 end
end
else
 goto lbusetemp

/**//*--使用標識列或主鍵為單一欄位的處理方法--*/
lbuseidentity: 
 exec('select top '+@Id1+@FdShow+' from '+@QueryStr
  +' where '+@FdName+' not in(select top '
  +@Id2+' '+@FdName+' from '+@QueryStr+@FdOrder
  +')'+@FdOrder
  )
 return

/**//*--表中有複合主鍵的處理方法--*/
lbusepk:  
 exec('select '+@FdShow+' from(select top '+@Id1+' a.* from
  (select top 100 percent * from '+@QueryStr+@FdOrder+') a
  left join (select top '+@Id2+' '+@strfd+' 
  from '+@QueryStr+@FdOrder+') b on '+@strjoin+'
  where '+@strwhere+') a'
  )
 return

/**//*--用臨時表處理的方法--*/
lbusetemp:  
select @FdName='[ID_'+cast(newid() as varchar(40))+']'
 ,@Id1=cast(@PageSize*(@PageCurrent-1) as varchar(20))
 ,@Id2=cast(@PageSize*@PageCurrent-1 as varchar(20))

exec('select '+@FdName+'=identity(int,0,1),'+@FdShow+'
  into #tb from'+@QueryStr+@FdOrder+'
 select '+@FdShow+' from #tb where '+@FdName+' between '
 +@Id1+' and '+@Id2
 )
GO

[xmq120]

基于2005的

CREATE   PROCEDURE   [dbo].[getPage] 
@pageSize int,              --页尺寸 
@currentPage int,           --当前页 
@tableFields varchar(2000), --返回的字段 
@tableName   varchar(200),  --表名 
@orderString varchar(1000), --排序字符串 
@whereString varchar(1000), --条件字符串
@IsReCount   bit = 0        -- 返回记录总数, 非 0 值则返回
AS 
BEGIN 

if   @currentPage   <   1   set   @currentPage   =   1 

DECLARE   @strSql   varchar(2000) 
DECLARE   @strOrder varchar(2000) 
DECLARE   @strWhere varchar(2000) 

set   @strOrder   =   REPLACE(RTRIM(LTRIM(@orderString)), 'order   By ', ' ') 
if   @strOrder   !=   ''  set   @strOrder   =   '   order   By   '   +   @strOrder 

set   @strWhere   =   REPLACE(RTRIM(LTRIM(@whereString)), 'where ', ' ') 
if   @strWhere   !=   '' 
     set   @strWhere   =   '   where   '   +   @strWhere 
else
     set   @strWhere   =   '   where  1=1  '   

if   @pageSize   =   0 
    set   @strSql   =   'select   '   +   @tableFields   +   '   from   '   +   @tableName   +   @strWhere   +   @strOrder 
else 
    if   @currentPage   =   1 
        set   @strSql   =   'select   top( '   +   Str(@pageSize)   +   ')   '   +   @tableFields   +   '   from   '   +   @tableName   +   @strWhere   +   @strOrder 
    else 
        begin 
        set   @strSql   =   'select   top( '   +   Str(@pageSize)   +   ')   *   from   (select   top( '   +   Str(@pageSize   *   @currentPage)   +   ')   '   +   @tableFields   +   ',   ROW_NUMBER()   OVER   ( ' 
        set   @strSql   =   @strSql   +   @strOrder 
        set   @strSql   =   @strSql   +   ')   As   RowNumber   From   '   +   @tableName 
        set   @strSql   =   @strSql   +   @strWhere 
        set   @strSql   =   @strSql   +   ')   as   t   where   t.RowNumber   >   '   +   Str(@pageSize   *   (@currentPage   -   1)) 
        set   @strSql   =   @strSql   +   @strOrder 
        end 

if @IsReCount != 0
    set @strSql = 'select count(*) as Total from [' + @tableName + ']  ' + @strWhere 

exec(@strSql) 
END

[downmoon]

http://so.csdn.net/bbsSearchResult.aspx?q=%E5%AD%98%E5%82%A8%E8%BF%87%E7%A8%8B%E5%88%86%E9%A1%B5&p=4

[tongling15]

搜搜吧 太多了

[downmoon]

https://forum.csdn.net/BList/DotNET/EssentialList
https://forum.csdn.net/BList/MSSQL/EssentialList

[Adechen]

csdn就有好多的