急！！！如何在VB窗体中用代码添加控件？？

2003-06-02 09:11:45 1.3k 阅读 AI 写同款 · GEO 优化AI 选题数据监测一键分发 ›

fanswer2000 墨衍会员 · AI 创作全网分发关注 + 加入社区

vb.net详解MDI窗体操作方法 MDI窗体可以避免打开窗体的时候被无数个子窗体困扰，我将为大家一一的介绍一下vb.net中MDI窗体的操作方法一、如何创建MDI窗体？ 1、创建mdi主窗体新建建立一个默认空白的Windows应用程序，在Form1窗体的属性窗口中找到IsMDIContainer 属性，设置为 True 2、创建MDI子窗体在vb.net中，mdi子窗体就是普通的窗体，无需更改其属性。所有直阅读详情

急！！！如何在VB窗体中用代码添加控件？？

想做一个画图程序!!

...全文

Vb.net遍历一个窗口中的所有某类对象 (窗体中的控件) 的方法学习目标：VB.NET利用Controls属性获取窗体控件列表练习平台：Windows10企业版（64位）测试工具：MicrosoftVisual Studio（版本默认安装）。程序语言：VB.NET通过窗体的Controls属性实现，参考代码： Try For i = 0 ToMe.Controls.Count - 1 ''获取包含在控件内的控件的集合元素数。... 阅读详情

fanswer2000

VB基础类 7,788 成员 197,583 内容

+ 关注 + 加入社区

切换为时间正序

xionglibin 2003-06-02

打赏
举报

上面的都能做到﹐
不過你用VBA 中的屬性也可以做到﹐
如使用
set obj=CreateObject("VBA.commandbox") 等方法就能產生一個控件了

cringer 2003-06-02

打赏
举报

object.Add (ProgID, name, container)
====================================
参数说明：
Object 必需的。一个对象表达式，其值是“应用于”列表中的一个对象。
ProgID 必需的。一个标识控件的字符串。大多数控件的 ProgID 都可通过查看对象浏览器来决定。控件的 ProgID 是由控件的库和类组成的。
例如，CommandButton 控件的 ProgID 是 VB.CommandButton。在ProgID 与对象浏览器中所显示的不一样的情况下，Visual Basic
将显示一个包括正确 ProgId 的错误信息。
name 必要的。一个字符串，用来标识集合的成员。
container 可选的。一个对象引用，它指定控件的容器。如果没有指定或为NULL，缺省值为 Controls 集合所属的容器。通过指定该参数，可
以把一个控件放置在任何现存的容器控件（如 Frame 控件）中。用户控件或 ActiveX 文档也可以作为一个容器。
================================
举例： //在picture1上面添加一个commandbutton
Private Sub Form_Load()
Form1.Controls.Add "VB.CommandButton", "cmdOk", Picture1
With Form1!cmdOk
.Visible = True
.Width = 500
.Caption = "确认(&Y)"
End With
End Sub

lihonggen0 2003-06-02

打赏
举报

http://expert.csdn.net/Expert/FAQ/FAQ_Index.asp?id=68250

lihonggen0 2003-06-02

打赏
举报

'先有form1上加一个text1 (0)

Private Sub Form_Load()
For i = 1 To 10
Load Text1(i)
Text1(i).Top = 400 * i + 200
Text1(i).Left = 20
Text1(i).Visible = True
Next
End Sub

lihonggen0 2003-06-02

打赏
举报

