请教一个SQL语句

[xiyahui]

有三个表一个是学生表：学号 姓名 性别等
一个是课程表：课程代号 课程名称等
一个是成绩表：学号 课程代号 成绩
请问要形成如下的查询结果应如何写语句
学号 姓名 课程1成绩 课程2成绩 课程3成绩 ....

也就是用横向的表列出每个学生所以课程的成绩。

[linzhisong]

用存储过程写了！

[xiyahui]

呵呵该如何写呢？？

[leimin]

mark 明天给你...

[蓝天]

drop table test_course
go
create table test_course (姓名 varchar(20),科目 varchar(20),成绩 int)
go
insert test_course values ('1','1',60)
insert test_course values ('1','2',60)
insert test_course values ('1','3',60)
insert test_course values ('1','4',60)
insert test_course values ('2','1',60)
insert test_course values ('2','3',60)
insert test_course values ('2','5',60)
insert test_course values ('2','6',60)
go
drop proc proc_course
go
create proc proc_course
as
begin
declare @str varchar(8000)
declare @cause varchar(20)
select @str = 'select 姓名, '

declare my_cursor cursor for
select distinct 科目 from test_course

open my_cursor
fetch next from my_cursor into @cause
while @@fetch_status = 0
begin
select @str = @str + 'sum((case 科目 when '''+ @cause + ' '' then 成绩 else 0 end)) 科目' + @cause + ','
fetch next from my_cursor
into @cause
end

close my_cursor
deallocate my_cursor
select @str= left(@str,len(@str)-1)
select @str= @str + ' from test_course group by 姓名'
exec( @str )
end
go

proc_course

[蓝天]

大同小异

[pengdali]

交叉数据报表
有时候需要旋转结果以便在水平方向显示列，而在垂直方向显示行。这就是所谓的创建 PivotTable®、创建交叉数据报表或旋转数据。

假定有一个表 Pivot，其中每季度占一行。对 Pivot 的 SELECT 操作在垂直方向上列出这些季度：

Year Quarter Amount
---- ------- ------
1990 1 1.1
1990 2 1.2
1990 3 1.3
1990 4 1.4
1991 1 2.1
1991 2 2.2
1991 3 2.3
1991 4 2.4

生成报表的表必须是这样的，其中每年占一行，每个季度的数值显示在一个单独的列中，如：

Year
Q1
Q2
Q3
Q4

1990
1.1
1.2
1.3
1.4

1991
2.1
2.2
2.3
2.4



下面的语句用于创建 Pivot 表并在其中填入第一个表中的数据：

USE Northwind
GO

CREATE TABLE Pivot
( Year SMALLINT,
Quarter TINYINT,
Amount DECIMAL(2,1) )
GO
INSERT INTO Pivot VALUES (1990, 1, 1.1)
INSERT INTO Pivot VALUES (1990, 2, 1.2)
INSERT INTO Pivot VALUES (1990, 3, 1.3)
INSERT INTO Pivot VALUES (1990, 4, 1.4)
INSERT INTO Pivot VALUES (1991, 1, 2.1)
INSERT INTO Pivot VALUES (1991, 2, 2.2)
INSERT INTO Pivot VALUES (1991, 3, 2.3)
INSERT INTO Pivot VALUES (1991, 4, 2.4)
GO

下面是用于创建旋转结果的 SELECT 语句：

SELECT Year,
SUM(CASE Quarter WHEN 1 THEN Amount ELSE 0 END) AS Q1,
SUM(CASE Quarter WHEN 2 THEN Amount ELSE 0 END) AS Q2,
SUM(CASE Quarter WHEN 3 THEN Amount ELSE 0 END) AS Q3,
SUM(CASE Quarter WHEN 4 THEN Amount ELSE 0 END) AS Q4
FROM Northwind.dbo.Pivot
GROUP BY Year
GO

该 SELECT 语句还处理其中每个季度占多行的表。GROUP BY 语句将 Pivot 中一年的所有行合并成一行输出。当执行分组操作时，SUM 聚合中的 CASE 函数的应用方式是这样的：将每季度的 Amount 值添加到结果集的适当列中，在其它季度的结果集列中添加 0。

如果该 SELECT 语句的结果用作电子表格的输入，那么电子表格将很容易计算每年的合计。当从应用程序使用 SELECT 时，可能更易于增强 SELECT 语句来计算每年的合计。例如：

SELECT P1.*, (P1.Q1 + P1.Q2 + P1.Q3 + P1.Q4) AS YearTotal
FROM (SELECT Year,
SUM(CASE P.Quarter WHEN 1 THEN P.Amount ELSE 0 END) AS Q1,
SUM(CASE P.Quarter WHEN 2 THEN P.Amount ELSE 0 END) AS Q2,
SUM(CASE P.Quarter WHEN 3 THEN P.Amount ELSE 0 END) AS Q3,
SUM(CASE P.Quarter WHEN 4 THEN P.Amount ELSE 0 END) AS Q4
FROM Pivot AS P
GROUP BY P.Year) AS P1
GO

带有 CUBE 的 GROUP BY 和带有 ROLLUP 的 GROUP BY 都计算与本例显示相同的信息种类，但格式稍有不同。

[pengdali]

按你的题目：


create table #学生表 (学号 int,姓名 varchar(100),性别 char(2))
create table #课程表 (课程代号 int,课程名称 varchar(100))
create table #成绩表 (学号 int,课程代号 int,成绩 int)

insert #学生表 values(1,'pongdali','女')
insert #学生表 values(2,'pengdali','男')
insert #课程表 values(1,'语文')
insert #课程表 values(2,'数学')
insert #课程表 values(3,'英语')
insert #成绩表 values(1,1,99)
insert #成绩表 values(1,2,98)
insert #成绩表 values(1,3,100)
insert #成绩表 values(2,1,34)
insert #成绩表 values(2,2,36)
insert #成绩表 values(2,3,12)
---------------上面是你的表，下面是得到你的结果
declare @sql varchar(8000)
set @sql = 'select a.姓名'
select @sql = @sql + ',sum(case b.课程代号 when '+cast(课程代号 as varchar)+' then b.成绩 else 0 end) ['+课程名称+']'
from (select * from #课程表) as a
select @sql = @sql+' from #学生表 a,#成绩表 b where a.学号=b.学号 group by a.姓名'

exec(@sql)

go
drop table #成绩表,#学生表,#课程表

[xiyahui]

那该怎么把这个存储过程的结果放入到客户端的recordset中调用。

[xiyahui]

??

[xiyahui]

55没有人在吗

[pengdali]

你直接调用呀！和普通的一样，你把上面的处理部分的表名改为你的表名，你不会调用过程吗？

[xiyahui]

我是说，如果把上面的写成存储过程，如何在客户端调用该存储过程并得到结果。
当然在sql的查询分析器中可以执行了。

[xiyahui]

例如现在用vb的dbgrid我如何得到这个存储过程的结果那？或者用ado我如何把该存储过程的结果赋予recordset。