怎么用DOS命令获得局域网其他主机IP?

[勇敢的搬砖人]

如题

[amaterasu_gz]

知道主机名的话，直接"ping 主机名"就有ip显示啊。

[janser08]

用局域网查看器

[syzh120]

net view 找到名字 然后PING

[ljc007]

[code=BatchFile]@echo off
:地址扫描
echo 内网IP段网卡地址扫描
echo.
echo 不扫描请输入 [N]，扫描请输入扫描的ip段前三段(例如:192.168.1):
set /p ipa=
IF /I '%ipa%'=='Y' goto ipend
echo.
echo 正在处理数据请稍候........
echo.
for /l %%i in (1 1 254) do start/b ping -n 1 -w 1 %ipa%.%%i>nul && echo 连接： %ipa%.%%i
arp -a|findstr /v "00-00-00-00-00-00"|more
arp -d
goto 地址扫描[/code]

[ljc007]

[code=BatchFile]@echo off
title 扫描即将开始
color a
cls
echo.
echo ------------------------------------------------------------
echo.
echo 　　本批处理是扫描内网IP、MAC地址和计算机名的，并自动保存文件TXT文件
echo. 　　　　
echo 　　 再利用“自动改IP.bat”实现自动改IP、计算机名、网络号、DNS、网关等
echo. 　　　
echo 并自动安装冰点，将冰点改名为DF.exe,并保存在“自动改IP.bat”同目录下
echo. 　　　
echo 为了扫描到的结果正确，请按照正确格式输入
echo.
echo ------------------------------------------------------------
set /p gateway=请输入内网网关：
set /p dns1=请输入你的首选DNS：
set /p dns2=请输入你的备用DNS：
echo gateway %gateway% >info.txt
echo DNS1 %dns1% >>info.txt
echo DNS2 %dns2% >>info.txt
echo MAC 　IP 计算机名 >>info.txt
set rc=0
set /p ipq=请输入内网IP的前3位（如192.168.0）：
set /p iph=请输入你要扫描的IP起始段（IP的最后一位）：
set /p con1=请输入你要扫描的数量：
set /a con= %iph%+%con1%
:scan
set ip=%ipq%.%iph%
ping -n 1 -w 1 %ip% >nul
title 正在检测 %ip% 　制作
if %errorlevel% GEQ 1 goto dz
for /f "tokens=1" %%i in ('nbtstat -a %ip% ^| find /i "UNIQUE" ^| find /i "00"') do set pcname=%%i
for /f "tokens=4" %%i in ('nbtstat -a %ip% ^| find /i "MAC Address"') do set mac=%%i
echo %mac% %ip% %pcname% >>info.txt
set /a iph=%iph%+1
set /a rc=%rc%+1
if %iph% GTR %con% goto end
goto scan
:dz
echo %ip%不在线，无法扫描！
set /a iph=%iph%+1
if %iph% GTR %con% goto end
goto scan
:end
title 扫描完毕 　 制作
echo 　　　扫描完毕!!
@echo 共扫描%con%台PC。其中%rc%台PC在线!!
pause[/code]

[GGJJyangjinhan]

没这么麻烦 dos里arp-a。看路由缓存表，所有的IP都在哪