高分求关于批处理复制文件名的问题

[quickpass]

大家好！

讨教个问题，我有2个文件夹假设是A文件夹和B文件夹（下面简称A B）。

A和B的文件名需要一模一样，但文件内容是不一样的。

A里面有500个word文件，其文件名是不规则的。

现B有一个模板复制了500份，其文件名也是不规则的，怎样做一个批处理使B的文件名和A的一样？

谢谢各位帮忙！

[Forever_Young]

依据什么来判断呢？B里面是模板，A里面是word文档，这两种文件没有任何可比性啊。

如果你A，B里面都是一样的文件，就是文件名不同还有得搞。

[ljc007]

[code=BatchFile]@echo off
setlocal enabledelayedexpansion
set SrcFolder=C:\test\A
set DstFolder=C:\test\B
set count=0
>"%Temp%\ListA.txt" dir /b "%SrcFolder%"
>"%Temp%\ListB.txt" dir /b "%DstFolder%"
set /p FirstA=<"%Temp%\ListA.txt"
set /p FirstB=<"%Temp%\ListB.txt"
ren "%DstFolder%\%FirstB%" "%FirstA%"
for /f "usebackq skip=1 delims=" %%a in ("%Temp%\ListA.txt") do (
set /a count+=1
call :SyncName %%a !count!
)
endlocal
goto :eof
:SyncName
for /f "usebackq skip=%2 delims=" %%a in ("%Temp%\ListB.txt") do (
ren "%DstFolder%\%%a" "%1"
goto :eof
)[/code]

[再见品月]

顶。。。LS

[quickpass]

谢谢2楼的朋友，是不需要判断word文档里的内容。
用你的方法已经解决了，不知可否注解一下，想学习学习。
非常感谢！！！

[ljc007]

[code=BatchFile]@echo off
setlocal enabledelayedexpansion
rem 指定源文件夹路径
set SrcFolder=C:\test\A
rem 指定目标文件夹路径
set DstFolder=C:\test\B
rem 计数器初始化
set count=0
rem 生成文件名列表
>"%Temp%\ListA.txt" dir /b "%SrcFolder%"
>"%Temp%\ListB.txt" dir /b "%DstFolder%"
rem 修改第一个文件名
set /p FirstA=<"%Temp%\ListA.txt"
set /p FirstB=<"%Temp%\ListB.txt"
ren "%DstFolder%\%FirstB%" "%FirstA%"
rem 修改剩下的所有文件名
for /f "usebackq skip=1 delims=" %%a in ("%Temp%\ListA.txt") do (
rem 计数器加1
set /a count+=1
rem 调用改名子过程
call :SyncName %%a !count!
)
endlocal
rem 打完手工
goto :eof
rem 改名子过程
:SyncName
for /f "usebackq skip=%2 delims=" %%a in ("%Temp%\ListB.txt") do (
ren "%DstFolder%\%%a" "%1"
goto :eof
)[/code]
如果对批处理感兴趣，建议找个批处理论坛，系统地学习一下。

[jyh_baoding]

同意楼上

[quickpass]

B里也是word文档啊，我说的模板意思是500个word文档都套用的一个模板。

[fzzlz]

不行吧，用工具了。

[ljc007]

[Quote=引用 8 楼 fzzlz 的回复:]
不行吧，用工具了。
[/Quote]
请问你是如何测试2楼代码的？怎样得出“不行吧”的结论呢？

[ljc007]

[Quote=引用 4 楼 Forever_Young 的回复:]
007的这个批处理能够处理内容不一样的文件？
[/Quote]
我的理解是，楼主不需要判断word文档里面的内容^_^

[Forever_Young]

007的这个批处理能够处理内容不一样的文件？

[浴火_凤凰]

顶。。。

[quickpass]

再次感谢！

[elitel]

学习

[baichishe]

确实有意思

[lin29276]

for /f "usebackq skip=%2 delims=" %%a in ("%Temp%\ListB.txt") do (
ren "%DstFolder%\%%a" "%1"
goto :eof

[janser08]

强人，我是来拜007的