如何用代码实现增加控件!!不用在界面上增加!

zhang_dq 2003-05-08 05:12:56
如何用代码实现增加控件!!不用在界面上增加!
比如我要增加一个COMMON DIALOG控件,怎么写代码?
...全文
28 点赞 收藏 6
写回复
6 条回复
切换为时间正序
当前发帖距今超过3年,不再开放新的回复
发表回复
weill 2003-05-26
补充:
Option Explicit
Private WithEvents MyText As TextBox

这两行也可以不要,不要的结果是,MyText不响应事件罗,呵……
回复
weill 2003-05-26
哪有哪么麻烦,呵,看我的……
这是我从msdn里看的,嘻,稍稍改了一下。
要求:控件要在工具箱里(我想大部分朋友都是在此情况下)。
例子说明:动态在窗体中加一个text控件。控件名"MyText",并对控件的响应作一个简单的示范(点击后MyText的文本变成"OK")
代码如下:

Option Explicit
Private WithEvents MyText As TextBox
'上一句说明 MyText 是用来响应由 ActiveX 对象所触发的事件的对象变量。

Private Sub Form_Load()
Set MyText = Controls.Add("VB.TextBox", "mycommand")
'上一句是什么,自个理解了,呵,就是加一个东西了(不是很好理解是把,那就慢慢来)。

'下面的,就不用我说了吧,没有也可以的,系统会来个默认的,不过MyText.Visible不能不设成真哦,不然,你就看不见啦……
With MyText
.Visible = True
.Width = 2000
.Text = "试机"
.Top = 2000
.Left = 1000
.Height = 300
End With
End Sub

Private Sub MyText_Click()
'在这里只是示个例,告诉你怎么控制动态控件了。
MyText.Text = "OK"
End Sub

今天没事编程玩的时候正好想起要在自个的程序中动态加点东东,一天始我也不会,不小心碰出来了,呵,把方法告诉大家吧:)。
回复
succed 2003-05-08
晕了!
回复
zhang_dq 2003-05-08
这么复杂?
回复
lihonggen0 2003-05-08

TechnoFantasy 原作

在VB中动态添加可响应消息的控件
在VB编程中,经常要根据不同的情况在运行时向窗口中添加或者删除控件,而各个控件还要
响应各种事件。在一般的情况下是首先在设计时将控件加入到窗口中,在它们的各个事件中写入
代码,然后将它们的Visible属性设置为False。在运行时再使控件显示出来,但是这样既不方便
同时也因为在设计时在窗口中加入太多的控件而使得程序的运行速度变慢。下面我向大家介绍一
种通过编程在运行时动态添加和删除控件的方法
首先建立一个工程文件,然后在Form1中加入以下的代码:
Dim WithEvents cmdMyCommand As VB.CommandButton
Option Explicit
'在下面的定义中,程序定义了一个TextBox控件、一个CommandButton控件
'和一个附加控件。
Dim WithEvents ctlDynamic As VBControlExtender
Dim WithEvents ctlText As VB.TextBox
Dim WithEvents ctlCommand As VB.CommandButton
Dim WithEvents ctlCommandDel As VB.CommandButton
Private Sub ctlCommandDel_Click()
Dim i As Integer
'将控件的许可证信息删除
Licenses.Remove "MSComctlLib.TreeCtrl"
If MsgBox("是否删除所有控件", vbYesNo) = vbYes Then
For i = 1 To Form1.Controls.Count
Controls.Remove 0
Next i
End If
End Sub
Private Sub ctlCommand_Click()
ctlText.Text = "你点击的是控制按钮"
End Sub
Private Sub ctlDynamic_ObjectEvent(Info As EventInfo)
'当点击树形控件的某一个条目后,在ctlText中显示条目。
If Info.Name = "Click" Then
ctlText.Text = "你点击的条目是 " & _
ctlDynamic.object.selecteditem.Text
End If
End Sub
Private Sub Form_Load()
Dim i As Integer
' 将树形控件的许可证信息加入到许可证集合中
' 如果许可证已经存在,则会返回错误信息732
Licenses.Add "MSComctlLib.TreeCtrl"
' 在Form中动态的加入一个树形控件,如果你想树形控件建立到不同的
'容器中,象一个Frame控件或者PictureBox控件,你只要将Controls.Add
'函数的第三个参数改为特定的容器名就可以了
Set ctlDynamic = Controls.Add("MSComctlLib.TreeCtrl", _
"myctl", Form1)
'设置树形控件的位置和尺寸
ctlDynamic.Move 1, 1, 2500, 3500
'在树形控件中加入10个节点
For i = 1 To 10
ctlDynamic.object.nodes.Add Key:="Test" & Str(i), _
Text:="Test" & Str(i)
ctlDynamic.object.nodes.Add Relative:="Test" & Str(i), _
Relationship:=4, Text:="TestChild" & Str(i)
Next i
'使树形控件可见
ctlDynamic.Visible = True
'加入一个TextBox
Set ctlText = Controls.Add("VB.TextBox", "ctlText1", Form1)
'设置TextBox的位置和尺寸
ctlText.Move (ctlDynamic.Left + ctlDynamic.Width + 50), _
1, 2500, 100
'将textBox的背景色设置为蓝色并将前景色设置为白色
ctlText.BackColor = vbBlue
ctlText.ForeColor = vbWhite
'使TextBox可见
ctlText.Visible = True
'加入一个CommandButton
Set ctlCommand = Controls.Add("VB.CommandButton", _
"ctlCommand1", Form1)
'设置CommandButton的位置和尺寸
ctlCommand.Move (ctlDynamic.Left + ctlDynamic.Width + 50), _
ctlText.Height + 50, 1500, 500
'设置CommandButton的标题
ctlCommand.Caption = "点击"
'使CommandButton可见
ctlCommand.Visible = True
'建立一个删除按钮
Set ctlCommandDel = Controls.Add("VB.CommandButton", _
"ctlCommand2", Form1)
ctlCommandDel.Move (ctlDynamic.Left + ctlDynamic.Width + 50), _
ctlText.Height + 650, 1500, 500
ctlCommandDel.Caption = "删除所有控件"
ctlCommandDel.Visible = True
End Sub
运行上面的程序,可以看到程序在窗口中加入了三个VB标准控件:一个TextBox和两个
CommandButton还加入了一个扩展的ActiveX控件:树形控件。这些控件还可以响应消息,
点击树形控件中的项目或者“点击”按钮就可以在文本框中显示相应的内容。点击“删除
所有控件”按钮就可以删除加入的所有控件了。
通过上面的程序可以看到,通过WithEvents可以定义带事件相应的控件,对于标准的VB
控件(例如CommandButton、TextBox等)可以通过VB.XXX来定义,其中XXX是控件的类的名称
,而对于扩展的ActiveX控件,可以通过VBControlExtender来定义,在装载扩展控件以前,
首先要使用Licenses对象加入控件的许可证信息。
上面的程序在VB6,WIN98中文版下运行通过。
回复
bydisplay 2003-05-08
http://vb1.myrice.com/article/control/ctl001.htm
有此文章,看看
回复
相关推荐
发帖
VB基础类
创建于2007-09-28

7489

社区成员

VB 基础类
申请成为版主
帖子事件
创建了帖子
2003-05-08 05:12
社区公告
暂无公告