在VB中动态添加可响应消息的控件
在VB编程中，经常要根据不同的情况在运行时向窗口中添加或者删除控件，而各个控件还要
响应各种事件。在一般的情况下是首先在设计时将控件加入到窗口中，在它们的各个事件中写入
代码，然后将它们的Visible属性设置为False。在运行时再使控件显示出来，但是这样既不方便
同时也因为在设计时在窗口中加入太多的控件而使得程序的运行速度变慢。下面我向大家介绍一
种通过编程在运行时动态添加和删除控件的方法
首先建立一个工程文件，然后在Form1中加入以下的代码：
Dim WithEvents cmdMyCommand As VB.CommandButton
Option Explicit
'在下面的定义中，程序定义了一个TextBox控件、一个CommandButton控件
'和一个附加控件。
Dim WithEvents ctlDynamic As VBControlExtender
Dim WithEvents ctlText As VB.TextBox
Dim WithEvents ctlCommand As VB.CommandButton
Dim WithEvents ctlCommandDel As VB.CommandButton
Private Sub ctlCommandDel_Click()
Dim i As Integer
'将控件的许可证信息删除
Licenses.Remove "MSComctlLib.TreeCtrl"
If MsgBox("是否删除所有控件", vbYesNo) = vbYes Then
For i = 1 To Form1.Controls.Count
Controls.Remove 0
Next i
End If
End Sub
Private Sub ctlCommand_Click()
ctlText.Text = "你点击的是控制按钮"
End Sub
Private Sub ctlDynamic_ObjectEvent(Info As EventInfo)
'当点击树形控件的某一个条目后，在ctlText中显示条目。
If Info.Name = "Click" Then
ctlText.Text = "你点击的条目是 " & _
ctlDynamic.object.selecteditem.Text
End If
End Sub
Private Sub Form_Load()
Dim i As Integer
' 将树形控件的许可证信息加入到许可证集合中
' 如果许可证已经存在，则会返回错误信息732
Licenses.Add "MSComctlLib.TreeCtrl"
' 在Form中动态的加入一个树形控件，如果你想树形控件建立到不同的
'容器中，象一个Frame控件或者PictureBox控件，你只要将Controls.Add
'函数的第三个参数改为特定的容器名就可以了
Set ctlDynamic = Controls.Add("MSComctlLib.TreeCtrl", _
"myctl", Form1)
'设置树形控件的位置和尺寸
ctlDynamic.Move 1, 1, 2500, 3500
'在树形控件中加入10个节点
For i = 1 To 10
ctlDynamic.object.nodes.Add Key:="Test" & Str(i), _
Text:="Test" & Str(i)
ctlDynamic.object.nodes.Add Relative:="Test" & Str(i), _
Relationship:=4, Text:="TestChild" & Str(i)
Next i
'使树形控件可见
ctlDynamic.Visible = True
'加入一个TextBox
Set ctlText = Controls.Add("VB.TextBox", "ctlText1", Form1)
'设置TextBox的位置和尺寸
ctlText.Move (ctlDynamic.Left + ctlDynamic.Width + 50), _
1, 2500, 100
'将textBox的背景色设置为蓝色并将前景色设置为白色
ctlText.BackColor = vbBlue
ctlText.ForeColor = vbWhite
'使TextBox可见
ctlText.Visible = True
'加入一个CommandButton
Set ctlCommand = Controls.Add("VB.CommandButton", _
"ctlCommand1", Form1)
'设置CommandButton的位置和尺寸
ctlCommand.Move (ctlDynamic.Left + ctlDynamic.Width + 50), _
ctlText.Height + 50, 1500, 500
'设置CommandButton的标题
ctlCommand.Caption = "点击"
'使CommandButton可见
ctlCommand.Visible = True
'建立一个删除按钮
Set ctlCommandDel = Controls.Add("VB.CommandButton", _
"ctlCommand2", Form1)
ctlCommandDel.Move (ctlDynamic.Left + ctlDynamic.Width + 50), _
ctlText.Height + 650, 1500, 500
ctlCommandDel.Caption = "删除所有控件"
ctlCommandDel.Visible = True
End Sub
运行上面的程序，可以看到程序在窗口中加入了三个VB标准控件：一个TextBox和两个
CommandButton还加入了一个扩展的ActiveX控件：树形控件。这些控件还可以响应消息，
点击树形控件中的项目或者“点击”按钮就可以在文本框中显示相应的内容。点击“删除
所有控件”按钮就可以删除加入的所有控件了。
通过上面的程序可以看到，通过WithEvents可以定义带事件相应的控件，对于标准的VB
控件（例如CommandButton、TextBox等）可以通过VB.XXX来定义，其中XXX是控件的类的名称
，而对于扩展的ActiveX控件，可以通过VBControlExtender来定义，在装载扩展控件以前，
首先要使用Licenses对象加入控件的许可证信息。

急！！！如何在VB窗体中用代码添加控件？？

相关推荐