求一个查询

zjh2702 2009-03-28 02:04:22
工号 年份

1 2001
1 2002
1 2003
1 2004

2 2003
2 2005
2 2007
2 2009


如何得到

工号 年份
1 2001、2002、2003、2004
2 2003、2005、2007、2009
...全文
87 6 打赏 收藏 转发到动态 举报
写回复
用AI写文章
6 条回复
切换为时间正序
请发表友善的回复…
发表回复
dawugui 2009-03-28
  • 打赏
  • 举报
回复
[Quote=引用 5 楼 ws_hgo 的回复:]
大乌龟
你还没有
做够啊
[/Quote]
我目前要逛抓分.到时候你就明白了.
ws_hgo 2009-03-28
  • 打赏
  • 举报
回复
大乌龟
你还没有
做够啊
dawugui 2009-03-28
  • 打赏
  • 举报
回复
create table tb(工号 int, 年份 int)
insert into tb values(1 , 2001 )
insert into tb values(1 , 2002 )
insert into tb values(1 , 2003 )
insert into tb values(1 , 2004 )
insert into tb values(2 , 2003 )
insert into tb values(2 , 2005 )
insert into tb values(2 , 2007 )
insert into tb values(2 , 2009 )
go

create function dbo.f_str(@工号 int) returns varchar(100)
as
begin
declare @str varchar(1000)
set @str = ''
select @str = @str + '、' + cast(年份 as varchar) from tb where 工号 = @工号
set @str = right(@str , len(@str) - 1)
return @str
end
go

--调用函数
select 工号 , 年份 = dbo.f_str(工号) from tb group by 工号

drop function dbo.f_str
drop table tb

/*

工号 年份
----------- ---------------------
1 2001、2002、2003、2004
2 2003、2005、2007、2009

(所影响的行数为 2 行)
*/


--sql 2005
create table tb(工号 int, 年份 int)
insert into tb values(1 , 2001 )
insert into tb values(1 , 2002 )
insert into tb values(1 , 2003 )
insert into tb values(1 , 2004 )
insert into tb values(2 , 2003 )
insert into tb values(2 , 2005 )
insert into tb values(2 , 2007 )
insert into tb values(2 , 2009 )
go

select 工号, [年份] = stuff((select ',' + cast([年份] as varchar) from tb t where 工号 = tb.工号 for xml path('')) , 1 , 1 , '')
from tb
group by 工号

drop table tb



/*

工号 年份
----------- -------------------
1 2001,2002,2003,2004
2 2003,2005,2007,2009

(2 行受影响)

*/
-狙击手- 2009-03-28
  • 打赏
  • 举报
回复
create function f_str(@gh int)
returns varchar(8000)
as
begin
declare @s varchar(8000)
select @s = isnnull(@s+'、','')+ltrim(年份) from ta
where 工号 = @gh
return @s
end
go

select 工号,dbo.f_str(工号)
from ta
group by 工号
liangCK 2009-03-28
  • 打赏
  • 举报
回复
问题描述:
无论是在sql 2000,还是在 sql 2005 中,都没有提供字符串的聚合函数,
所以,当我们在处理下列要求时,会比较麻烦:
有表tb, 如下:
id value
----- ------
1 aa
1 bb
2 aaa
2 bbb
2 ccc
需要得到结果:
id values
------ -----------
1 aa,bb
2 aaa,bbb,ccc
即, group by id, 求 value 的和(字符串相加)

1. 旧的解决方法

-- 1. 创建处理函数
CREATE FUNCTION dbo.f_str(@id int)
RETURNS varchar(8000)
AS
BEGIN
DECLARE @r varchar(8000)
SET @r = ''
SELECT @r = @r + ',' + value
FROM tb
WHERE id=@id
RETURN STUFF(@r, 1, 1, '')
END
GO
-- 调用函数

SELECt id, values=dbo.f_str(id)
FROM tb
GROUP BY id

-- 2. 新的解决方法(适用于2005及以后版本)
-- 示例数据
DECLARE @t TABLE(id int, value varchar(10))
INSERT @t SELECT 1, 'aa'
UNION ALL SELECT 1, 'bb'
UNION ALL SELECT 2, 'aaa'
UNION ALL SELECT 2, 'bbb'
UNION ALL SELECT 2, 'ccc'

-- 查询处理
SELECT *
FROM(
SELECT DISTINCT
id
FROM @t
)A
OUTER APPLY(
SELECT
[values]= STUFF(REPLACE(REPLACE(
(
SELECT value FROM @t N
WHERE id = A.id
FOR XML AUTO
), '<N value="', ','), '"/>', ''), 1, 1, '')
)N

/*--结果
id values
----------- ----------------
1 aa,bb
2 aaa,bbb,ccc
(2 行受影响)
--*/

CSDN 社区帖子地址

附: 合并与分拆的CLR, sql2005的示例中有:
在安装sql 2005的示例后,默认安装目录为
drive:\Program Files\Microsoft SQL Server\90\Samples\Engine\Programmability\CLR\StringUtilities中
sdhdy 2009-03-28
  • 打赏
  • 举报
回复
--******************************************************************************************
-- 合并列值
--*******************************************************************************************
表结构,数据如下:
id value
----- ------
1 aa
1 bb
2 aaa
2 bbb
2 ccc

需要得到结果:
id values
------ -----------
1 aa,bb
2 aaa,bbb,ccc
即:group by id, 求 value 的和(字符串相加)

1. 旧的解决方法(在sql server 2000中只能用函数解决。)
--=============================================================================
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
--1. 创建处理函数
CREATE FUNCTION dbo.f_strUnite(@id int)
RETURNS varchar(8000)
AS
BEGIN
DECLARE @str varchar(8000)
SET @str = ''
SELECT @str = @str + ',' + value FROM tb WHERE id=@id
RETURN STUFF(@str, 1, 1, '')
END
GO
-- 调用函数
SELECt id, value = dbo.f_strUnite(id) FROM tb GROUP BY id
drop table tb
drop function dbo.f_strUnite
go
/*
id value
----------- -----------
1 aa,bb
2 aaa,bbb,ccc
(所影响的行数为 2 行)
*/
--===================================================================================
2. 新的解决方法(在sql server 2005中用OUTER APPLY等解决。)
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go
-- 查询处理
SELECT * FROM(SELECT DISTINCT id FROM tb)A OUTER APPLY(
SELECT [values]= STUFF(REPLACE(REPLACE(
(
SELECT value FROM tb N
WHERE id = A.id
FOR XML AUTO
), ' <N value="', ','), '"/>', ''), 1, 1, '')
)N
drop table tb

/*
id values
----------- -----------
1 aa,bb
2 aaa,bbb,ccc

(2 行受影响)
*/

--SQL2005中的方法2
create table tb(id int, value varchar(10))
insert into tb values(1, 'aa')
insert into tb values(1, 'bb')
insert into tb values(2, 'aaa')
insert into tb values(2, 'bbb')
insert into tb values(2, 'ccc')
go

select id, [values]=stuff((select ','+[value] from tb t where id=tb.id for xml path('')), 1, 1, '')
from tb
group by id

/*
id values
----------- --------------------
1 aa,bb
2 aaa,bbb,ccc

(2 row(s) affected)

*/

drop table tb

22,210

社区成员

发帖
与我相关
我的任务
社区描述
MS-SQL Server 疑难问题
社区管理员
  • 疑难问题社区
  • 尘觉
加入社区
  • 近7日
  • 近30日
  • 至今
社区公告
暂无公告

试试用AI创作助手写篇文章吧